Trailing-Edge
-
PDP-10 Archives
-
BB-H348C-RM_1982
-
swskit-v21/listings/rsx11s/drcin.list
There are no other files named drcin.list in the archive.
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3
1 .TITLE DRCIN
2 .IDENT /01.05/
3
4 ;
5 ; COPYRIGHT (C) 1977
6 ; DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.
7 ;
8 ; THIS SOFTWARE IS FURNISHED UNDER A LICENSE FOR USE ONLY ON A
9 ; SINGLE COMPUTER SYSTEM AND MAY BE COPIED ONLY WITH THE
10 ; INCLUSION OF THE ABOVE COPYRIGHT NOTICE. THIS SOFTWARE, OR
11 ; ANY OTHER COPIES THEREOF, MAY NOT BE PROVIDED OR OTHERWISE
12 ; MADE AVAILABLE TO ANY OTHER PERSON EXCEPT FOR USE ON SUCH
13 ; SYSTEM AND TO ONE WHO AGREES TO THESE LICENSE TERMS. TITLE
14 ; TO AND OWNERSHIP OF THE SOFTWARE SHALL AT ALL TIMES REMAIN
15 ; IN DEC.
16 ;
17 ; THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO CHANGE WITHOUT
18 ; NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT BY DIGITAL
19 ; EQUIPMENT CORPORATION.
20 ;
21 ; DEC ASSUMES NO RESPONSIBILITY FOR THE USE OR RELIABILITY OF
22 ; ITS SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DEC.
23 ;
24 ; VERSION 01
25 ;
26 ; P. WANNHEDEN 24-MAY-77
27 ;
28 ; MACRO LIBRARY CALLS
29 ;
30
31 .MCALL HWDDF$,TCBDF$,PCBDF$,ITBDF$
32 000000 HWDDF$ ; DEFINE HARDWARE REGISTERS
33 000000 TCBDF$ ; DEFINE TCB OFFSETS
34 000000 PCBDF$ ; DEFINE PCB OFFSETS
35 000000 ITBDF$ ; DEFINE ITB OFFSETS
36
37 ;+
38 ; **-$DRCIN-CONNECT TO INTERRUPT.
39 ;
40 ; THIS DIRECTIVE INSTRUCTS THE SYSTEM TO CONNECT A SPECIFIED INTERRUPT
41 ; VECTOR TO AN INTERRUPT SERVICE ROUTINE (ISR) IN THE TASK'S OWN SPACE,
42 ; OR TO DISCONNECT A PREVIOUSLY CONNECTED INTERRUPT VECTOR.
43 ;
44 ; IF THE FUNCTION "CONNECT" IS REQUESTED, THE OPERATION IS AS FOLLOWS:
45 ; A BLOCK OF DYNAMIC MEMORY IS ALLOCATED AND SET UP AS AN INTERRUPT
46 ; TRANSFER BLOCK (ITB). THE ITB IS LINKED TO THE ITB LIST OF THE
47 ; TASK WITH LISTHEAD (SINGLE WORD!!) IN T.CPCB OF THE TCB.
48 ; CHECKPOINTING AND SHUFFLING IS DISABLED FOR THE TASK.
49 ; THE VECTOR IS SET UP TO POINT TO THE OFFSET X.JSR IN THE ITB,
50 ; WHICH CONTAINS A SUBROUTINE CALL TO THE SPECIAL INTERRUPT SAVE
51 ; ROUTINE $INTSC.
52 ;
53 ; IF THE FUNCTION "DISCONNECT" IS REQUESTED, THE OPERATION IS
54 ; ESSENTIALLY THE REVERSE OF WHAT IS DESCRIBED FOR "CONNECT".
55 ;
56 ; *************************************************
57 ; * NOTE - THE DISCONNECT FUNCTION, WHEN *
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-1
58 ; * DISCONNECTING THE LAST VECTOR (OR *
59 ; * ONLY), CLEARS THE CHECKPOINT-DISABLE *
60 ; * BIT (T2.CKD) AND NO-SHUFFLE BIT (PS.NSF) *
61 ; * REGARDLESS OF WHAT THE STATE WAS BEFORE *
62 ; * VECTORS WERE CONNECTED OR ANY CHANGE IN *
63 ; * STATE WHILE VECTORS WERE CONNECTED. *
64 ; * (EXCEPTION - IF THE TASK IS MARKED FOR *
65 ; * ABORT BECAUSE OF MEMORY PARITY ERROR, *
66 ; * IT IS NOT MADE SHUFFLABLE). *
67 ; *************************************************
68 ;
69 ; DPB FORMAT:
70 ;
71 ; WD. 00 -- DIC(129.),DPB SIZE(7.).
72 ; WD. 01 -- INTERRUPT VECTOR ADDRESS.
73 ; WD. 02 -- BASE ADDRESS FOR MAPPING OF ISR AND
74 ; ENABLE/DISABLE-INTERRUPT ROUTINES.
75 ; IGNORED IN AN UNMAPPED SYSTEM.
76 ; WD. 03 -- ADDRESS OF INTERRUPT SERVICE ROUTINE. IF ZERO, DIRECTIVE
77 ; IS "DISCONNECT FROM INTERRUPTS" AND REMAINING ARGUMENTS
78 ; ARE IGNORED.
79 ; WD. 04 -- ADDRESS OF ENABLE/DISABLE-INTERRUPT ROUTINE.
80 ; WD. 05 -- (LOW BYTE) LOW BYTE OF PSW TO BE SET
81 ; BEFORE CALLING ISR.
82 ; WD. 06 -- ADDRESS OF AST ROUTINE.
83 ;
84 ; INPUTS:
85 ;
86 ; R2=ADDRESS OF THE TASK STATUS WORD OF THE CURRENT TASK.
87 ; R3=POINTER TO WD. 01 IN DPB
88 ; R4=ADDRESS OF THE HEADER OF THE CURRENT TASK.
89 ; R5=ADDRESS OF THE TCB OF THE CURRENT TASK.
90 ;
91 ; OUTPUTS: (DIRECTIVE STATUS AND PS RETURNED TO TASK).
92 ;
93 ; IF SUCCESSFUL COMPLETION:
94 ; CC-C 0
95 ; DIRECTIVE STATUS:
96 ; +1
97 ; BEFORE RETURN, THE ENABLE/DISABLE-INTERRUPTS ROUTINE
98 ; (IF SPECIFIED) IS CALLED IN KERNEL MODE WITH CC-C CLEAR.
99 ;
100 ; IF DIRECTIVE IS REJECTED:
101 ; CC-C 1
102 ; DIRECTIVE STATUS:
103 ; D.RS1 AN ITB COULD NOT BE ALLOCATED (NO POOL SPACE).
104 ; D.RS8 THE FUNCTION REQUESTED IS "DISCONNECT"
105 ; AND THE TASK IS NOT OWNER OF THE VECTOR.
106 ; D.RS16 ISSUING TASK IS NOT PRIVILEGED.
107 ; D.RS17 THE SPECIFIED VECTOR IS ALREADY IN USE.
108 ; D.RS19 THE SPECIFIED VECTOR IS ILLEGAL (LOWER THAN 60
109 ; OR HIGHER THAN HIGHEST VECTOR SPECIFIED AT SYSGEN,
110 ; OR NOT A MULTIPLE OF 4).
111 ; D.RS81 ISR OR ENABLE/DISABLE-INTERRUPT ROUTINE IS NOT
112 ; WITHIN 4K WORDS FROM (BASE ADDRESS & 177700).
113 ;-
114
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-2
115 .IF DF C$$INT
116
117 .ENABL LSB
118
119 $DRCIN::
120
121 .IF DF M$$MGE
122
123 BIT #T3.PRV,T.ST3(R5) ; IS TASK PRIVILEGED?
124 BEQ 95$ ; N - ILLEGAL, JUMP
125
126 .ENDC
127
128
129 MOV (R3)+,R4 ; GET VECTOR ADDRESS
130 BIT #3,R4 ; MULTIPLE OF 4?
131 BNE 60$ ; N - ILLEGAL VECTOR, JUMP
132 CMP R4,#60 ; VECTOR IN RANGE?
133 BLO 60$ ; N - JUMP
134 CMP R4,#V$$CTR
135 BHIS 60$ ; N - JUMP
136 MOV (R3)+,R0 ; GET BASE ADDRESS
137 MOV (R3)+,-(SP) ; GET ISR ADDRESS
138 BEQ 40$ ; ZERO - DISCONNECT, JUMP
139 ;
140 ; DIRECTIVE IS "CONNECT"
141 ;
142
143 .IF NDF E$$NSI
144
145 CMP @R4,#$NONSI ; VECTOR IN USE?
146 BNE 70$ ; Y - ILLEGAL, JUMP
147
148 .IFF
149
150 CMP @R4,#$NS0 ; VECTOR IN USE?
151 BLO 70$ ; Y - ILLEGAL, JUMP
152 CMP @R4,#$NS7
153 BHI 70$ ; Y - ILLEGAL, JUMP
154
155 .ENDC
156
157 10$: BIT #T2.CKD,@R2 ; CHECKPOINTING DISABLED?
158 BNE 15$ ; Y - JUMP
159 BIS #T2.CKD,@R2 ; N - DO IT
160 CLR T.CPCB(R5) ; INITIALIZE LIST OF ITB'S
161 15$:
162
163 .IF DF D$$YNM & D$$SHF
164
165 MOV T.PCB(R5),R1 ; GET PCB
166 BIT #PS.SYS,P.STAT(R1) ; SYSTEM CONTROLLED?
167 BEQ 20$ ; N - JUMP
168 BIS #PS.NSF,P.STAT(R1) ; SET NON-SHUFFLABLE
169 20$:
170
171 .ENDC
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-3
172
173
174 .IF DF M$$MGE
175
176 BIC #77,R0 ; CLEAR LOWER 6 BITS IN BASE ADDRESS
177 CALL $RELOC ; RELOCATE TO APR 6 ADDRESS
178 SUB #20000,R2 ; RELOCATE TO APR 5 ADDRESS
179 BCS 90$ ; OUT OF RANGE - JUMP
180 SUB R0,@SP ; GET DISPLACEMENT FROM "BASE" TO "ISR"
181 CMP @SP,#20000 ; .GT. 4K WORDS?
182 BHIS 90$ ; Y - ILLEGAL, JUMP
183
184 .IFTF
185
186 MOV (R3)+,-(SP) ; GET ENB./DIS.INT. ROUTINE ADDRESS
187
188 .IFT
189
190 BEQ 30$ ; NO SUCH ROUTINE - JUMP
191 SUB R0,@SP ; GET DISPLACEMENT FROM BASE
192 BCS 90$ ; OUT OF RANGE - JUMP
193 CMP @SP,#20000 ; .GT. 4K WORDS?
194 BHIS 90$ ; Y - ILLEGAL, JUMP
195 ADD R2,@SP ; MAKE APR 5 ADDRESSES
196 30$: ADD R2,2(SP)
197 MOV R1,-(SP) ; SAVE APR 5 VALUE
198
199 .IFTF
200
201 MOV #X.LEN,R1 ; GET SIZE OF ITB IN BYTES
202 CALL $ALOCB ; ALLOCATE AN ITB
203 BCS 80$ ; FAILURE - JUMP
204 MOV T.CPCB(R5),@R0 ; LINK ITB TO ITB LIST IN TCB (X.LNK)
205 MOV R0,T.CPCB(R5)
206 TST (R0)+ ; STEP PAST LINK WORD IN ITB
207 MOV R0,R1 ; SAVE INTERRUPT ENTRY POINT
208 MOV #4537,(R0)+ ; "JSR R5,@#$INTSC" (X.JSR)
209 MOV #$INTSC,(R0)+ ; (X.JSR+2)
210 MOV (R3)+,@R0 ; PSW AND UNUSED BYTE (X.PSW)
211
212 .IFT
213
214 ADD #X.REL-X.PSW,R0 ; POINT TO X.REL IN ITB
215 MOV (SP)+,(R0)+ ; STORE APR 5 VALUE (X.REL)
216
217 .IFF
218
219 ADD #X.DSI-X.PSW,R0 ; POINT TO X.DSI IN ITB
220
221 .IFTF
222
223 MOV (SP)+,(R0)+ ; STORE ENB./DIS.INT. ROUTINE ADDRESS (X.DSI)
224 MOV R5,(R0)+ ; STORE TCB ADDRESS (X.TCB)
225 MOV (SP)+,X.ISR-<X.TCB+2>(R0) ; STORE ISR ADDRESS (X.ISR)
226 CLR X.FORK+2-<X.TCB+2>(R0) ; CLEAR FORK PC WORD (X.FORK+2)
227
228 .IF DF A$$TRP
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-4
229
230 MOV #$DQAC,(R0)+ ; STORE ADDRESS OF ROUTINE TO DEQUEUE
231 ; AST BLOCK QUEUED BY $QASTC
232 TST (R0)+ ; STEP PAST AST QUEUE THREAD WORD
233 MOV PC,(R0)+ ; SET NON-ZERO TO INDICATE
234 ; AST BLOCK FREE (A.CBL)
235 MOV #7*2+2,(R0)+ ; NUMBER OF WORDS TO ALLOCATE ON AST STACK
236 ; (A.BYT)
237 MOV @R3,(R0)+ ; AST ADDRESS (A.AST)
238 MOV #1,(R0)+ ; NUMBER OF AST PARAMETERS = 1 (A.NPR)
239
240 .ENDC
241
242 MOV R4,(R0)+ ; AST PARAMETER = VECTOR ADDRESS (X.VEC)
243 MOV @R4,@R0 ; SAVE VECTOR PC (X.VPC)
244 MOV R1,@R4 ; SET VECTOR TO POINT TO ITB
245 TST -(R1) ; BACK UP TO START OF ITB AND CLEAR CC-C
246 35$: MOV X.DSI(R1),R2 ; GET ADDRESS OF USER ROUTINE TO
247 ; ENABLE/DISABLE INTERRUPTS
248 BEQ 130$ ; NONE - EXIT
249
250 .IFT
251
252 MOV X.REL(R1),KISAR5 ; MAP ROUTINE IN KERNEL APR 5
253
254 .ENDC
255
256 CALLR @R2 ; CALL ROUTINE AND RETURN
257 ; R1 = POINTER TO ITB
258 ; CC-C = 0 TO ENABLE INTERRUPTS,
259 ; = 1 TO DISABLE INTERRUPTS
260 ;
261 ;
262 ; DIRECTIVE IS "DISCONNECT"
263 ;
264 40$: MOV @R4,R1 ; GET PC FROM VECTOR
265 SUB #X.JSR,R1 ; GET START OF ITB (X.LNK)
266 BIT #T2.CKD,@R2 ; CHECKPOINTING DISABLED?
267 BEQ 100$ ; N - TASK HAS NO ITB'S, JUMP
268 CALL $DISIN ; DISABLE INTERRUPTS, DEALLOCATE THE
269 ; ITB ETCETERA
270 BCS 100$ ; ERROR (TASK IS NOT OWNER OF VECTOR) - JUMP
271 DRSTS +1 ; EXIT WITH SUCCESS
272
273 60$: DRSTS D.RS19 ; ILLEGAL VECTOR
274 70$: DRSTS D.RS17 ; VECTOR ALREADY IN USE
275 80$: DRSTS D.RS1 ; NO POOL SPACE
276
277 .IF DF M$$MGE
278
279 90$: DRSTS D.RS81 ; ISR OR ENB./DIS.INT. ROUTINE ADDRESS NOT
280 ; WITHIN RANGE (BASE&177700, BASE&177700+4K)
281 95$: DRSTS D.RS16 ; PRIVILEGE VIOLATION
282
283 .ENDC
284
285 100$: DRSTS D.RS8 ; DISCONNECT - TASK IS NOT OWNER OF VECTOR
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-5
286 ;
287 ;
288 ;+
289 ; **-$DISIN-DISCONNECT INTERRUPT VECTOR.
290 ;
291 ; INPUT:
292 ; R1 POINTER TO ITB
293 ; R5 POINTER TO TASK TCB
294 ;
295 ; OUTPUT:
296 ; IF SUCCESS:
297 ; CC-C 0
298 ; THE FOLLOWING OPERATIONS ARE PERFORMED:
299 ; 1. THE ITB IS REMOVED FROM THE ITB LIST STARTING
300 ; IN T.CPCB OF THE TASK'S TCB.
301 ; 2. IF A USER ROUTINE TO DISABLE INTERRUPTS WAS SUPPLIED
302 ; WHEN THE VECTOR WAS CONNECTED TO, THAT ROUTINE IS CALLED
303 ; IN KERNEL MODE WITH CC-C SET.
304 ; 3. VECTOR PC IS RESTORED TO POINT TO THE NONSENSE INTERRUPT ROUTINE.
305 ; 4. IF THE FORK BLOCK OF THE ITB IS IN THE FORK QUEUE, IT
306 ; IS REMOVED.
307 ; 5. IF THE AST BLOCK OF THE ITB IS IN THE AST QUEUE FOR THE TASK,
308 ; IT IS REMOVED.
309 ; 6. IF THIS WAS THE ONLY VECTOR CONNECTED TO THE TASK,
310 ; CHECKPOINTING IS ENABLED FOR THE TASK. IF THE TASK RUNS IN
311 ; A SYSTEM CONTROLLED PARTITION, THE TASK IS MADE SHUFFLABLE.
312 ; 7. FINALLY, THE ITB IS DEALLOCATED.
313 ;
314 ; IF ERROR (TASK IS NOT OWNER OF VECTOR):
315 ; CC-C 1
316 ;
317 ; REGISTERS ALTERED: R0,R1,R2,R3
318 ;-
319 ;
320 ;
321 $DISIN::MOV R5,R0 ; GET TCB
322 ADD #T.CPCB,R0 ; POINT TO ITB LISTHEAD
323 MOV 2(R0),-(SP) ; SAVE WORD FOLLOWING LISTHEAD
324 CALL $QRMVT ; REMOVE FROM ITB LIST
325 MOV (SP)+,2(R0) ; RESTORE WORD FOLLOWING LISTHEAD
326 BCS 130$ ; ITB NOT IN LIST - EXIT WITH ERROR
327 SEC
328 CALL 35$ ; CALL USER ROUTINE TO DISABLE INTERRUPTS
329 ; WITH CC-C SET
330 MOV X.VPC(R1),@X.VEC(R1) ; RESTORE VECTOR PC
331 ADD #X.FORK,R1 ; POINT AT FORK BLOCK IN ITB
332 MOV #$FRKHD,R0 ; GET FORK LISTHEAD
333 MTPS #PR7 ; DISABLE INTERRUPTS
334 CALL $QRMVT ;;; REMOVE FROM FORK LIST IF IT IS THERE
335 MTPS #0 ;;; ENABLE INTERRUPTS
336
337 .IF DF A$$TRP
338
339 ADD #X.AST-X.FORK,R1 ; POINT AT AST BLOCK IN ITB
340 MOV R5,R0
341 ADD #T.ASTL,R0 ; GET AST LIST LISTHEAD
342 CALL $QRMVT ; REMOVE FROM AST LIST IF IT IS THERE
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-6
343 SUB #X.AST,R1 ; RESTORE ITB POINTER
344
345 .IFF
346
347 SUB #X.FORK,R1 ; RESTORE ITB POINTER
348
349 .ENDC
350
351 MOV R1,R0 ; GET ITB POINTER IN R0
352 TST T.CPCB(R5) ; ITB LIST NOW EMPTY?
353 BNE 120$ ; N - JUMP
354 BIC #T2.CKD,T.ST2(R5) ; Y - ENABLE CHECKPOINTING
355
356 .IF DF D$$YNM & D$$SHF
357
358 MOV T.PCB(R5),R1 ; GET PCB
359 BIT #PS.SYS,P.STAT(R1) ; SYSTEM CONTROLLED PARTITION?
360 BEQ 120$ ; N - JUMP
361 BIT #T2.ABO,T.ST2(R5) ; TASK MARKED FOR ABORT?
362 BEQ 110$ ; N - JUMP
363 CMP T.EFLG(R5),#S.PRTY ; Y - IS REASON MEMORY PARITY ERROR?
364 BEQ 120$ ; Y - DON'T MAKE SHUFFLABLE
365 110$: BIC #PS.NSF,P.STAT(R1) ; MAKE SHUFFLABLE
366
367 .ENDC
368
369 120$: MOV #X.LEN,R1 ; GET LENGTH OF ITB
370 CALL $DEACB ; DEALLOCATE ITB
371 CLC ; SUCCESS
372 130$: RETURN
373
374 .DSABL LSB
375
376 .ENDC
377
378
379 000001 .END
DRCIN MACRO M1110 22-AUG-79 06:57 PAGE 3-7
SYMBOL TABLE
AS.DEL= 000010 I.ATTL= 000044 PS = 177776 TPS = 177564 T2.HLT= 000200
AS.EXT= 000004 I.EFN 000003 PS.APR= 000007 TS.BLK= 170700 T2.SPN= 000004
AS.RED= 000001 I.FCN 000012 PS.CHK= 010000 TS.CKP= 000200 T2.STP= 000020
AS.WRT= 000002 I.IOSB 000014 PS.CKP= 040000 TS.CKR= 000100 T2.TIO= 001000
A$$CHK= 000000 I.LGTH= 000044 PS.CKR= 020000 TS.EXE= 100000 T2.WFR= 000001
A$$CPS= 000000 I.LNK 000000 PS.COM= 000200 TS.MSG= 020000 T3.ACP= 100000
A$$TRP= 000000 I.LN2 000006 PS.DEL= 000010 TS.NRP= 010000 T3.CAL= 000100
A.AST 000006 I.PRI 000002 PS.DRV= 000020 TS.OUT= 000400 T3.CLI= 001000
A.BYT 000004 I.PRM 000024 PS.FXD= 004000 TS.RDN= 040000 T3.MCR= 004000
A.CBL 000002 I.TCB 000004 PS.LIO= 001000 TS.RUN= 004000 T3.NET= 000020
A.DQSR 177776 I.UCB 000010 PS.NSF= 000400 T.ACTL 000052 T3.NSD= 000200
A.IOC 000003 KDSAR0= 172360 PS.OUT= 100000 T.ASTL 000016 T3.PMD= 040000
A.KSR5 177774 KDSDR0= 172320 PS.PER= 002000 T.ATT 000054 T3.PRV= 010000
A.LGTH= 000014 KISAR0= 172340 PS.PIC= 000100 T.CPCB 000004 T3.REM= 020000
A.MPCT 000011 KISAR5= 172352 PS.SYS= 000040 T.DPRI 000040 T3.ROV= 000040
A.NPR 000010 KISAR6= 172354 P$$RTY= 000000 T.EFLG 000022 T3.RST= 000400
A.PCB 000012 KISAR7= 172356 P$$TPT= 000000 T.IOC 000003 T3.SLV= 002000
A.PCBL 000000 KISDR0= 172300 P.BLKS 000016 T.LBN 000041 UBMPR = 170200
A.PRI 000002 KISDR6= 172314 P.BUSY 000024 T.LDV 000044 UDSAR0= 177660
A.PRM 000012 KISDR7= 172316 P.IOC 000003 T.LNK 000000 UDSDR0= 177620
A.STAT 000010 K$$CNT= 177546 P.LNK 000000 T.MXSZ 000050 UISAR0= 177640
A.TCB 000004 K$$CSR= 177546 P.MAIN 000012 T.NAM 000006 UISAR4= 177650
A.TCBL 000006 K$$IEN= 000115 P.NAM 000004 T.OFF 000060 UISAR5= 177652
CMODE = 140000 K$$LDC= 000001 P.OWN 000026 T.PCB 000046 UISAR6= 177654
C$$ORE= 002000 K$$TPS= 000074 P.PRI 000002 T.PRI 000002 UISAR7= 177656
FE.CAL= 000040 L$$ASG= 000000 P.REL 000014 T.RCVL 000012 UISDR0= 177600
FE.CEX= 020000 L$$DRV= 000000 P.SIZE 000016 T.RRFL 000064 UISDR4= 177610
FE.DRV= 000010 MPAR = 172100 P.STAT 000030 T.SRCT 000063 UISDR5= 177612
FE.EXP= 000200 MPCSR = 177746 P.SUB 000010 T.STAT 000032 UISDR6= 177614
FE.EXT= 000001 M$$CRB= 000124 P.SWSZ 000022 T.ST2 000034 UISDR7= 177616
FE.EXV= 000004 M$$MGE= 000000 P.TCB 000026 T.ST3 000036 V$$CTR= 001200
FE.LSI= 000400 M$$NET= 000000 P.WAIT 000020 T.TCBL 000030 V$$RSN= 000031
FE.MUP= 000002 M$$NT2= 000000 R$$DER= 000000 T.UCB 000026 X$$DBT= 000000
FE.MXT= 040000 N$$LDV= 000001 R$$EXV= 000000 T2.ABO= 000100 X.DSI 000024
FE.NLG= 100000 PIRQ = 177772 R$$SND= 000000 T2.AST= 100000 X.FORK 000012
FE.PKT= 000100 PMODE = 030000 R$$11M= 000000 T2.BFX= 004000 X.ISR 000010
FE.PLA= 000020 PR0 = 000000 R$$11S= 000000 T2.CAF= 000400 X.JSR 000002
G$$TPP= 000000 PR1 = 000040 SISDR0= 172200 T2.CHK= 020000 X.LNK 000000
G$$TTK= 000000 PR4 = 000200 SR0 = 177572 T2.CKD= 010000 X.PSW 000006
H$$RTZ= 000074 PR5 = 000240 SR3 = 172516 T2.DST= 040000 X.REL 000022
I$$RDN= 000000 PR6 = 000300 SWR = 177570 T2.FXD= 002000 X.TCB 000026
I.AST 000022 PR7 = 000340 S$$YSZ= 001740
. ABS. 177776 000
000000 001
ERRORS DETECTED: 0
VIRTUAL MEMORY USED: 3925 WORDS ( 16 PAGES)
DYNAMIC MEMORY: 5092 WORDS ( 19 PAGES)
ELAPSED TIME: 00:00:18
[11,24]DRCIN,SY0:[11,34]DRCIN/-SP=[1,1]EXEMC/ML,[11,10]RSXMC/PA:1,DRCIN