Trailing-Edge
-
PDP-10 Archives
-
DBMS-20_V6_BIN_19811001
-
sources/dbms20.ctl
There are 26 other files named dbms20.ctl in the archive. Click here to see a list.
;DBMS20.CTL CTL EDIT 12 VERSION [6%363] SEP-81
; This software is furnished under a license and may only be used
; or copied in accordance with the terms of such license.
;
; COPYRIGHT (C) 1974, 1981 BY DIGITAL EQUIPMENT COPRORATION, MAYNARD, MASS.
;USED TO LOAD SCHEMA PROCESSOR, FORTRAN PRE-PROCESSOR, DBINFO,
;DBMEND, FORTRAN RUN-TIME SYSTEM(S), COBOL RUN-TIME SYSTEM(S)
;
;***** WARNING---THIS CTL FILE IS USED TO BUILD DBMS-20 ON
; THE DEVELOPMENT SYSTEMS IN MARLBORO. IT IS NOT
; GUARANTEED TO RUN ON ANY OTHER SYSTEM. THE USER
; SHOULD CHECK THIS CTL FILE FOR ANY INSTALLATION
; DEPENDENT ITEMS.
;
;***** ALWAYS DOES A "TAKE SETUP.CMD" TO CREATE ENVIRONMENT.
; EXAMINE THE INSTALLATION GUIDE BEFORE SUBMITTING
; THIS CTL FILE. ( SETUP.CMD = DBMS20.CMD ON TAPE.)
;
;***** IF APPLICABLE REBUILD COBOL, LIBOL, C74LIB AND/OR FOROTS BEFORE
; RUNNING THIS CTL FILE
;
; ***** IMPORTANT: *****
; THE DISTRIBUTED .LOG FILE FOR THIS .CTL FILE DOES BUILD
; ALL HOST SYSTEMS, BUT THERE IS NO INTENT THAT A USER
; INSTALLATION BUILD IDENTICAL COPIES OF THESE HOST-SYSTEMS.
; THE INTENT IS TO DEMONSTRATE THAT THE PROCESS OF BUILDING
; FORLIB, DBMSF, C74LIB, AND LIBOL IS VALID.
;
; IF YOU DESIRE COBOL-68 DBMS-20 SUPPORT, YOU MUST INCLUDE A COPY OF
; THE LATEST RELEASED LIBOL.REL AND LIBSHR.REL IN YOUR AREA.
; DBMS MUST NOT BE IN THIS COPY OF LIBOL.
;
; IF YOU DESIRE COBOL-74 DBMS-20 SUPPORT, YOU MUST INCLUDE A COPY OF
; THE LATEST RELEASED C74LIB.REL AND C74SHR.REL IN YOUR AREA.
; DBMS MUST NOT BE IN THIS COPY OF LIBOL.
;
; IF YOU WISH TO BUILD A FORTRAN-20/DBMS-20 RUN-TIME SYSTEM,
; YOU MUST INCLUDE A COPY OF THE LATEST RELEASED FORLIB.REL IN YOUR AREA.
; DBMS MUST NOT BE IN THIS COPY OF FORLIB.
;
;
; NOTE *** SUBMIT DBMS20.CTL WITH /TAG:DBALL
; TO CREATE:
; THE SCHEMA PROCESSOR (SCHEMA.EXE)
; THE BACKUP/RECOVERY UTILITY (DBMEND.EXE)
; THE INFO-GENERATING UTILITY (DBINFO.EXE)
; THE FORTRAN PRE-PROCESSOR (FORDML.EXE)
; THE COBOL OTS (LIBOL.REL AND LIBO12.EXE)
; OR (C74LIB.REL AND C74O12.EXE)
; THE FORTRAN (V6) OTS (FORLIB.REL AND DBMSF.EXE)
; OR (V5A) (FORLIB.REL AND FOROTS.EXE)
;
; THIS CTL FILE NEITHER BUILDS NOR LINKS THE COBOL COMPILER
; YOU MUST USE THE COBOL.CTL FILE FROM THE COBOL DISTRIBUTION TAPE.
; MAC FILES FOR REBUILDING THE COBOL COMPILER WITH DBMS IN IT
;
;[SELF]: CMLSYM, DBSDCL, GENDCL, STRDCL, STRUNV,
; DBDML, DBGETF, DMLERR, DMLIO, DMLVOK
;
; YOU ALSO NEED TWO REL FILES:
; STRHI, SCHIO2
;REQUIRED FILES: (LATEST RELEASED VERSIONS)
;
;<SUBSYS> MAKLIB LINK
;
;<REL> SCAN.REL WILD.REL HELPER.REL
;
;[SELF]: DBMS20.CTL SETUP.CMD (DBMS20.CMD)
; SCHEM2.CMD SCHEMA.HLP
; FORDM2.CMD FORDML.HLP
; DBMEN2.CMD DBMEND.HLP
; DBINF2.CMD DBINFO.HLP
; DBCS28.CMD DBCS24.CMD
; DBCS2F.CMD DBCS25.CMD
;
;
;OUTPUT: SCHEMA.EXE FORDML.EXE DBMEND.EXE DBINFO.EXE
; SCHEMA.MAP FORDML.MAP DBMEND.MAP DBINFO.MAP
;
; IF BUILDING A COBOL-68 SYSTEM: LIBO12.EXE,LIBO12.MAP, AND LIBOL.REL
; IF BUILDING A COBOL-74 SYSTEM: C74O12.EXE,C74O12.MAP, AND C74LIB.REL
; IF BUILDING A FORTRAN SYSTEM: DBMSF.EXE,DBMSF.MAP, AND FORLIB.REL
; FOROTS.EXE (FORTRAN V5A ONLY)
;
;OUTPUT LISTINGS: DBMS20.LOG
;
; SYS: = FILES ON SYS:
; USER: = FILES SUPPLIED BY THE USER
; DSK: = FILES SUPPLIED BY DEC
; OUTPUT: SCHEMA.EXE SCHEMA.MAP
; SYS: SCAN, WILD, HELPER
; DSK: GENME1, GENMS2, SCHIO2, DDLANY, DDL20, GENIO2, STRHI
; OUTPUT: DBMEND.EXE DBMEND.MAP
; SYS: SCAN, HELPER
; DSK: GENIO2, GENME2, GENMS2, SCHIO2, MNDANY, DBMEN2, DBSANY, STRHI
; OUTPUT: DBINFO.EXE DBINFO.MAP
; SYS: SCAN, HELPER
; DSK: GENME1, GENMS2, SCHIO2, INFANY, DBSANY, DBSFG, DBSI20, GENIO2, STRHI
; OUTPUT: FORDML.EXE FORDML.MAP
; SYS: SCAN, WILD, HELPER
; DSK: GENME1, SCHIO2, FMLANY, STRHI
; OUTPUT: LIBOL.REL LIBOL.MAP
; USER: LIBOL ; WITHOUT DBMS IN IT
; DSK: DBSCOB, DBS20, DBSANY, SCHIO2
; OUTPUT: LIBO12.EXE LIBO12.MAP
; SYS: MACREL
; USER: LIBOL LIBSHR
; OUTPUT: C74LIB.REL C74LIB.MAP
; USER: C74LIB ; WITHOUT DBMS IN IT
; DSK: DBSCOB, DBS20, DBSANY, SCHIO2
; OUTPUT: C74O12.EXE C74O12.MAP
; SYS: MACREL
; USER: C74LIB C74SHR
; OUTPUT: FORLIB.REL FORLIB.MAP FOROTS.EXE (FORTRAN V5A ONLY)
; USER: FORLIB ; WITHOUT DBMS IN IT
; DSK: DBSFG, DBS20, DBSANY, SCHIO2, F5AMEM.FIX
; OUTPUT: DBMSF.EXE DBMSF.MAP
; DSK: DBSFG, DBS20, DBSANY, SCHIO2
;MAKE A RECORD OF WHAT IS BEING USED
@DEFINE *
@
@TAKE DSK:SETUP.CMD
@INFO LOGICAL
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@VDIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,SYS:SCAN.REL,SYS:WILD.REL,SYS:HELPER.REL,
@CHECKSUM SEQUENTIAL
@
@VDIRECT SCHEM2.CMD, FORDM2.CMD, DBMEN2.CMD, DBINF2.CMD, DBCS28.CMD, DBCS24.CMD, DBCS2F.CMD, DBCS25.CMD,
@CHECKSUM SEQUENTIAL
@
@VDIRECT CMLERR.REL, CMLIO.REL, CMLVOK.REL, DBDML.REL, DBGETF.REL, DBMEN2.REL, DBS20.REL, DBSANY.REL, DBSCOB.REL, DBSFG.REL, DBSI20.REL, DDL20.REL, DDLANY.REL, FMLANY.REL, GENIO2.REL, GENME1.REL, GENME2.REL, GENMS2.REL, INFANY.REL, MNDANY.REL, SCHIO2.REL, STRHI.REL,
@CHECKSUM SEQUENTIAL
@
!@VDIRECT DBCSYM.UNV, DBKERN.UNV, DBSDCL.UNV, DDLDCL.UNV, DMLDCL.UNV, DMLSYM.UNV, GENDCL.UNV, GENSWI.UNV, GENTAB.UNV, INFDCL.UNV, MNDDCL.UNV, STRDCL.UNV, STRING.UNV,
!@CHECKSUM SEQUENTIAL
@
@ERROR
@GOTO DBOTS
; DBOTS IS THE DEFAULT PATH -- JUST BUILD THE OTS
; ENTRY AT DBALL WILL BUILD THE UTILTIES AND THE OTS
DBALL::
; DBALL IS THE ENTRY POINT TO REBUILD THE UTILITIES
; DBOTS IS THE ENTRY POINT TO JUST DO THE RUN-TIME SYSTEMS
;MAKE A RECORD OF WHAT IS BEING USED
@DEFINE *
@
@DEFINE DSK:
@TAKE DSK:SETUP.CMD
@INFO LOGICAL
@GET SYS:LINK
@INFO VERSION
@GET SYS:MAKLIB
@INFO VERSION
@VDIRECT SYS:MAKLIB.EXE,SYS:LINK.EXE,SYS:SCAN.REL,SYS:WILD.REL,SYS:HELPER.REL,
@CHECKSUM SEQUENTIAL
@
@VDIRECT SCHEM2.CMD, FORDM2.CMD, DBMEN2.CMD, DBINF2.CMD, DBCS28.CMD, DBCS24.CMD, DBCS2F.CMD, DBCS25.CMD,
@CHECKSUM SEQUENTIAL
@
@VDIRECT CMLERR.REL, CMLIO.REL, CMLVOK.REL, DBDML.REL, DBGETF.REL, DBMEN2.REL, DBS20.REL, DBSANY.REL, DBSCOB.REL, DBSFG.REL, DBSI20.REL, DDL20.REL, DDLANY.REL, FMLANY.REL, GENIO2.REL, GENME1.REL, GENME2.REL, GENMS2.REL, INFANY.REL, MNDANY.REL, SCHIO2.REL, STRHI.REL,
@CHECKSUM SEQUENTIAL
@
!@VDIRECT DBCSYM.UNV, DBKERN.UNV, DBSDCL.UNV, DDLDCL.UNV, DMLDCL.UNV, DMLSYM.UNV, GENDCL.UNV, GENSWI.UNV, GENTAB.UNV, INFDCL.UNV, MNDDCL.UNV, STRDCL.UNV, STRING.UNV,
!@CHECKSUM SEQUENTIAL
@
@ERROR
; ********** SCHEMA **********
BLDSCH::
@R LINK
*@SCHEM2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:SCHEMA
@IF (ERROR) @GOTO TRUBLE
; ********** DBMEND **********
BLDDBM::
@R LINK
*@DBMEN2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMEND
@IF (ERROR) @GOTO TRUBLE
; ********** DBINFO **********
BLDINF::
@R LINK
*@DBINF2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBINFO
@IF (ERROR) @GOTO TRUBLE
; ********** FORDML **********
@R LINK
*@FORDM2.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:FORDML
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
DBOTS::
; DBOTS IS THE DEFAULT ENTRY POINT.
; IF YOU WANT TO REBUILD THE UTILITIES
; YOU SHOULD "@SUBMIT DBMS20/TIME:30/TAG:DBALL"
; ********** LIBOL **********
BLDLIB::
@ERROR %
@VDIRECT LIBOL.REL
@IF (ERROR) @GOTO NO68LIB
@ERROR
@R MAKLIB
*LIBOL=LIBOL/DELETE:RESOLV
*LIBOL=LIBOL/DELETE:RSVGAT
*LIBOL=LIBOL/DELETE:DBSTP$
*COBFUN.TMP=LIBOL/EXTR:COBFUN
*LIBOL=LIBOL/DELETE:COBFUN
*LIBOL=LIBOL,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*LIBOL=LIBOL/INDEX
@DEL COBFUN.TMP
@IF (ERROR) @GOTO TRUBLE
; ********** LIBO12 **********
@R LINK
*@DBCS28.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:LIBO12 0 1, 564 577, 600 675
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
NO68LIB::
; ********** C74LIB **********
@ERROR %
@VDIRECT C74LIB.REL
@IF (ERROR) @GOTO NO74LIB
@ERROR
@R MAKLIB
*C74LIB=C74LIB/DELETE:RESOLV
*C74LIB=C74LIB/DELETE:RSVGAT
*C74LIB=C74LIB/DELETE:DBSTP$
*COBFUN.TMP=C74LIB/EXTR:COBFUN
*C74LIB=C74LIB/DELETE:COBFUN
*C74LIB=C74LIB,DBSCOB/APPEND,DBS20/APPEND,COBFUN.TMP/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*C74LIB=C74LIB/INDEX
@DEL COBFUN.TMP
@IF (ERROR) @GOTO TRUBLE
; ********** C74O12 **********
@R LINK
*@DBCS24.CMD
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:C74O12 0 1,550 575,600 675
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
NO74LIB::
; ********** FORLIB (V6) **********
@ERROR %
@VDIRECT FORLIB.REL
@IF (ERROR) @GOTO NOFORT
@ERROR
;IF MODULE FORMEM EXISTS THEN THIS MUST BE V6
@R MAKLIB
*NUL:=FORLIB/EXTRACT:FORMEM
@IF (ERROR) @GOTO NOFV6
@R MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFG/APPEND,DBS20/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB/INDEX
@IF (ERROR) @GOTO TRUBLE
; ********** DBMSF (FORTRAN V6) **********
@LINK
*@DBCS2F.CMD
@GET DBMSF.EXE
@IF (ERROR) @GOTO TRUBLE
@SAVE DSK:DBMSF.EXE 700 734
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
@GOTO NOFORT
NOFV6::
; ********** FORLIB (V5A) **********
@ERROR
;IF MODULE FORFUN EXISTS THEN THIS MUST BE V5A
@R MAKLIB
*NUL:=FORLIB/EXTRACT:FORFUN
@IF (ERROR) @GOTO NOFORT
@R MAKLIB
*FORLIB=FORLIB/DELETE:FORDBM
*FORLIB=FORLIB,DBSFG/APPEND,DBS20/APPEND,DBSANY/APPEND,SCHIO2/APPEND
*FORLIB=FORLIB,F5AMEM.FIX/FIX
*FORLIB=FORLIB/INDEX
@IF (ERROR) @GOTO TRUBLE
; ********** FOROTS (FORTRAN V5A) **********
@LINK
*@DBCS25.CMD
@SAVE FOROTS
@IF (ERROR) @GOTO TRUBLE
@EXPUNGE
NOFORT::
@ERROR
@VDIRECT SCHEMA.*,FORDML.*,DBMEND.*,DBINFO.*,DBMSF.*,LIBOL.REL,FORLIB.REL,C74LIB.REL,LIBO12.EXE,C74O12.EXE,FOROTS.EXE,
@CHECKSUM SEQUENTIAL
@
; ********** TELL HOW WE DID **********
@PLEASE -- DBMS-20 CREATION SUCCESSFUL!!!
@GOTO ENDOF
TRUBLE::
@PLEASE -- DBMS-20 CREATION NOT SUCCESSFUL???
ENDOF::
@EXPUNGE
@LOGO
; [ END OF DBMS20.CTL ]