Trailing-Edge
-
PDP-10 Archives
-
BB-4148D-BM_1980
-
dbms-v5a/source/dbms20.ctl
There are 26 other files named dbms20.ctl in the archive. Click here to see a list.
;DBMS20.CTL V(EDIT)==5A(13)
;USED TO LOAD SCHEMA PROCESSOR, FORTRAN PRE-PROCESSOR, DBINFO,
;DBMEND, DAEMDB, FORTRAN RUN-TIME SYSTEM, COBOL RUN-TIME SYSTEM
;
;***** WARNING---THIS CTL FILE IS USED TO BUILD DBMS-20 ON
; THE DEVELOPMENT SYSTEMS IN MARLBORO. IT IS NOT
; GAURANTEED TO RUN ON ANY OTHER SYSTEM. THE USER
; SHOULD CHECK THIS CTL FILE FOR ANY INSTALLATION
; DEPENDENT ITEMS.
;
;***** NOTE--- TO CREATE THE SCHEMA PROCESSOR (SCHEMA.EXE), THE
; FORTRAN PRE-PROCESSOR (FORDML.EXE), THE BACKUP/
; RECOVERY UTILITY (DBMEND.EXE), THE INFO-GENERATING
; UTILITY (DBINFO.EXE), AND THE BACKROUND MTA
; JOURNALING FACILITY (DAEMDB.EXE) SUBMIT DBMS20.CTL
; WITH /TAG:DBALL.
;
;
;SUBMIT WITH COMMAND .SUBMIT DBMS20/TIME:00:30:00
;
;COPYRIGHT 1975,1976,1977,1978,1979 DIGITAL EQUIPMENT CORP., MARLBORO, MASS.
;
;REQUIRED FILES:
;<SUBSYS> MAKLIB (LATEST RELEASED VERSIONS)
; LINK
;<REL> SCAN.REL WILD.REL HELPER.REL
;[SELF]: DBSANY.REL DBS20.REL DBSFOR.REL DBSCOB.REL
; GENME2.REL GENMS2.REL GENIO2.REL
; DBMS20.CTL DBMS5.RND DBMS5A.RND
; SCHEMA.CMD SCHEMA.HLP
; FORDM2.CMD FORDML.HLP
; DBMEN2.CMD DBMEND.HLP
; DBINF2.CMD DBINFO.HLP
; DAEMD2.CMD DAEMDB.HLP
; DBCS28.CMD DBCS2F.CMD DBCS24.CMD
; DDLANY.REL DDL20.REL
; FMLANY.REL FML20.REL
; MNDANY.REL MND20.REL
; INFANY.REL INF20.REL
; DABANY.REL DAB20.REL
; STRLIB.REL SCHIO2.REL
;
;
;***** EXAMINE SECTION 6 OF DBMS5A.DOC BEFORE SUBMITTING THIS CTL FILE.
; IF APPLICABLE REBUILD COBOL-68, COBOL-74, LIBOL, C74LIB,
; AND/OR FOROTS BEFORE RUNNING THIS CTL FILE
;***** IMPORTANT:
; THE DISTRIBUTED .LOG FILE FOR THIS .CTL FILE DOES BUILD
; A FOROTS, LIBOL, AND C74LIB, BUT THERE IS NO INTENT THAT A
; USER INSTALLATION BUILD IDENTICAL COPIES OF THESE HOST-SYSTEMS.
; THE INTENT IS TO DEMONSTRATE THAT THE PROCESS OF BUILDING FOROTS,
; LIBOL, AND C74LIB IS VALID.
;
;***** IF YOU DESIRE COBOL-68 DBMS-20 SUPPORT, YOU MUST INCLUDE
; A COPY OF THE LATEST RELEASED LIBOL.REL AND LIBSHR.REL IN YOUR AREA.
;***** IF YOU DESIRE COBOL-74 DBMS-20 SUPPORT, YOU MUST INCLUDE
; A COPY OF THE LATEST RELEASED C74LIB.REL AND C74SHR.REL IN YOUR AREA.
;***** IF YOU WISH TO BUILD A FORTRAN-20/DBMS-20 RUN-TIME SYSTEM, YOU
; MUST INCLUDE A COPY OF THE LATEST RELEASED FORLIB.REL IN YOUR AREA.
;
;
;OUTPUT: SCHEMA.EXE FORDML.EXE DBMEND.EXE DBINFO.EXE DAEMDB.EXE
; SCHEMA.MAP FORDML.MAP DBMEND.MAP DBINFO.MAP DAEMDB.MAP
;
; IF BUILDING A COBOL-68 SYSTEM: C68OTS.EXE,C68OTS.MAP, AND LIBOL.REL
; IF BUILDING A COBOL-74 SYSTEM: C74OTS.EXE,C74OTS.MAP, AND C74LIB.REL
; IF BUILDING A FORTRAN SYSTEM: FDBOTS.EXE,FDBOTS.MAP, AND FORLIB.REL
;
;OUTPUT LISTINGS: DBMS20.LOG, DBMS5A.DOC, DBMS5.DOC, *.MAP
;
;USE LATEST RELEASED SOFTWARE
;
;
; THIS IS FOR IN-HOUSE USE ONLY:
;
@DEFINE DSK: DSK:,SUPT:<DBMS-V5A>,SUPT:<DBMS-MAINT.V5-DISTRIBUTION>,SUPT:<COBOL-MAINT>,PS:<SUBSYS>,PS:<UNSUPPORTED>
;
; END OF IN-HOUSE USE ONLY.
;
@DEFINE SYS: DSK:,PS:<SUBSYS>
@DEFINE DEC: DSK:,<SUBSYS>
;
;MAKE A RECORD OF WHAT IS BEING USED
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@DIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,
@CHECKSUM SEQUENTIAL
@
@DIRECT DEC:SCAN.REL,DEC:WILD.REL,DEC:HELPER.REL,
@CHECKSUM SEQUENTIAL
@
@DIRECT DBS*.REL,SCHIO2.REL,DBMS5A.RND,DBMS5.RND,DBMS20.CTL,DBCS2%.CMD,*.HLP,
@CHECKSUM SEQUENTIAL
@
@IF (ERROR) @GOTO TRUBLE
@GOTO QCOBOL
DBALL::
@DEFINE DSK: DSK:,SUPT:<DBMS-V5A>,SUPT:<DBMS-MAINT.V5-DISTRIBUTION>,SUPT:<COBOL-MAINT>,PS:<SUBSYS>,PS:<UNSUPPORTED>
@DEFINE SYS: DSK:,PS:<SUBSYS>,PS:<FIELD-IMAGE>
@DEFINE DEC: DSK:,<SUBSYS>
;
;MAKE A RECORD OF WHAT IS BEING USED
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@DIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,
@CHECKSUM SEQUENTIAL
@
@DIRECT DEC:SCAN.REL,DEC:WILD.REL,DEC:HELPER.REL,
@CHECKSUM SEQUENTIAL
@
@DIRECT DDL*.REL,FML*.REL,MND*.REL,DBS*.REL,INF*.REL,DAB*.REL,GEN*.REL,STRHI.REL,SCHIO2.REL,DBMS5A.RND,DBMS5.RND,DBMS20.CTL,%%%%%2.CMD,DBCS2%.CMD,*.HLP,
@CHECKSUM SEQUENTIAL
@
@IF (ERROR) @GOTO TRUBLE
;CREATE SCHEMA PROCESSOR
;
@R LINK
*@SCHEM2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:SCHEMA
@IF (ERROR) @GOTO TRUBLE
;
;CREATE FORTRAN PRE-PROCESSOR
;
@R LINK
*@FORDM2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FORDML
@IF (ERROR) @GOTO TRUBLE
;
;CREATE BACKUP/RECOVERY UTILITY
;
@R LINK
*@DBMEN2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMEND
@IF (ERROR) @GOTO TRUBLE
;
;CREATE INFO-GENERATING UTILITY
;
@R LINK
*@DBINF2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBINFO
@IF (ERROR) @GOTO TRUBLE
;
;CREATE BACKGROUND MTA JOURNALING FACILITY
;
@R LINK
*@DAEMD2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DAEMDB
@IF (ERROR) @GOTO TRUBLE
;
QCOBOL::
;BUILD COBOL-68 INTERFACE IF LIBOL.REL IS AVAILABLE
;
@ERROR %
@DIRECT LIBOL.REL
@IF (ERROR) @GOTO NOC68
@ERROR
;
@R MAKLIB
*LIBOL=LIBOL/DELETE:RESOLV
*LIBOL=LIBOL/DELETE:RSVGAT
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*LIBOL=LIBOL/INDEX
@DEL COBFUN.TMP
;
@R LINK
*@DBCS28
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:C68OTS 0 1,600 675
@IF (ERROR) @GOTO TRUBLE
!!! LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
;HERE TO BUILD COBOL-74 OTS SUPPORT IF C74LIB IS AVAILABLE
NOC68::
@ERROR %
@DIRECT C74LIB.REL
@IF (ERROR) @GOTO NOC74
@ERROR
@R MAKLIB
*C74LIB=C74LIB/DELETE:RESOLV
*C74LIB=C74LIB/DELETE:RSVGAT
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*C74LIB=C74LIB/INDEX
@DEL COBFUN.TMP
;
@R LINK
*@DBCS24
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:C74OTS 0 1,600 675
@IF (ERROR) @GOTO TRUBLE
!!! LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
@ERROR
;
NOC74::
QFORT::
;BUILD FORTRAN INTERFACE IF FORLIB.REL IS AVAILABLE
;
@ERROR %
@DIRECT FORLIB.REL
@IF (ERROR) @GOTO NOFORT
@ERROR
;
@R MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFOR/APPEND,DBS20/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB/INDEX
;
@R LINK
*@DBCS2F
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FDBOTS
@IF (ERROR) @GOTO TRUBLE
!!! LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
NOFORT::
@ERROR
;
;HAVE BUILT EVERYTHING, NOW CLEANUP
;
;BUILD AND PRINT DOC FILE
;
@R RUNOFF
*DBMS5A.DOC=DBMS5A.RND
*DBMS5.DOC=DBMS5.RND
@IF (ERROR) .PLEASE -- ?COULD NOT CREATE DOC FILES
;
@PRINT DBMS5A.DOC/COPIES:1,DBMS5.DOC/COPIES:1,*.MAP
@IF (ERROR) .PLEASE -- ?COULD NOT PRINT DOC AND/OR MAP FILES
;
;SEE WHAT WE GOT
;
@DIRECT SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,DAEMDB.*,%%%OTS.*,LIBOL.REL,C74LIB.REL,FORLIB.REL,
@CHECKSUM SEQUENTIAL
@
;
;TELL HOW WE DID
;
@PLEASE -- DBMS-20 CREATION SUCCESSFUL!!!
@GOTO ENDOF
TRUBLE::
@PLEASE -- ?DBMS-20 CREATION NOT SUCCESSFUL
ENDOF::;[ END OF DBMS20.CTL ]