! UPD ID= 3336 on 1/13/81 at 10:08 AM by NIXON                          
!DBMS.CTL	VERSION 5
!
!USED TO LOAD SCHEMA PROCESSOR, FORTRAN PRE-PROCESSOR, DBINFO,
!DBMEND, DAEMDB, FORTRAN RUN-TIME SYSTEM, COBOL RUN-TIME SYSTEM
!
!*****     WARNING---THIS CTL FILE IS USED TO BUILD DBMS ON
!                    THE DEVELOPMENT SYSTEMS IN MARLBORO. IT IS NOT
!                    GAURANTEED TO RUN ON ANY OTHER SYSTEM. THE USER
!                    SHOULD CHECK THIS CTL FILE FOR ANY INSTALLATION
!                    DEPENDENT ITEMS.
!
!THIS FILE RUNS ON EITHER TOPS-20 OR TOPS-10 ON ALL SUPPORTED MONITORS
!SUBMIT WITH COMMAND	SUBMIT DBMS/TIME:1:0:0
!
!THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
!  OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
!
!COPYRIGHT (C) 1979, 1981 BY DIGITAL EQUIPMENT CORPORATION
!
!
!INSTALLATION SPECIFIC ASSIGNMENTS SHOULD BE PUT IN THE FOLLOWING FILE:
! ON TOPS-20 IN A TAKE FILE DBMS.CMD
! ON TOPS-10 IN A MIC  FILE DBMS.MIC
!	  OR IN A TECO FILE DBMS.TEC
!NOTE, IN GENERAL THIS CONTROL FILE WILL NOT RUN WITHOUT ONE OF THE ABOVE
!DEFINITION FILES BEING PRESENT.
!
!TEST FOR WHICH SYSTEM
@GOTO TOPS20	!TOPS20 VERSION
.GOTO TOPS10	!TOPS10 VERSION
TOPS20::
!
!REQUIRED FILES:
!<FIELD-IMAGE>	MAKLIB		(LATEST RELEASED VERSIONS)
!		LINK
!<REL>		SCAN.REL	WILD.REL	HELPER.REL
!<RELEASE 4>	MACREL.REL
![SELF]:	DBSANY.REL	DBS20.REL	DBSFOR.REL	DBSCOB.REL
!		GENME2.REL	GENMS2.REL	GENIO2.REL
!		DBMS20.CTL	DBS052.RND
!		SCHEMA.CMD	SCHEMA.HLP
!		FORDM2.CMD	FORDML.HLP
!		DBMEN2.CMD	DBMEND.HLP
!		DBINF2.CMD	DBINFO.HLP
!		DAEMD2.CMD	DAEMDB.HLP
!		DBCS2C.CMD	DBCS2F.CMD
!		DDLANY.REL	DDL20.REL
!		FMLANY.REL	FML20.REL
!		MNDANY.REL	MND20.REL
!		INFANY.REL	INF20.REL
!		DABANY.REL	DAB20.REL
!		STRLIB.REL	SCHIO2.REL
!		L12B6D.CMD	L12B7D.CMD
!
!
!*****	EXAMINE SECTION 6 OF DBMS20.DOC BEFORE SUBMITTING THIS CTL FILE.
!	IF APPLICABLE REBUILD COBOL, LIBOL AND/OR FOROTS BEFORE RUNNING THIS CTL FILE
!*****	IMPORTANT:
!	THE DISTRIBUTED .LOG FILE FOR THIS .CTL FILE DOES BUILD
!	BOTH A FOROTS AND A LIBOL, BUT THERE IS NO INTENT THAT A USER INSTALLATION
!	BUILD IDENTICAL COPIES OF THESE HOST-SYSTEMS.
!	THE INTENT IS TO DEMONSTRATE THAT THE PROCESS OF BUILDING FOROTS
!	AND LIBOL IS VALID.
!
!***** IF YOU DESIRE COBOL-68 DBMS-20 SUPPORT, YOU MUST INCLUDE
!	A COPY OF THE LATEST RELEASED LIBOL.REL AND LIBSHR.REL IN COBOL-68-BUILD:.
!
!***** IF YOU DESIRE COBOL-74 DBMS-20 SUPPORT, YOU MUST INCLUDE
!	A COPY OF THE LATEST RELEASED C74LIB.REL AND C74SHR.REL IN COBOL-74-BUILD:.
!
!***** IF YOU WISH TO BUILD A FORTRAN-20/DBMS-20 RUN-TIME SYSTEM, YOU
!      MUST INCLUDE A COPY OF THE LATEST RELEASED FORLIB.REL IN YOUR AREA.
!
!
!OUTPUT:	SCHEMA.EXE	FORDML.EXE	DBMEND.EXE	DBINFO.EXE	DAEMDB.EXE
!		SCHEMA.MAP	FORDML.MAP	DBMEND.MAP	DBINFO.MAP	DAEMDB.MAP
!
! IF BUILDING A COBOL-68 SYSTEM:	LIBO12.EXE,LIBOL.MAP, AND LIBOL.REL
! IF BUILDING A COBOL-74 SYSTEM:	C74O12.EXE,C74OTS.MAP, AND C74LIB.REL
! IF BUILDING A FORTRAN  SYSTEM:	FDBOTS.EXE,FDBOTS.MAP, AND FORLIB.REL
!
!OUTPUT LISTINGS:		DBMS20.LOG, DBMS20.DOC(3), *.MAP
!USE LATEST RELEASED SOFTWARE
!
@TAKE DBMS.CMD
@IF (ERROR) !IGNORE IT
!
!MAKE A RECORD OF WHAT IS BEING USED

@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION

@VDIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,
@CHECKSUM SEQUENTIAL
@
@VDIRECT DEC:SCAN.REL,DEC:WILD.REL,DEC:HELPER.REL,
@CHECKSUM SEQUENTIAL
@

@VDIRECT DBS*.REL,SCHIO2.REL,DBCS2%.CMD,*.HLP,
@CHECKSUM SEQUENTIAL
@

@IF (ERROR) @GOTO TRUBLE
@GOTO QCOBOL
DBALL::
!
!MAKE A RECORD OF WHAT IS BEING USED

@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION

@DIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,
@CHECKSUM SEQUENTIAL
@
@DIRECT DEC:SCAN.REL,DEC:WILD.REL,DEC:HELPER.REL,
@CHECKSUM SEQUENTIAL
@

@DIRECT DDL*.REL,FML*.REL,MND*.REL,DBS*.REL,INF*.REL,DAB*.REL,GEN*.REL,STRHI.REL,SCHIO2.REL,%%%%%2.CMD,DBCS2%.CMD,*.HLP,
@CHECKSUM SEQUENTIAL
@

@IF (ERROR) @GOTO TRUBLE
!CREATE SCHEMA PROCESSOR
!
@LINK
*@SCHEM2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:SCHEMA
@IF (ERROR) @GOTO TRUBLE
!
!CREATE FORTRAN PRE-PROCESSOR
!
@LINK
*@FORDM2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FORDML
@IF (ERROR) @GOTO TRUBLE
!
!CREATE BACKUP/RECOVERY UTILITY
!
@LINK
*@DBMEN2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMEND
@IF (ERROR) @GOTO TRUBLE
!
!CREATE INFO-GENERATING UTILITY
!
@LINK
*@DBINF2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBINFO
@IF (ERROR) @GOTO TRUBLE
!
!CREATE BACKGROUND MTA JOURNALING FACILITY
!
@LINK
*@DAEMD2
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DAEMDB
@IF (ERROR) @GOTO TRUBLE
QCOBOL::
!BUILD COBOL-68 INTERFACE IF LIBOL.REL IS AVAILABLE
!
@ERROR %
@DIRECT LIBOL.REL
@IF (ERROR) @GOTO NOCOB
@ERROR
!
@MAKLIB
*LIBOL=LIBOL/DELETE:RESOLV
*LIBOL=LIBOL/DELETE:RSVGAT
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*LIBOL=LIBOL/INDEX
@DEL COBFUN.TMP
!
@LINK
*@L12B6D.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:LIBO12 0 1,500 575,600 675
@IF (ERROR) @GOTO TRUBLE
!
!RENAME THE COBOL-68 FILES BACK TO THE COBOL-68 BUILD AREA
@RENAME LIBOL.REL COBOL-68-BUILD:LIBOL.REL
@IF (ERROR)!
@RENAME LIBO12.EXE COBOL-68-BUILD:LIBO12.EXE
@IF (ERROR)!
@RENAME LIBOL.MAP COBOL-68-BUILD:LIBOL.MAP
@IF (ERROR)!
!!!	LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
@IF (ERROR)!
!
NOCOB::
@ERROR
QCBL74::
!BUILD COBOL-74 INTERFACE IF C74LIB.REL IS AVAILABLE
!
@ERROR %
@DIRECT C74LIB.REL
@IF (ERROR) @GOTO NOC74
@ERROR
!
@MAKLIB
*C74LIB=C74LIB/DELETE:RESOLV
*C74LIB=C74LIB/DELETE:RSVGAT
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*C74LIB=C74LIB/INDEX
@DEL COBFUN.TMP
!
@LINK
*@L12B7D.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:C74O12 0 1,500 575,600 675
@IF (ERROR) @GOTO TRUBLE
!
!RENAME THE COBOL-74 FILES BACK TO THE COBOL- BUILD AREA
@RENAME C74LIB.REL COBOL-74-BUILD:C74LIB.REL
@IF (ERROR)!
@RENAME C74O12.EXE COBOL-74-BUILD:C74O12.EXE
@IF (ERROR)!
@RENAME C74OTS.MAP COBOL-74-BUILD:C74OTS.MAP
@IF (ERROR)!
!!!	LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
@IF (ERROR)!
NOC74::
@ERROR
QFORT::
!BUILD FORTRAN INTERFACE IF FORLIB.REL IS AVAILABLE
!
@ERROR %
@DIRECT FORLIB.REL
@IF (ERROR) @GOTO NOFORT
@ERROR
!
@MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFOR/APPEND,DBS20/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB/INDEX
!
@LINK
*@DBCS2F
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FDBOTS
@IF (ERROR) @GOTO TRUBLE
!!!	LIBRARIES SO BIG MAKE SURE OLD COPY WENT AWAY
@EXPUNGE
NOFORT::
@ERROR
!
!HAVE BUILT EVERYTHING, NOW CLEANUP
!
!SEE WHAT WE GOT
!
@DIRECT SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,DAEMDB.*,%DBOTS.*,LIBOL.REL,FORLIB.REL,
@CHECKSUM SEQUENTIAL
@
!
!TELL HOW WE DID
!
@PLEASE -- DBMS-20 CREATION SUCCESSFUL!!!
@GOTO ENDOF

TRUBLE::
@PLEASE -- DBMS-20 CREATION NOT SUCCESSFUL???
@GOTO ENDOF
TOPS10::
!REQUIRED FILES:
!SYS:		PIP		(LATEST RELEASED VERSIONS)
!		DIRECT
!		CREF
!		MAKLIB
!		LINK+LNK*
!		SCAN.REL
!		WILD.REL
!		HELPER.REL
!
![SELF]:	DBSANY.REL	DBS10.REL	DBSFOR.REL	DBSCOB.REL
!		GENME1.REL	GENMS1.REL	GENIO1.REL
!		DBMS10.CTL	DBS051.RND
!		SCHEMA.CMD	SCHEMA.HLP
!		FORDM1.CMD	FORDML.HLP
!		DBMEN1.CMD	DBMEND.HLP
!		DBINF1.CMD	DBINFO.HLP
!		DAEMD1.CMD	DAEMDB.HLP
!		DBCS1C.CMD	DBCS1F.CMD
!		DDLANY.REL	DDL10.REL
!		FMLANY.REL	FML10.REL
!		MNDANY.REL	MND10.REL
!		INFANY.REL	INF10.REL
!		DABANY.REL	DAB10.REL
!		STRHI.REL	SCHIO1.REL
!
!
!*****	EXAMINE SECTION 6 OF DBMS10.DOC BEFORE SUBMITTING THIS CTL FILE.
!	IF APPLICABLE REBUILD COBOL, LIBOL AND/OR FOROTS BEFORE RUNNING THIS CTL FILE
!
!***** IF YOU DESIRE COBOL-68 DBMS-10 SUPPORT, YOU MUST INCLUDE
!	A COPY OF THE LATEST RELEASED LIBOL.REL AND LIBSHR.REL IN YOUR AREA.
!
!***** IF YOU DESIRE COBOL-74 DBMS-10 SUPPORT, YOU MUST INCLUDE
!	A COPY OF THE LATEST RELEASED C74LIB.REL AND C74SHR.REL IN YOUR AREA.
!
!
!***** IF YOU WISH TO BUILD A FORTRAN-10/DBMS-10 RUN-TIME SYSTEM, YOU
!      MUST INCLUDE A COPY OF THE LATEST RELEASED FORLIB.REL IN YOUR AREA.
!
!
!OUTPUT:	SCHEMA.EXE	FORDML.EXE	DBMEND.EXE	DBINFO.EXE	DAEMDB.EXE
!		SCHEMA.MAP	FORDML.MAP	DBMEND.MAP	DBINFO.MAP	DAEMDB.MAP
!
! IF BUILDING A COBOL-68 SYSTEM:	LIBO12.EXE,LIBOL.MAP, AND LIBOL.REL
! IF BUILDING A COBOL-74 SYSTEM:	C74O12.EXE,C74OTS.MAP, AND C74LIB.REL
! IF BUILDING A FORTRAN  SYSTEM:	FDBOTS.EXE,FDBOTS.MAP, AND FORLIB.REL
!
!OUTPUT LISTINGS:		DBMS10.LOG, DBMS10.DOC(3), *.MAP
!
! ****	WILL BUILD JUST THE DESIRED OTS'S
.SET WATCH VERSION
!SET UP THE DEFAULT LOGICAL NAMES
!
.DO DBMS.MIC
.IF (ERROR) !IGNORE IT

.R DIRECT
*TTY:/CHECKSUM=SYS:DIRECT+MAKLIB+LINK+LNK*+SCAN.REL+WILD.REL+HELPER.REL

.R DIRECT
*TTY:/CHECKSUM=DBS*.REL,SCHIO1.REL,DBS051.RND,DBMS10.CTL,DBCS1?.CMD,*.HLP
.IF (ERROR) .GOTO TRUBLE
.GOTO	QCOBOL

! ****	CAUSE ALL THE SOFTWARE TO BE REBUILT BY SPECIFYING /TAG:DBALL
DBALL::
.SET WATCH VERSION
.DO DBMS.MIC
.IF (ERROR) !IGNORE IT

.R DIRECT
*TTY:/CHECKSUM=SYS:DIRECT+MAKLIB+LINK+LNK*+SCN7.REL+WILD.REL+HELPER.REL

.R DIRECT
*TTY:/CHECKSUM=DDL*.REL,FML*.REL,MND*.REL,DBS*.REL,DAB*.REL,INF*.REL,GEN*.REL,STRHI.REL,SCHIO1.REL,DBS051.RND,DBMS10.CTL,?????1.CMD,DBCS1?.CMD,*.HLP
.IF (ERROR) .GOTO TRUBLE
!CREATE SCHEMA PROCESSOR
!
.R LINK
*@SCHEM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:SCHEMA
.IF (ERROR) .GOTO TRUBLE
!
!CREATE FORTRAN PRE-PROCESSOR
!
.R LINK
*@FORDM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:FORDML
.IF (ERROR) .GOTO TRUBLE
!
!CREATE BACKUP/RECOVERY UTILITY
!
.R LINK
*@DBMEN1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBMEND
.IF (ERROR) .GOTO TRUBLE
!
!CREATE INFO-GENERATING UTILITY
!
.R LINK
*@DBINF1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBINFO
.IF (ERROR) .GOTO TRUBLE
!
!CREATE BACKGROUND MTA FACILITY
!
.R LINK
@DAEMD1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DAEMDB
.IF (ERROR) .GOTO TRUBLE
!
QCOBOL::
!BUILD COBOL INTERFACE IF LIBOL.REL IS AVAILABLE
!
.ERROR %
.R DIRECT
*TTY:=LIBOL.REL
.IF (ERROR) .GOTO NOCOB
.ERROR
!
.R MAKLIB
*LIBOL=LIBOL/DELETE:RESOLV
*LIBOL=LIBOL/DELETE:RSVGAT
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS10/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*LIBOL=LIBOL/INDEX
.DEL COBFUN.TMP
!
.R LINK
*LIBO12.MAP/MAP=LIBSHR,LIBOL/SEARCH/GO
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:LIBO12
.IF (ERROR) .GOTO TRUBLE
NOCOB::
.ERROR
!
QCBL74::
!BUILD COBOL-74 INTERFACE IF C74LIB.REL IS AVAILABLE
!
.ERROR %
.R DIRECT
*TTY:=C74LIB.REL
.IF (ERROR) .GOTO NOC74
.ERROR
!
.R MAKLIB
*C74LIB=C74LIB/DELETE:RESOLV
*C74LIB=C74LIB/DELETE:RSVGAT
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS10/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*C74LIB=C74LIB/INDEX
.DEL COBFUN.TMP
!
.R LINK
*C74OTS.MAP/MAP=C74SHR,C74LIB/SEARCH/GO
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:C74O12
.IF (ERROR) .GOTO TRUBLE
NOC74::
.ERROR
!
QFORT::
!BUILD FORTRAN INTERFACE IF FORLIB.REL IS AVAILABLE
!
.ERROR %
.R DIRECT
*TTY:=FORLIB.REL
.IF (ERROR) .GOTO NOFORT
.ERROR
!
.R MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFOR/APPEND,DBS10/APPEND,DBSANY/APPEND,SCHIO1/APPEND
*FORLIB=FORLIB/INDEX
!
.R LINK
*@DBCS1F
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:FDBOTS
.IF (ERROR) .GOTO TRUBLE
NOFORT::
.ERROR
!
!HAVE BUILT EVERYTHING, NOW CLEANUP
!
!BUILD AND PRINT DOC FILE
!
.R RUNOFF
*DBMS10=DBS051
.IF (ERROR) .PLEASE -- COULD NOT CREATE DBMS10.DOC???
.PRINT DBMS10.DOC/COPIES:3,*.MAP/DISPOSE:DELETE
.IF (ERROR) .PLEASE -- COULD NOT PRINT DOC AND/OR MAP FILES???
!
!SEE WHAT WE GOT
!
.R DIRECT
*TTY:/CHECKSUM=SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,DAEMDB.*,?DBOTS.*
*TTY:/CHECKSUM=LIBOL.REL,LIBO12.EXE,FORLIB.REL,C74012.EXE
!
!TELL HOW WE DID
!
.PLEASE -- DBMS-10 CREATION SUCCESSFUL!!!
.GOTO ENDOF

TRUBLE::
.PLEASE -- DBMS-10 CREATION NOT SUCCESSFUL???
ENDOF::.![ END OF DBMS.CTL ]