Google
 

Trailing-Edge - PDP-10 Archives - BB-D480F-BB_1985_short - frmbnf.syn
There are 12 other files named frmbnf.syn in the archive. Click here to see a list.
;COPYRIGHT (C) DIGITAL EQUIPMENT CORPORATION 1974, 1985
;ALL RIGHTS RESERVED.
;
;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
;ONLY  IN  ACCORDANCE  WITH  THE  TERMS  OF  SUCH LICENSE AND WITH THE
;INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS SOFTWARE OR ANY  OTHER
;COPIES THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY
;OTHER PERSON.  NO TITLE TO AND OWNERSHIP OF THE  SOFTWARE  IS  HEREBY
;TRANSFERRED.
;
;THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE WITHOUT  NOTICE
;AND  SHOULD  NOT  BE  CONSTRUED  AS A COMMITMENT BY DIGITAL EQUIPMENT
;CORPORATION.
;
;DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY  OF  ITS
;SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.

;AUTHORS: T.E. OSTEN, D. B. TOLMAN, T.F. VASAK

	THE SYNTAX OF PDP-10 FORTRAN 10 FORMAT STATEMENT
			100-310-000-00
			NOVEMBER 17,1971

	FRMBNFV = #10^24 + 0^18 + 1	!Version date: 22-Jul-81

***** Begin Revision History *****

***** Begin Version 6 *****

1	760	TFV	1-Mar-80	-----
	F77 FORMAT statement changes

***** End Revision History *****

NOTE **** Everything before the first form feed is ignored, so all
	  global comments, and the revision history must be fully
	  contained on the first logical page. Starting with page
	  2, all comments must be preceded by a ; (semicolon), and
	  terminated with a . (dot).


		THE  INFORMATION IN  THIS MEMORANDUM IS
		SUBJECT TO CHANGE  WITHOUT  NOTICE  AND
		SHOULD NOT BE CONSTRUED AS A COMMITMENT
		BY   DIGITAL  EQUIPEMENT  CORPORATION .
;							100-310-000-00
							PAGE 02
.
;THE MODIFIED BNF SYNTAX DESCRIBED IN TERMS OF ITSELF .

BNFDEFINITION      = METASYMBOL "="  BNFCOMPONENT  [ COMMENT ] "." .

BNFCOMPONENT       = ( TERMINAL l
                     METASYMBOL l
                     OR l
                     AND l
                     OPTION l
                     LIST l
                     REPEAT l
                     ACTION ) .

TERMINAL           = """ *ASCIICHARACTER """ ;TERMINAL CHARACTER STRING .

METASYMBOL         = [ *LETTER  "-" ] *LETTER  ;AN ELEMENT
                     OF THE SYNTAX DEFINED BY THE SYNTAX OR BY A LEXICAL
                     PROCESS .

OR                 = "(" BNFCOMPONENT *[ "l" BNFCOMPONENT ] ")" 
                     ;ONLY ONE OF THE BNFCOMPONENTS IS REQUIRED .

AND                = BNFCOMPONENT *[ BNFCOMPONENT ] ;ALL OF THE
                     BNFCOMPONENTS ARE REQUIRED .

OPTION             = "[" BNFCOMPONENT "]" ;USE OF THE BNFCOMPONENT IS
                     OPTIONAL .

LIST               = "+" BNFCOMPONENT ;BNFCOMPONENTS SEPERATED BY
                     COMMAS .

REPEAT             = "*" BNFCOMPONENT ;BNFCOMPONENTS NOT SEPERATED BY
                     COMMAS .

ACTION             = "%" ACTIONNAME "%" ;ACTION TO BE PERFORMED WHEN ENCOUNTERED .

COMMENT            = ";" *ASCIICHARACTER .

;*****************************************************************************************************************
;							100-310-000-00
							PAGE 03
.
;CHECKS THAT THE FORMAT STATEMENT CONFORMS TO THE SYNTAX WHICH FOLLOWS.

FORMATSPEC        = LPAREN  [ FDGROUP ] RPAREN LINEND .

FDGROUP           = +( FIELDDESCRIPTOR [ *SLASH ] ) .

FIELDDESCRIPTOR   = ( ( PLUS l MINUS ) CONST PCHAR [ [ CONST ] TWODESCRIPTOR ] l
                    CONST ( PCHAR [ [ CONST ] TWODESCRIPTOR ] l
                    TWODESCRIPTOR l ONEDESCRIPTOR l XCHAR l LPAREN  FDGROUP RPAREN )  l
                    TWODESCRIPTOR l ONEDESCRIPTOR l TCHAR [ LCHAR l RCHAR ] CONST l
                    SCHAR [ SCHAR l PCHAR ] l BCHAR ( NCHAR l ZCHAR ) l
                    DOLLAR l SLASH l COLON l
                    LITSTRING l XCHAR l QCHAR l LPAREN  FDGROUP RPAREN ) .

TWODESCRIPTOR     = ( ( ECHAR l DCHAR l GCHAR ) [ CONST [ PERIOD CONST ] [ ECHAR CONST ] ] l 
                    ( FCHAR l ICHAR l OCHAR l ZCHAR ) [ CONST [ PERIOD CONST ] ] ) .

ONEDESCRIPTOR     = ( LCHAR l ACHAR l RCHAR ) [ CONST ] .