Trailing-Edge
-
PDP-10 Archives
-
BB-H506E-SM
-
sort/source/autsrt.ctl
There are no other files named autsrt.ctl in the archive.
!AUTSRT.CTL VERSION 4C
!USED TO MAKE COBOL, FORTRAN, AND STAND-ALONE SORT FOR VALIDATING AUTOPATCH
!THIS FILE RUNS ON EITHER TOPS-20 OR TOPS-10
!SUBMIT WITH COMMAND SUBMIT SORT/TIME:0:30:00/RESTART:YES
!
!IF ANY NON-STANDARD ASSEMBLY SWITCHES ARE DESIRED THEY SHOULD BE
! INSERTED IN SRTPRM.MAC
!
!INSTALLATION SPECIFIC ASSIGNMENTS SHOULD BE PUT IN THE FOLLOWING FILE:
! ON TOPS-20 IN A TAKE FILE AUTSRT.CMD
! ON TOPS-10 IN A MIC FILE AUTSRT.MIC
!NOTE, IN GENERAL THIS CONTROL FILE WILL NOT RUN WITHOUT ONE OF THE ABOVE
!DEFINITION FILES BEING PRESENT.
!
!IF LISTINGS ARE DESIRED, THE EMPTY FILE
!LISTEM.MAC SHOULD BE IN DSK:.
!
!THIS CONTROL FILE BY DEFAULT CREATES:
! STAND-ALONE SORT,
! COBOL SORT, AND
! FORTRAN SORT.
START::
! TEST FOR WHICH SYSTEM
@GOTO TOPS20 !TOPS20 VERSION
.GOTO TOPS10 !TOPS10 VERSION
TOPS20::
@SET TRAP FILE
@CHKPNT START::
! REQUIRED FILES:
! SYS: MACRO.EXE
! CREF.EXE
! LINK.EXE
! MACTEN.UNV
! MACSYM.UNV
! MONSYM.UNV
! MACREL.REL (IF COBOL)
!
! PA1050.EXE
!
! DSK: AUTSRT.CTL
! SORT20.VER - Contains the operating system flag.
!
! SORT SOURCES
! DSK: SORT.MAC SRTPRM.MAC SRTSTA.MAC
! SRTCMD.MAC SRTJSS.MAC SRTCMP.MAC
! SRTFLT.MAC SRTCBL.MAC SRTCER.MAC
! FORSRT.MAC
!
! COBOL FILES FROM VERSION 12B RELEASE
! UNV: FTDEFS.UNV
! METUNV.UNV
! SET UP THE DEFAULTS
@ERROR
@TAKE AUTSRT.CMD
@IF (ERROR) !IGNORE IT
!
! MAKE A RECORD OF WHAT IS BEING USED
!
@GET SYS:MACRO
@INFO VERSION
@GET SYS:LINK
@INFO VERSION
@GET SYS:CREF
@INFO VERSION
@GET SYS:PA1050
@INFO VERSION
!
! GET CHECKSUMS SO WE KNOW WHAT WE HAVE
! FIRST THE SYSTEM SOFTWARE
!
@VD SYS:MACRO.EXE,SYS:LINK.EXE,SYS:PA1050.EXE,SYS:CREF.EXE,UNV:MACTEN.UNV,UNV:MACSYM.UNV,UNV:MONSYM.UNV,SYS:MACREL.REL,
@CHECK SEQ
@
! NEXT THE SORT SOURCES
!
@VD SORT.MAC,SRT*.MAC,FORSRT.MAC,AUTSRT.CTL,AUTSRT.CMD,
@CHECK SEQ
@
! AND FINALLY THE COBOL FILES
!
@VD UNV:FTDEFS.UNV,UNV:METUNV.UNV,
@CHECK SEQ
@
! CREATE STAND-ALONE SORT.
!
@ERROR %
@DIR LISTEM.MAC
@IF (ERROR) @GOTO NOLIST !CREF NOT WANTED
!
@ERROR
@MACRO
*SORT,SORT/C=SORT20.VER,SRTPRM,SRTSTA,SRTCMD,SRTJSS,SRTCER,SRTCMP,SRTFLT,SORT
@IF (ERROR) @GOTO TRUBLE
!
@CREF
*DSK:SORT.LZT=SORT
@IF (ERROR) @GOTO TRUBLE
@GOTO DONCRF
!
NOLIST::
@ERROR
@MACRO
*SORT=SORT20.VER,SRTPRM,SRTSTA,SRTCMD,SRTJSS,SRTCER,SRTCMP,SRTFLT,SORT
@IF (ERROR) @GOTO TRUBLE
!
DONCRF::
@LINK
*SORT.MAP/MAP=SORT,/SYMSEG:HIGH/GO
@IF (ERROR) @GOTO TRUBLE
@INFO MEM
!
! NOW SAVE IT.
!
@SAVE DSK:SORT
@IF (ERROR) @GOTO TRUBLE
@! GET TO MONITOR LEVEL
@GOTO COBOL
!
TRUBLE::@PLEASE -- STAND-ALONE SORT CREATION UNSUCCESSFUL
@GOTO FAIL
TOPS10::
.CHKPNT START::
! REQUIRED FILES:
! SYS: PIP.EXE (LATEST RELEASED VERSIONS)
! TECO.EXE
! MACRO.EXE
! DIRECT.EXE
! CREF.EXE
! COMPIL.EXE
! LINK.EXE+LNK???.EXE
! SCAN.REL
!
! REL: HELPER.REL
!
! UNV: MACTEN.UNV
! UUOSYN.UNV
! SCNMAC.UNV
!
! DSK: AUTSRT.CTL
! AUTSRT.MIC
! SORT10.VER - Contains the operating system flag.
! FSORT.VER - Contains the o/s flag as well as V/M flag.
!
! SORT SOURCES
! DSK: SORT.MAC SRTPRM.MAC SRTSTA.MAC
! SRTUUO.MAC SRTSCN.MAC SRTCMP.MAC
! SRTFLT.MAC SRTCBL.MAC SRTCER.MAC
! SRTFOR.MAC
!
! COBOL FILES FROM VERSION 12B RELEASE
! UNV: FTDEFS.UNV
! METUNV.UNV
.ERROR
! SET UP THE DEFAULT LOGICAL NAMES
.DO AUTSRT.MIC
.IF (ERROR) !IGNORE IT
!
! MAKE A RECORD OF WHAT IS BEING USED
!
.R DIRECT
*TTY:/CHECKSUM=SYS:PIP+MACRO+DIRECT+CREF+LINK+LNK???+TECO
*TTY:/CHECKSUM=REL:HELPER.REL+SYS:SCAN.REL+UNV:MACTEN.UNV+UUOSYM.UNV+SCNMAC.UNV
*TTY:/CHECKSUM=DSK:SORT.*
*TTY:/CHECKSUM=DSK:SORT.MAC+SRT???.MAC
*TTY:/CHECKSUM=UNV:FTDEFS.UNV+METUNV.UNV
! CREATE STAND-ALONE SORT.
!
.ERROR %
.DIR LISTEM.MAC
.IF (ERROR) .GOTO NOLIST !CREF NOT WANTED
!
.ERROR
.R MACRO
*SORT,SORT/C=SORT10.VER,SRTPRM,SRTSTA,SRTSCN,SRTUUO,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
.R CREF
*DSK:SORT.LZT=SORT
.IF (ERROR) .GOTO TRUBLE
.GOTO DONCRF
!
NOLIST::
.ERROR
.R MACRO
*SORT=SORT10.VER,SRTPRM,SRTSTA,SRTSCN,SRTUUO,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
.R LINK
*SORT.MAP/MAP=SORT,-
*SYS:SCAN/SEGMENT:LOW/INCLUDE:(.VERBO,.TOUTS,.SAVE),-
*SYS:SCAN/EXCLUDE:(.VERBO,.TOUTS,.SAVE,$SCNDC),-
*REL:HELPER/G
.IF (ERROR) .GOTO TRUBLE
.SSAVE SORT
.IF (ERROR) .GOTO TRUBLE
!
.! GET TO MONITOR LEVEL
.GOTO COBOL
!
TRUBLE::.PLEASE -- STAND-ALONE SORT CREATION UNSUCCESSFUL.^[
.GOTO FAIL
COBOL:: ! NOW FOR COBOL.
!
! TEST FOR WHICH SYSTEM
@GOTO TOPS20 !TOPS20 VERSION
.GOTO TOPS10 !TOPS10 VERSION
!
TOPS20::
@CHKPNT COBOL::
! SET UP THE DEFAULTS
!
@ERROR
@TAKE AUTSRT.CMD
@IF (ERROR) !IGNORE IT
!
! ASSEMBLE SOURCES
!
@ERROR %
@DIR LISTEM.MAC
@IF (ERROR) @GOTO NOLIST !CREF NOT WANTED
!
@ERROR
@MACRO
*SRTCBL,SRTCBL/C=SORT20.VER,SRTPRM,SRTCBL,SRTCER,SRTJSS,SORT
@IF (ERROR) @GOTO TRUBLE
!
! CREATE LISTINGS.
!
@CREF
*DSK:SRTCBL.LZT=SRTCBL
@IF (ERROR) @GOTO TRUBLE
@GOTO DONCRF
!
NOLIST::
@ERROR
@MACRO
*SRTCBL=SORT20.VER,SRTPRM,SRTCBL,SRTCER,SRTJSS,SORT
@IF (ERROR) @GOTO TRUBLE
!
DONCRF::
@GOTO FORTRA
!
TRUBLE::@PLEASE -- COBOL SORT CREATION UNSUCCESSFUL!!!
@GOTO FAIL
TOPS10::
.CHKPNT COBOL::
.ERROR
! SET UP THE DEFAULT LOGICAL NAMES
! CHANGE THEM IF USER SO DESIRES
.DO AUTSRT.MIC
.IF (ERROR) !IGNORE IT
!
! ASSEMBLE SOURCES WITH LISTINGS.
!
.ERROR %
.DIR LISTEM.MAC
.IF (ERROR) .GOTO NOLIST !CREF NOT WANTED
!
.ERROR
.R MACRO
*SRTCBL,SRTCBL/C=SORT10.VER,SRTPRM,SRTCBL,SRTCER,SRTUUO,SORT
.IF (ERROR) .GOTO TRUBLE
!
! CREATE LISTINGS.
!
.R CREF
*DSK:SRTCBL.LZT=SRTCBL
.IF (ERROR) .GOTO TRUBLE
.GOTO DONCRF
!
NOLIST::
.ERROR
.R MACRO
*SRTCBL=SORT10.VER,SRTPRM,SRTCBL,SRTCER,SRTUUO,SORT
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
.GOTO FORTRA
!
TRUBLE::.PLEASE -- COBOL SORT CREATION UNSUCCESSFUL.^[
.GOTO FAIL
FORTRA:: ! NOW FOR FORTRAN.
!
! TEST FOR WHICH SYSTEM
@GOTO TOPS20 !TOPS20 VERSION
.GOTO TOPS10 !TOPS10 VERSION
!
TOPS20::
@CHKPNT FORTRA::
!
@GOTO FINISH !FORSRT PART OF FORTRAN RELEASE NOW
TOPS10::
.CHKPNT FORTRA::
.ERROR
! SET UP THE DEFAULT LOGICAL NAMES
! CHANGE THEM IF USER SO DESIRES
.DO AUTSRT.MIC
.IF (ERROR) !IGNORE IT
!
! ASSEMBLE SOURCES
!
.ERROR %
.DIR LISTEM.MAC
.IF (ERROR) .GOTO NOLIST !CREF NOT WANTED
!
.ERROR
.R MACRO
*SRTFOR,SRTFOR/C=SORT10.VER,SRTPRM,SRTFOR,SRTSTA,SRTSCN,SRTUUO,SRTCER,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
! CREATE LISTINGS.
!
.R CREF
*DSK:SRTFOR.LZT=SRTFOR
.IF (ERROR) .GOTO TRUBLE
.GOTO DONCRF
!
NOLIST::
.ERROR
.R MACRO
*SRTFOR=SORT10.VER,SRTPRM,SRTFOR,SRTSTA,SRTSCN,SRTUUO,SRTCER,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
.GOTO VMSORT
VMSORT::
.CHKPNT VMSORT::
! SET UP THE DEFAULTS
!
.ERROR
.DO AUTSRT.MIC
.IF (ERROR) !IGNORE IT
!
! CREATE TOPS-10 V/M STAND-ALONE SORT.
!
.ERROR %
.DIR LISTEM.MAC
.IF (ERROR) .GOTO NOLIST !CREF NOT WANTED
!
.ERROR
.R MACRO
*FSORT,FSORT/C=FSORT.VER,SRTPRM,SRTSTA,SRTSCN,SRTUUO,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
.R CREF
*DSK:FSORT.LZT=FSORT
.IF (ERROR) .GOTO TRUBLE
.GOTO DONCRF
!
NOLIST::
.ERROR
.R MACRO
*FSORT=FSORT.VER,SRTPRM,SRTSTA,SRTSCN,SRTUUO,SRTCMP,SRTFLT,SORT
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
.R LINK
*FSORT.MAP/MAP=FSORT,-
*SYS:SCAN/SEGMENT:HIGH,-
*REL:HELPER/G
.IF (ERROR) .GOTO TRUBLE
.SSAVE FSORT
.IF (ERROR) .GOTO TRUBLE
!
.GOTO FINISH
!
TRUBLE::.PLEASE -- FORTRAN SORT CREATION UNSUCCESSFUL.^[
.GOTO FAIL
^L
FINISH::
!
! TEST FOR WHICH SYSTEM
@GOTO TOPS20 !TOPS20 VERSION
.GOTO TOPS10 !TOPS10 VERSION
!
TOPS20::
@CHKPNT FINISH::
! SET UP THE DEFAULTS
!
@ERROR
@TAKE AUTSRT.CMD
@IF (ERROR) !IGNORE IT
!
! SEE WHAT WE GOT.
!
@VD SORT.*,SRTCBL.REL,
@CHECK SEQ
@
!
! TELL OPERATOR HOW WE DID.
!
@PLEASE -- SORT CREATION SUCCESSFUL
@! GET TO MONITOR LEVEL
@GOTO OK
TOPS10::
.CHKPNT FINISH::
.ERROR
! SET UP THE DEFAULT LOGICAL NAMES
!
.DO AUTSRT.MIC
.IF (ERROR) !IGNORE IT
!
! SEE WHAT WE GOT.
!
.R DIRECT
*TTY:/CHECKSUM=SORT.*+SRTCBL.REL+SRTFOR.REL+FSORT.EXE
!
! TELL OPERATOR HOW WE DID.
!
.PLEASE -- SORT CREATION SUCCESSFUL.^[
.! GET TO MONITOR LEVEL
.GOTO OK
FAIL::
OK::! END OF AUTSRT.CTL