Trailing-Edge
-
PDP-10 Archives
-
bb-bt99g-bb
-
t1l702.ctl
There is 1 other file named t1l702.ctl in the archive. Click here to see a list.
;
; COPYRIGHT (C) 1984, 1985 BY
; DIGITAL EQUIPMENT CORPORATION, MAYNARD, MA.
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED
; AND COPIED ONLY IN ACCORDANCE WITH THE TERMS OF SUCH
; LICENSE AND WITH THE INCLUSION OF THE ABOVE COPYRIGHT
; NOTICE. THIS SOFTWARE OR ANY OTHER COPIES THEREOF MAY NOT
; BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY OTHER
; PERSON. NO TITLE TO AND OWNERSHIP OF THE SOFTWARE IS
; HEREBY TRANSFERRED.
;
; THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE
; WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT
; BY DIGITAL EQUIPMENT CORPORATION.
;
; DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR
; RELIABILITY OF ITS SOFTWARE ON EQUIPMENT WHICH IS NOT
; SUPPLIED BY DIGITAL.
;
;*******************************************************************************
;T1L702.CTL /RCB
;
;-----
;Running T1L702:
;
;Submit T1L702.CTL with the following command:
; .SUBMIT T1L702/RESTART/TIME:1:00:00
;
;-----
;Requirements:
;
;1) The configuration files (FKL,HDWKL,TTYKL,NETKL) must be created with
; MONGEN before T1L702 runs.
;2) The DECnet and CPNSER sources must be available if they are
; to be used.
;
;-----
;Introduction:
;
;This file will assemble all modules for a KL10, create TOPL10.REL,
;TOPL10.GLB, and optionally CREF listings.
;*******************************************************************************
BEGIN::
.CHKPNT BEGIN
.PLEASE ** T1L702 ** Starting
;*******************************************************************************
; Initialization
;*******************************************************************************
;
.IF (ERROR)
;
.ERROR
.R QUOLST
.IF (ERROR)
;
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
;Delete any source files in PAT:
.NOERROR
.DELETE PAT:S.MAC,PAT:NETPRM.MAC,PAT:DTEPRM.MAC,PAT:RH2PRM.MAC,PAT:MACSYM.MAC
.DELETE PAT:D36PAR.MAC,PAT:COMMON.MAC,PAT:COMDEV.MAC,PAT:COMNET.MAC,PAT:COMMOD.MAC
.DELETE PAT:MONBTS.MAC,PAT:FTEJBD.MAC,PAT:JOBDAT.MAC,PAT:FILFND.MAC,PAT:FILIO.MAC
.DELETE PAT:FILUUO.MAC,PAT:KONPAR.MAC,PAT:DPXKON.MAC,PAT:FHXKON.MAC,PAT:FSXKON.MAC
.DELETE PAT:RNXKON.MAC,PAT:RPXKON.MAC,PAT:AUTCON.MAC,PAT:CDPSER.MAC,PAT:CDRSER.MAC
.DELETE PAT:CLOCK1.MAC,PAT:COMCON.MAC,PAT:CORE1.MAC,PAT:D36COM.MAC
.DELETE PAT:D60SER.MAC,PAT:D6DINT.MAC,PAT:D6SINT.MAC,PAT:D76INT.MAC,PAT:D85INT.MAC
.DELETE PAT:D8SINT.MAC,PAT:DATMAN.MAC,PAT:DCRSER.MAC,PAT:DISSER.MAC,PAT:DLPSER.MAC
.DELETE PAT:FTDLS1.MAC,PAT:DLSINT.MAC,PAT:DTASER.MAC,PAT:DTESER.MAC,PAT:DX2COM.MAC
.DELETE PAT:ERRCON.MAC,PAT:FEDSER.MAC,PAT:IPCSER.MAC,PAT:KASER,PAT:KLSER.MAC
.DELETE PAT:LOKCON.MAC,PAT:LPTSER.MAC,PAT:METCON.MAC,PAT:MOSSER.MAC,PAT:MSGSER.MAC
.DELETE PAT:NETDEV.MAC,PAT:NETSER.MAC,PAT:NULFEK.MAC,PAT:PLTSER.MAC,PAT:PSISER.MAC
.DELETE PAT:PTPSER.MAC,PAT:PTRSER.MAC,PAT:PTYSER.MAC,PAT:QUESER.MAC,PAT:RDXSER.MAC
.DELETE PAT:RTTRP.MAC,PAT:SCHED1.MAC,PAT:SCNSER.MAC,PAT:SEGCON.MAC,PAT:SWPSER.MAC
.DELETE PAT:TAPSER.MAC,PAT:TAPUUO.MAC,PAT:TD2KON.MAC,PAT:TM2KON.MAC,PAT:T78KON.MAC
.DELETE PAT:TMPUUO.MAC,PAT:TMXKON.MAC,PAT:TSKSER.MAC,PAT:TTDINT.MAC,PAT:TX1KON.MAC
.DELETE PAT:UUOCON.MAC,PAT:VBCSER.MAC,PAT:VMSER.MAC,PAT:PATCH.MAC,PAT:SYSINI.MAC
.DELETE PAT:ONCMOD.MAC,PAT:REFSTR.MAC,PAT:ONCE.MAC
.ERROR
.RUN ASL:UPDATE
*@PAT:T1L702.SUP
.IF (ERROR) .GOTO ERROR
.GOTO FILES
INFO::
.CHKPNT INFO
.PLEASE ** T1L702 ** CHKPNT INFO - Get some listing information
;*******************************************************************************
; See if we want CREF listings
;*******************************************************************************
;
.ERROR
.R QUOLST
.IF (ERROR)
;
.NOERROR
.RUN ASL:PIP
*DSK:/D=LIST.KL
;
.ERROR ?
.OPERATOR $
;
.RUN ASL:TECO
=!ASK! $Do you want CREF listings ? (Y/N)
=^^TU1 Q1-78"E ONO' Q1-110"E ONO' Q1-89"E OYES' Q1-121"E OYES' OASK
=!NO! "[No CREF listings will be generated] OXIT
=!YES! "[CREF listings will be generated] EWLIST.KL
=!XIT! EX
;
.ERROR %
.NOOPERATOR
FILES::
.CHKPNT FILES
.PLEASE ** T1L702 ** CHKPNT FILES - Build indirect files
;*******************************************************************************
; Build KL10 indirect files
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF (NOERROR) .GOTO FILESI
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
FILESI::
;
.COPY CONKL.CMD=KL10.FIL
.ERROR ?
;
;Format CONKL.CMD
.RUN ASL:TECO
=EBCONKL.CMD 25<A> J0L <.U1 S#; Q1-.D L;> EX
;
;Create LODKL.CCL
.ERROR ?
.RUN ASL:TECO
*EWLODKL.CCL I/NOINIT /HASH:6000 RL72Z/SAVE, RL72Z/MAP /CONTEN:NONE = /LOCALS -
*COMMON.RLL, MONBTS.RLL/SEARCH, COMDEV.RLL, COMNET.RLL, COMMOD.RLL, /SEARCH -
*TOPL10 /PATCH:100 /GO
= EX
;
;
.ERROR ?
.COPY PAT:=ASL:CPNSER.MAC
.IF (ERROR) .GOTO BSKMPE
.RUN ASL:TECO
*EBCONKL.CMD 25<A> ZJ I,CPNSER.RLL=CPNSER.MAC
= EX
.RUN ASL:TECO
=EBLODKL.CCL 4<A> ZJ -L ICPNSER.RLL, EX
.GOTO CSKMPE
BSKMPE::
.RUN ASL:PIP
*DSK:CPNSER.RLL/I=NUL:NUL.NUL
CSKMPE::
;
;
.ERROR ?
.COPY PAT:=ASL:DECNET.FIL
.IF (ERROR) .GOTO BSKDCN
.ERROR ?
.RUN ASL:TECO
*ERDECNET.FIL 25<A> SD36PAR L B,.K <.U1 :S#; Q1-.D :FS.REL.RLL; L> HXT HK
=EBCONKL.CMD 25<A> SD36PAR L GT EX
.RUN ASL:TECO
=EBLODKL.CCL 4<A> ZJ -L IDECNET.RLL, EX
.GOTO CSKDCN
BSKDCN::
.RUN ASL:PIP
*DSK:DECNET.RLL/I=NUL:NUL.NUL
CSKDCN::
;
;Clean up
.NOERROR
.DELETE CONKL.BAK, LODKL.BAK
.ERROR
BUILD::
.CHKPNT BUILD
.PLEASE ** T1L702 ** CHKPNT BUILD - Beginning monitor assembly
;*******************************************************************************
; Assemble KL10 modules
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO BUILDI
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
BUILDI::
;
;Find out if LIST.KL exists - if so, create CREF lstings
.ERROR %
.RUN DIRECT
*LIST.KL
.IF (NOERROR) .GOTO BUILD1
;
.ERROR
.COMPIL /COMPILE @CONKL.CMD
.IF (ERROR) .GOTO BUILD2
.GOTO BUILD3
;
BUILD1::
.ERROR
.COMPIL /COMPILE/CREF @CONKL.CMD
.IF (NOERROR) .GOTO BUILD3
;
BUILD2::
.PLEASE ** T1L702 ** Assembly errors exist
.GOTO ERROR
;
BUILD3::
COMBIN::
.CHKPNT COMBIN
.PLEASE ** T1L702 ** CHKPNT COMBIN - Building TOPL10.REL
;*******************************************************************************
; Combine KL10 modules into TOPL10.REL
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO CMBKLI
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
CMBKLI::
;
.NOERROR
.RUN PIP
*DSK:/D=CMBKL.CCL
.ERROR ?
;
;Create CMBKL.CCL
.RUN TECO
*ERKL10.FIL 25<A> J0L SEJBDAT 0L -.D
*J0L ITOPL10.REL/I= <S#; -D K I.RLL,> ZJ -D I
= J0L SSYSINI.RLL I,EDDT.REL EWCMBKL.CCL EX
;
;
.ERROR ?
.COPY PAT:=ASL:DECNET.FIL
.IF (ERROR) .GOTO CMBKLL
;
.NOERROR
.RUN PIP
*DSK:/D=DCNKL.CCL
.ERROR ?
;
;Create DCNKL.CCL
.RUN TECO
*ERDECNET.FIL 25<A> J0L SROUTER 0L-.D
*J0L IDECNET.RLL/I= <:S#; -D K I.RLL,> ZJ -D I
= EWDCNKL.CCL EX
;
;Make DECNET.RLL
.RUN PIP 50P
*DCNKL.CCL@
.IF (NOERROR) .GOTO CMBKLL
.PLEASE ** T1L702 ** Errors creating DECNET.RLL
.GOTO ERROR
;
;Make TOPL10.REL
CMBKLL::
.RUN PIP 50P
*CMBKL.CCL@
.IF (NOERROR) .GOTO LOAD
.PLEASE ** T1L702 ** Errors creating TOPL10.REL
.GOTO ERROR
LOAD::
.CHKPNT LOAD
.PLEASE ** T1L702 ** CHKPNT LOAD - Begining RL72Z LOAD
;*******************************************************************************
; RL72Z LOAD
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF (NOERROR) .GOTO LOADI
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
LOADI::
;
.RUN LINK
*@LODKL.CCL
.IF (NOERROR) .GOTO GLOB
.PLEASE ** T1L702 ** Errors creating RL72Z.EXE
.GOTO ERROR
GLOB::
.CHKPNT GLOB
.PLEASE ** T1L702 ** CHKPNT GLOB - Begining TOPL10 GLOB
;*******************************************************************************
; TOPL10 GLOB
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.RUN GLOB
*COMMON.RLL,COMDEV.RLL,COMNET.RLL,COMMOD.RLL,MONBTS.RLL,DECNET.RLL
*CPNSER.RLL,D6DINT.RLL,TOPL10.REL
*DSK:TOPL10.GLB=
.IF (ERROR) .PLEASE ** T1L702 ** Error creating monitor GLOB
LIST::
.CHKPNT LIST
.PLEASE ** T1L702 ** CHKPNT LIST - Generate CREF listings if required
;*******************************************************************************
; Generate CREF listings if required
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
;Find out if LIST.KL exists - if so, run CREF
.ERROR %
.RUN DIRECT
*LIST.KL
.IF (ERROR) .GOTO LIST1
;
.ASSIGN DSK LPT
.CREF
.IF (ERROR) .PLEASE ** T1L702 ** Errors creating CREF listings
.DEASSIGN LPT
;
.ERROR ?
;
;Create QKL.CCL
.RUN TECO
*ERKL10.FIL 25<A> <S#; -D K I.LST
> EWQKL.CCL EX
;
;Sort QKL.CCL alphabetically
.RUN SORT
*QKL.CCL=QKL.CCL/KEY:1:6:ASCEND/RECORD:6/VARIABLE
;
.RUN TECO
=ERQKL.CCL 25<A> I/FORMS:MFI/PRIORI:1/OKNONE <.-Z;L2RI,-L> 4R2D EWQKL.CCL EX
;
.RUN QUEUE
*@QKL
;*MONGEN.LST/FORMS:MFI
.IF (ERROR) .PLEASE ** T1L702 ** Errors QUEUEing listings
.GOTO LIST2
;
LIST1::
.PLEASE ** T1L702 ** CREF listing not requested
;
LIST2::
EXIT::
.CHKPNT EXIT
.PLEASE ** T1L702 ** CHKPNT EXIT - End of stream
;*******************************************************************************
; End of stream
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO EXITI
.R PEPB
*INITIALIZE TOPS-10-KL-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
EXITI::
;
.ERROR %
.R PEPB
*SIGNAL-SUCCESS TOPS-10-KL-V702
*EXIT
.GOTO END
;
%ERR:: .GOTO ERROR
%CERR:: .GOTO ERROR
%TERR:: .PLEASE ** T1L702 ** Time limit exceeded
.GOTO ERR2
;
ERROR::
.PLEASE ** T1L702 ** Stream has errors
ERR2::
;
.R PEPB
*SIGNAL-FAILURE TOPS-10-KL-V702
*EXIT
;
END::
;
%FIN:: .PLEASE ** T1L702 ** Stream finished
;
;[END OF T1L702.CTL]