Google
 

Trailing-Edge - PDP-10 Archives - ap-c800d-sb - cobtst.mac
There are 7 other files named cobtst.mac in the archive. Click here to see a list.
TITLE COBTST - TO TEST SWITCH SETTINGS FOR BATCH JOBS
SUBTTL	D.M.NIXON	12/9/77


;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
;  OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
;
;COPYRIGHT (C) 1977, 1979 BY DIGITAL EQUIPMENT CORPORATION


SEARCH	INTERM

CH=4		;I/O CHARACTER
W1=6		;FIRST OUTPUT WORD FROM I/O
W2=7		;SECOND OUTPUT WORD FROM I/O
TB=15		;TEMP
TA=16		;TEMP


DEFINE	SWITCH<
XX	ONESEG
XX	DEBUG
XX	DBMS
XX	ANS68
XX	ANS74
XX	BIS
>

START:	RESET
	OUTSTR	[ASCIZ	/*/]
	SETZ	W1,		;RESULT INDICATOR
	MOVE	TA,[POINT 6,W1]
	MOVEI	TB,6
INLUP:	INCHWL	CH		;GET CHAR
	CAIE	CH,15
	CAIN	CH,12		;LOOK FOR END OF LINE
	JRST	TEST		;GOT IT
	SUBI	CH,40		;SIXBITIZE
	IDPB	CH,TA		;STORE
	SOJG	TB,INLUP	;GET NEXT CHAR
TEST:	MOVSI	TA,-SWTLEN
	CAMN	W1,SWTTAB(TA)
	JRST	FND		;GO MATCH
	AOBJN	TA,.-2		;LOOP
	OUTSTR	[ASCIZ	/?FEATURE TEST NOT IN TABLE/]
	JRST	RET

FND:	XCT	SWTXCT(TA)
	JUMPN	W2,FALSE
	OUTSTR	[ASCIZ	/%TRUE/]
	JRST	RET

FALSE:	OUTSTR	[ASCIZ	/?FALSE/]
RET:	EXIT	1,

DEFINE	XX (A)<	SIXBIT	/A/>
SWTTAB:	SWITCH
	SWTLEN==.-SWTTAB

DEFINE	XX (A)<
	IFE	A,<SETOM W2>		;FALSE
	IFN 	A,<SETZM W2>		;TRUE
>
SWTXCT:	SWITCH


END	START