Google
 

Trailing-Edge - PDP-10 Archives - BB-H580E-SB_1985 - rerun.ctl
There are 13 other files named rerun.ctl in the archive. Click here to see a list.
!RERUN.CTL	VERSION 12C
!
!USED TO MAKE RERUN.EXE FROM RERUN.MAC
!THIS FILE RUNS ON EITHER TOPS-20 OR TOPS-10
!SUBMIT WITH COMMAND	SUBMIT RERUN
!
!COPYRIGHT (C) DIGITAL EQUIPMENT CORPORATION 1979, 1985 
!ALL RIGHTS RESERVED.
!
!THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
!  OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
!
!SHOULD BE RUN AFTER COBOL.CTL AND LIBOL.CTL
!OR MAKE SURE THE CORRECT .UNV FILES ARE ON DSK:
!
!INSTALLATION SPECIFIC ASSIGNMENTS SHOULD BE PUT IN THE FOLLOWING FILE:
! ON TOPS-20 IN A TAKE FILE COBOL.CMD
! ON TOPS-10 IN A MIC  FILE COBOL.MIC
!	  OR IN A TECO FILE COBOL.TEC
!NOTE, IN GENERAL THIS CONTROL FILE WILL NOT RUN WITHOUT ONE OF THE ABOVE
!DEFINITION FILES BEING PRESENT.
!
!IF LISTINGS ARE DESIRED, THE EMPTY FILE
!LISTEM.MAC SHOULD BE IN DSK:
!
!TEST FOR WHICH SYSTEM
@GOTO TOPS20	!TOPS20 VERSION
.GOTO TOPS10	!TOPS10 VERSION
!
TOPS20::
!REQUIRED FILES:
!<FIELD-IMAGE>	CREF.EXE
!		LINK.EXE
!		MACRO.EXE
!		MONSYM.UNV
!
!<NEW>		PA1050.EXE
!
!<SELF>	RERUN.MAC
!	RERUN.HLP
!
!<SELF>	!FROM COBOL & LIBOL BUILD
!	COMUNI.UNV
!	COPYRT.UNV
!	FTDEFS.UNV
!	LBLPRM.UNV
!
!OUTPUT FILE:
!	RERUN.EXE
!
!OUTPUT LISTINGS:
!	RERUN.HLP
!	RERUN.LOG
!
!
@ERROR
@TAKE COBOL.CMD
@IF (ERROR) !IGNORE IT
!
!MAKE A RECORD OF WHAT IS BEING USED.
@GET SYS:PA1050
@INFO VERSION
@GET SYS:MACRO
@INFO VERSION
@GET SYS:LINK
@INFO VERSION
@GET SYS:CREF
@INFO VERSION
!
@VD SYS:MACRO.EXE,SYS:LINK.EXE,SYS:CREF.EXE,SYS:MONSYM.UNV,SYS:PA1050.EXE,
@CHECK SEQ
@
!
@VD RERUN.*,COMUNI.UNV,COPYRT.UNV,FTDEFS.UNV,LBLPRM.UNV,
@CHECK SEQ
@
!
!ASSEMBLE SOURCES
!
@ERROR %
@TYPE LISTEM.MAC
@IF (ERROR) @GOTO NOLIS1
@ERROR
!
!HERE FOR CREF LISTINGS
!
@MACRO
*RERUN,RERUN/C=RERUN
@IF (ERROR) @GOTO TRUBLE
@CREF
*DSK:RERUN.LZT=RERUN
@IF (ERROR) @PLEASE TROUBLE CREATING RERUN.LZT
@GOTO DONCRF
!
!
!HERE FOR NO CREF LISTINGS
!
NOLIS1::
@ERROR
@MACRO
*RERUN=RERUN
@IF (ERROR) @GOTO TRUBLE
!
DONCRF::
!LOAD IT
@LINK
*RERUN.MAP/MAP=RERUN,/SYMSEG:HIGH/GO
@IF (ERROR) @GOTO TRUBLE
@INFO MEM
@EXAMINE 600000
@IF (ERROR) @GOTO TRUBLE !WRONG VERSION OF PA1050 USED
!
!NOW SAVE IT. NOTE WE MUST GET RID OF PAGE 400 (A LINK BUG)
!
@SAVE DSK:RERUN 0 377,600 677
@IF (ERROR) @GOTO TRUBLE
!
!TRY IT JUST TO MAKE SURE IT WORKS
@RUN DSK:RERUN
!
!SEE WHAT WE GOT:
@VD RERUN.EXE,
@CHECK SEQ
@
@DELET RERUN.REL
@IF (ERROR) @ !IGNORE ANY ERRORS.
!
@PLEASE RERUN CREATION SUCCESSFUL
!DELETE UNNEEDED FILES
@DELETE RERUN.REL
@IF (ERROR) @!IGNORE ERROR
@EXP
@MODIFY BATCH */DEPEND:-1
@GOTO OK
!
TRUBLE::
@PLEASE RERUN CREATION FAILED
@GOTO OK
TOPS10::
!
!REQUIRED FILES:
!SYS:		COMPIL.EXE
!		CREF.EXE
!		DIRECT.EXE
!		LINK.EXE + LNK???.EXE
!		MACRO.EXE
!		PIP.EXE
!
![SELF]	FTDEFS.MAC
!	RERUN.MAC
!	RERUN.HLP
!
![SELF]	!FROM COBOL & LIBOL BUILD
!	COMUNI.UNV
!	COPYRT.UNV
!	FTDEFS.UNV
!	LBLPRM.UNV
!
!OUTPUT: 
!	RERUN.EXE
!	RERUN.LOG
!
!
!MAKE A RECORD OF WHAT IS BEING USED.
.ERROR
.SET WATCH VERSION
!SET UP THE DEFAULT LOGICAL NAMES
.ASSIGN DSK: SRC:
.ASSIGN DSK: C68:
.ASSIGN DSK: C74:
!
!CHANGE THEM IF USER SO DESIRES
.DO COBOL.MIC
.IF (ERROR) !IGNORE IT
!
!SEE WHAT WE ARE USING
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 SYS:PIP.EXE,MACRO.EXE,LINK.EXE,LNK???.EXE,DIRECT.EXE,COMPIL.EXE,CREF.EXE
.IF (ERROR) . !IGNORE ANY ERRORS.
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 SRC:RERUN.*,DSK:FTDEFS.UNV,LBLPRM.UNV,COMUNI.UNV,COPYRT.UNV
.IF (ERROR) . !IGNORE ANY ERRORS.
!ASSEMBLE THE SOURCES:
.TYPE LISTEM.MAC
.IF (ERROR) .GOTO NOLIS1
!
!HERE FOR CREF LISTINGS
.R MACRO
*RERUN,RERUN/C=RERUN
!
.R CREF
*DSK:RERUN.LZT=RERUN
!
.GOTO DONCRF
!
NOLIS1::
.ERROR
.R MACRO
*RERUN=RERUN
.IF (ERROR) .GOTO TRUBLE
!
DONCRF::
!LOAD IT:
.R LINK
*RERUN.MAP/MAP=RERUN/GO
.IF (ERROR) .GOTO TRUBLE
.SAVE DSK:RERUN
.IF (ERROR) .GOTO TRUBLE
!
!TRY IT JUST TO MAKE SURE IT WORKS
.RUN DSK:RERUN
!
!SEE WHAT WE GOT:
.R DIRECT
*TTY:=/CHECKSUM/WIDTH:90 RERUN.*
.IF (ERROR) . !IGNORE ANY ERRORS.
!
!DELETE UNNEEDED FILES
.DELETE RERUN.REL
.IF (ERROR) .!IGNORE ANY ERRORS
!
.PLEASE RERUN CREATION SUCCESSFUL
!
!WE CANNOT MIX GALAXY 2 AND GALAXY 4.1
!SO
.DEAS SYS
.IF (ERROR) !
!
.SUB INP:*=/MODIFY/DEPEND:-1
.GOTO OK
!
TRUBLE::
.PLEASE RERUN CREATION FAILED
!
OK::!END OF RERUN.CTL.