Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

TITLE	SEDB10 - BEEHIVE B100 TERMINAL DEFINITIONS FOR THE EDITOR
SUBTTL	A CHRISTOPHER HALL FECIT

;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
;  OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
;
;COPYRIGHT (C) 1981 BY DIGITAL EQUIPMENT CORPORATION, MAYNARD, MASS.

;LOAD THE EDITOR BY: .COMP SED,SEDB10
;		     .LOAD/RE SEDB10,SED
;		     .SS SED

	SEARCH	SEDSYM
IFE TOPS10,<SEARCH MONSYM>

	EXTERN	CPOPJ,PUTTYP,PUTSTG,PUTSQ1,PUTNUM,TRMNAM,TYPBUF
	EXTERN	CHOME,CDOWN,CRIGHT
	INTERN	TERMNL

FTFAST==0	;SET THIS IF TERMINAL SENDS OUT XON-XOFF'S

TERMNL:	OTABLE	;ADDRESS OF THE TERMINAL TABLE TO USE

;TERMINAL OUTPUT TABLE - SEQUENCES TO MAKE THE TERMINAL DO SPECIAL THINGS
;FILL IN WITH THE CODES FOR YOUR TERMINAL

OTABLE:	BYTE (7) 33,"A"		;CURSOR UP
	BYTE (7) 33,"B"		; DOWN
	BYTE (7) 33,"C"		; RIGHT
	BYTE (7) 33,"D"		; LEFT
	BYTE (7) 33,"H"		; HOME
	BYTE (7) 33,"J"		;CLEAR TO END OF PAGE
	BYTE (7) 33,"K"		;CLEAR TO END OF LINE
	BYTE (7) 12		;ROLL UP AND CLEAR LINE
	BYTE (7) 0		;ROLL DOWN AND CLEAR LINE
	BYTE (7) 33,"]"		;PROTECT ON (CPOPJ IF NONE)
	BYTE (7) 33,"["		;PROTECT OFF (CPOPJ IF NONE)
	BYTE (7) 0		;INSERT LINE (0 IF NONE)
	BYTE (7) 0		;INSERT SPACE (0 IF NONE)
	BYTE (7) 0		;DELETE LINE (0 IF NONE)
	BYTE (7) 33,"P"		;DELETE SPACE (0 IF NONE)
	BYTE (7) 33,"F","7"," "	;MOVE TO BOTTOM
	BCLRSC			;HOME AND CLEAR ENTIRE PAGE
	POSCUR			;ROUTINE TO POSITION TO CHARACTER
	POSLIN			;ROUTINE TO POSITION TO START OF LINE
	^D24			;LINES PER PAGE
	^D80			;CHARACTERS PER LINE
IFE FTFAST,<
	WRP!LSD!NLP		;TERMINAL-DEPENDENT FLAGS
>
IFN FTFAST,<
	WRP!LSD!NLP!NPG		;TERMINAL-DEPENDENT FLAGS (KEEP TTY PAGE)
>
	CPOPJ			;ROUTINE TO CALL ON ENTRY
	CPOPJ			;ROUTINE TO CALL ON EXIT
	6,,0			;NUMBER OF NULLS TO OUTPUT,,NULL CHARACTER
	ITABLE			;ADDRESS OF INPUT CHARACTER TABLE
	0			;MARK TO DISPLAY ON ENTER (OMIT IF MRK NOT SET)

;TERMINAL INPUT TABLE - TELLS WHAT CONTROL CHARACTERS OR SEQUENCES
;INVOKE WHICH COMMANDS

IFE FTFAST,<
		0			;CODE FOR RUBOUT (0==RESET)
ITABLE:	EXP	40, 1, 2, 3, 4, 5, 6, 7 ;NOTHING SPECIAL
	EXP	10,11,50,13,14,15,16,17
	EXP	20,21,22,23,24,25,26,27
	EXP	30,31,32
	-SIZ.IS,,ISUBTB			;ESCAPE NEEDS A SUBTABLE (FOR EXAMPLE)
	EXP		 34,35,36,37
>
IFN FTFAST,<
;THIS TABLE SETS UP THE KEYBOARD ARRANGEMENT FOR WHEN YOU NEED TO KEEP
;TTY PAGE IN EFFECT BECAUSE THE TERMINAL SENDS OUT ITS OWN CONTROL S AND Q'S
;THOSE TWO CHARACTERS CANNOT BE COMMANDS SINCE SED DOES NOT KNOW WHETHER THE
;USER HAS TYPED THEM OR THEY WERE SENT BY THE TERMINAL.

;SO Q GOES TO A, A AND S GO TO K AND L, K TO ESCAPE-L, AND L TO ESCAPE-T.

		 0			;COMMAND FOR RUBOUT (RESET)
ITABLE:	EXP	40,21, 2, 3, 4, 5, 6, 7 ;NOTHING SPECIAL
	EXP	10,11,50, 1,23,15,16,17
	EXP	20, 0,22, 0,24,25,26,27
	EXP	30,31,32
	-SIZ.IS,,ISUBTB
	EXP		 34,35,36,37
>
;SUBTABLE. PUT THE MOST FREQUENTLY-USED SEQUENCES FIRST
;ENTER IS PROBABLY THE MOST COMMON OF ALL

ISUBTB:	33,,"E" 	;ESCAPE E == ENTER
	33,,"e"
	43,,"T" 	;ESCAPE T == REAL-TAB
	43,,"t"
	40,,"Q" 	;ESCAPE Q == RECALL
	40,,"q"
	41,,"I" 	;ESCAPE I == INSERT-MODE
	41,,"i"
	44,,"M" 	;ESCAPE M == MARK
	44,,"m"
	50,,"K" 	;ESCAPE K == ERASE-LINE
	50,,"k"
	47,,"W" 	;ESCAPE W == WINDOW
	47,,"w"
IFN FTFAST,<
	13,,"L"		;ESCAPE L == SLIDE-LEFT
	14,,"R"		;ESCAPE T == SLIDE-RIGHT
	13,,"l"		;ESCAPE l == SLIDE-LEFT
	14,,"r"		;ESCAPE t == SLIDE-RIGHT
>
SIZ.IS=.-ISUBTB

;SUBROUTINE TO MOVE TO ROW (RW), COLUMN (CM)

POSCUR:	MOVE	T1,[BYTE (7) 33,"F"]
	PUSHJ	P,PUTSQ1	;START IT OFF
	MOVEI	T1,40(RW)	;GET ROW POSITION
	IDPB	T1,TY
	MOVEI	T1,40(CM)	;GET COLUMN POSITION
	IDPB	T1,TY
	POPJ	P,		;DONE

;SUBROUTINE TO MOVE TO START OF LINE (T4)

POSLIN:	MOVE	T1,[BYTE (7) 33,"F"]
	PUSHJ	P,PUTSQ1	;START IT OFF
	MOVEI	T1,40(T4)	;GET ROW POSITION
	IDPB	T1,TY
	MOVEI	T1,40		;MOVE TO COLUMN ZERO
	IDPB	T1,TY
	POPJ	P,

;SUBROUTINE TO MOVE TO START OF LINE (T4)

BCLRSC:	MOVE	T1,[BYTE (7) 33,"E"]
	PUSHJ	P,PUTSQ1
	PUSHJ	P,PUTTYP	;OUTPUT IT NOW
	MOVEI	T1,^D100	;LET IT TAKE EFFECT
IFN TOPS10,<
	HIBER	T1,
	  JFCL
>
IFE TOPS10,<
	DISMS
>
	POPJ	P,

	END