Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

;
;   DB20V6.CTL -- Patch and rebuild DBMS-20-V6
;   Version 1(0)
;	July 24, 1982  / HAH
;
 
;
;COPYRIGHT (c) 1982, 1983 BY
;	    Digital Equipment Corporation, Maynard, MA.
;
;   This software is furnished under a license and may be  used
;   and  copied  only  in  accordance  with  the  terms of such
;   license and with  the  inclusion  of  the  above  copyright
;   notice.   This software or any other copies thereof may not
;   be provided  or  otherwise	made  available  to  any  other
;   person.   No  title  to  and  ownership  of the software is
;   hereby transferred.
;
;   The information in	this  software	is  subject  to  change
;   without  notice and should not be construed as a commitment
;   by Digital Equipment Corporation.
;
;   Digital  assumes  no  responsibility   for	 the   use   or
;   reliability  of  its  software  on	equipment  which is not
;   supplied by Digital.
;

;
;   This .CTL file applies the  patches  to  the  libraries  of
;   DBMS-20-V6   and   rebuilds  SCHEMA.EXE,  FORDML.EXE,
;   DBMEND.EXE, and DBINFO.EXE.
;
;   For this .CTL file to run, the connected directory must  be
;   the patching directory (Logical name PAT:).
;
;   This control file is expected to run without errors.
;

@PEPB
*INITIALIZE DBMS-20-V6
*EXIT


;
;	Apply patches to the library files
;

@TYPE PAT:DB20V6.MKL

@R ASL:MAKLIB
*@PAT:DB20V6.MKL
@EXPUNGE PAT:

@DEFINE DSK: PAT:

;
;	Build schema processor SCHEMA.EXE
;

@R ASL:LINK
*SCHEMA/MAP=ASL:SCAN,ASL:WILD,ASL:HELPER,-
*GENME1,GENMS2,SCHIO2,DDLANY,DDL20,-
*/SEARCH GENIO2,STRHI
*@PAT:DB20V6.VER
*/GO
@SAVE SCHEMA

;
;	Build backup/recovery utility DBMEND.EXE
;

@R ASL:LINK
*DBMEND/MAP=ASL:HELPER,GENIO2,GENME2,GENMS2,SCHIO2,-
*MNDANY,DBMEN2,/SEARCH DBSANY,STRHI
*@PAT:DB20V6.VER
*/GO
@SAVE DBMEND

;
;	Build info generating utility DBINFO.EXE
;

@R ASL:LINK
*DBINFO/MAP=ASL:SCAN,ASL:HELPER,-
*GENME1,GENMS2,SCHIO2,INFANY,-
*DBSANY/S/EXCLUDE:(DBSET,DBWITH,DBCURN,DBJOUR,DBOTSI),-
*DBSFG/S,DBSI20/S,GENIO2/S,STRHI/S
*@PAT:DB20V6.VER
*/GO
@SAVE DBINFO

;
;	Build FORTRAN Interface if FORLIB.REL is available
;

@ERROR %
@COPY DIS:FORLIB.REL 
@IF (ERROR) @GOTO ENDBLD
@ERROR

;
;	Build Fortran pre-processor FORDML.EXE
;

@R ASL:LINK
*FORDML/MAP=ASL:SCAN,ASL:WILD,ASL:HELPER,-
*GENME1,SCHIO2,FMLANY,STRHI/SEARCH
*@PAT:DB20V6.VER
*/GO
@SAVE FORDML

;	IF MODULE FORMEM EXISTS THEN THIS MUST BE V6

@R MAKLIB
*NUL:=FORLIB/EXTRACT:FORMEM
@IF (ERROR) @GOTO NOFV6

@R ASL:MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFG/APPEND,DBS20/APPEND,-
*DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB/INDEX

@EXPUNGE PAT: 

@R ASL:LINK
*DBMSF/SAV/MAP=/SET:.HIGH.:700010
*/DEFINE:DBFNAD:131103/DEFINE:HOST$F:131103/DEFINE:DBMS%:229384
*/START:DBMS$.
*DBSFG/INCL:(DBPORT,DBLEAV,DBIF),DBSANY,DBS20,SCHIO2/GO
@GET DBMSF
@SAVE DBMSF 700 734

@GOTO ENDBLD

NOFV6::
;	In order to have this control file build FOROTS.EXE for FORTRAN V5A
;	you must remove the following semi-colons from this file.  The re-linked
;	FOROTS.EXE will not be installed by PEP but will be in the 
;	directory.


;
;@R ASL:LINK
;*FOROTS/MAP=FORLIB/INCLUDE:FOROTS,FORLIB/SEARCH/GO
;@SAVE FOROTS
;

ENDBLD::

;
;	Signal success
;

@EXPUNGE PAT:

@DEFINE DSK:
@COPY PAT:SCHIO2.REL
@COPY PAT:STRHI.REL
@COPY PAT:DBS20.REL
@COPY PAT:DBSANY.REL
@COPY PAT:DBSCOB.REL

@EXPUNGE DSK:

@PEPB
*SIGNAL-SUCCESS DBMS-20-V6
*EXIT
@GOTO EXIT

;
;	Signal failure on error
;

%ERR::
@EXPUNGE PAT:
@DEFINE DSK:

@PEPB
*SIGNAL-FAILURE DBMS-20-V6
*EXIT

EXIT::
%FIN::