Google
 

Trailing-Edge - PDP-10 Archives - bb-bt99g-bb - t1s702.ctl
There is 1 other file named t1s702.ctl in the archive. Click here to see a list.
;
;		       COPYRIGHT (C) 1984, 1985 BY
;	    DIGITAL EQUIPMENT CORPORATION, MAYNARD, MA.
;
;   THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE  USED
;   AND  COPIED  ONLY  IN  ACCORDANCE  WITH  THE  TERMS OF SUCH
;   LICENSE AND WITH  THE  INCLUSION  OF  THE  ABOVE  COPYRIGHT
;   NOTICE.   THIS SOFTWARE OR ANY OTHER COPIES THEREOF MAY NOT
;   BE PROVIDED  OR  OTHERWISE	MADE  AVAILABLE  TO  ANY  OTHER
;   PERSON.   NO  TITLE  TO  AND  OWNERSHIP  OF THE SOFTWARE IS
;   HEREBY TRANSFERRED.
;
;   THE INFORMATION IN	THIS  SOFTWARE	IS  SUBJECT  TO  CHANGE
;   WITHOUT  NOTICE AND SHOULD NOT BE CONSTRUED AS A COMMITMENT
;   BY DIGITAL EQUIPMENT CORPORATION.
;
;   DIGITAL  ASSUMES  NO  RESPONSIBILITY   FOR	 THE   USE   OR
;   RELIABILITY  OF  ITS  SOFTWARE  ON	EQUIPMENT  WHICH IS NOT
;   SUPPLIED BY DIGITAL.
;
;*******************************************************************************
;T1S702.CTL /RCB
;
;-----
;Running T1S702:
;
;Submit T1S702.CTL with the following command:
;	.SUBMIT T1S702/RESTART/TIME:1:00:00
;
;-----
;Requirements:
;
;1) 	The configuration files (FKS,HDWKS,TTYKS,NETKS) must be created with
;		MONGEN before T1S702 runs.
;2)	The DECnet sources must be available if they are to be used.
;
;-----
;Introduction:
;
;This file will assemble all modules for a KS10, create TOPS10.REL,
;TOPS10.GLB, and optionally CREF listings.
;*******************************************************************************
BEGIN::
.CHKPNT BEGIN
.PLEASE ** T1S702 ** Starting
;*******************************************************************************
;				Initialization
;*******************************************************************************
;
.IF (ERROR)
;
.ERROR
.R QUOLST
.IF (ERROR)
;
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
;.Delete any source files in PAT:
.NOERROR
.DELETE PAT:S.MAC,PAT:NETPRM.MAC,PAT:RH2PRM.MAC,PAT:DTEPRM.MAC,PAT:MACSYM.MAC
.DELETE PAT:D36PAR.MAC,PAT:COMMON.MAC,PAT:COMDEV.MAC,PAT:COMNET.MAC,PAT:COMMOD.MAC
.DELETE PAT:MONBTS.MAC,PAT:FTEJBD.MAC,PAT:JOBDAT.MAC,PAT:FILFND.MAC,PAT:FILIO.MAC
.DELETE PAT:FILUUO.MAC,PAT:KONPAR.MAC,PAT:RHXKON.MAC,PAT:CD2SER.MAC,PAT:CLOCK1.MAC
.DELETE PAT:COMCON.MAC,PAT:CORE1.MAC,PAT:DATMAN.MAC,PAT:D36COM.MAC,PAT:D60SER.MAC
.DELETE PAT:D8KINT.MAC,PAT:DZINT.MAC,PAT:ERRCON.MAC,PAT:IPCSER.MAC,PAT:KASER.MAC
.DELETE PAT:KSSER.MAC,PAT:LOKCON.MAC,PAT:LP2SER.MAC,PAT:METCON.MAC,PAT:MSGSER.MAC
.DELETE PAT:NETSER.MAC,PAT:NETDEV.MAC,PAT:NULFEK.MAC,PAT:PSISER.MAC,PAT:PTYSER.MAC
.DELETE PAT:QUESER.MAC,PAT:RDXSER.MAC,PAT:SCHED1.MAC,PAT:SCNSER.MAC,PAT:SEGCON.MAC
.DELETE PAT:SWPSER.MAC,PAT:TMPUUO.MAC,PAT:TAPSER.MAC,PAT:TAPUUO.MAC,PAT:TRHKON.MAC
.DELETE PAT:TSKSER.MAC,PAT:UUOCON.MAC,PAT:VMSER.MAC,PAT:PATCH.MAC,PAT:SYSINI.MAC
.DELETE PAT:ONCMOD.MAC,PAT:REFSTR.MAC,PAT:ONCE.MAC,PAT:D6KINT.MAC
.ERROR
.RUN ASL:UPDATE
*@PAT:T1S702.SUP
.IF (ERROR) .GOTO ERROR
.GOTO FILES
INFO::
.CHKPNT INFO
.PLEASE ** T1S702 ** CHKPNT INFO - Get some listing information
;*******************************************************************************
;			See if we want CREF listings
;*******************************************************************************
;
.ERROR
.R QUOLST
.IF (ERROR)
;
.NOERROR
.RUN ASL: PIP
*DSK:/D=LIST.KS
;
.ERROR ?
.OPERATOR $
;
.RUN ASL: TECO
=!ASK! $Do you want CREF listings ? (Y/N)
=^^TU1 Q1-78"E ONO' Q1-110"E ONO' Q1-89"E OYES' Q1-121"E OYES' OASK
=!NO! "[No CREF listings will be generated] OXIT
=!YES! "[CREF listings will be generated] EWLIST.KS
=!XIT! EX
;
.ERROR %
.NOOPERATOR
FILES::
.CHKPNT FILES
.PLEASE ** T1S702 **  CHKPNT FILES - Build indirect files
;*******************************************************************************
;			Build KS10 indirect files
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF (NOERROR) .GOTO FILESI
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
FILESI::
;
.COPY CONKS.CMD=KS10.FIL
.ERROR ?
;
;Format CONKS.CMD
.RUN TECO
=EBCONKS.CMD 25<A> J0L <.U1 S#; Q1-.D L;> EX
;
;Create LODKS.CCL
.ERROR ?
.RUN TECO
*EWLODKS.CCL I/NOINIT /HASH:6000 RS72Z/SAVE, RS72Z/MAP /CONTEN:NONE = /LOCALS -
*COMMON.RLS, MONBTS.RLS/SEARCH, COMDEV.RLS, COMNET.RLS, COMMOD.RLS, /SEARCH -
*TOPS10 /PATCH:100 /GO
= EX
;
;
.ERROR ?
.COPY PAT:=ASL:DECNET.FIL
.IF (ERROR) .GOTO BSKDCN
.RUN TECO
*ERDECNET.FIL 25<A> SD36PAR L -.D <.U1 :S#; Q1-.D :FS.REL.RLS; L> HXT HK
=EBCONKS.CMD 25<A> SD36PAR L GT EX
.RUN TECO
=EBLODKS.CCL 4<A> ZJ -L IDECNET.RLS,  EX
.GOTO CSKDCN
BSKDCN::
.RUN PIP
*DSK:DECNET.RLS/I=NUL:NUL.NUL
CSKDCN::
;
;Clean up
.NOERROR
.DELETE CONKS.BAK, LODKS.BAK
.ERROR
BUILD::
.CHKPNT BUILD
.PLEASE ** T1S702 **  CHKPNT BUILD - Beginning monitor assembly
;*******************************************************************************
;			Assemble KS10 modules
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO BUILDI
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
BUILDI::
;
;Find out if LIST.KS exists - if so, create CREF lstings
.ERROR %
.RUN DIRECT
*LIST.KS
.IF (NOERROR) .GOTO BUILD1
;
.ERROR
.COMPIL /COMPILE @CONKS.CMD
.IF (ERROR) .GOTO BUILD2
.GOTO BUILD3
;
BUILD1::
.ERROR
.COMPIL /COMPILE/CREF @CONKS.CMD
.IF (NOERROR) .GOTO BUILD3
;
BUILD2::
.PLEASE ** T1S702 ** Assembly errors exist
.GOTO ERROR
;
BUILD3::
COMBIN::
.CHKPNT COMBIN
.PLEASE ** T1S702 ** CHKPNT COMBIN - Building TOPS10.REL
;*******************************************************************************
;		Combine KS10 modules into TOPS10.REL
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO CMBKSI
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
CMBKSI::
;
.ERROR ?
.COPY PAT:=ASL:DECNET.FIL
.IF (ERROR) .GOTO CMBKSD
.NOERROR
.RUN PIP
*DSK:/D=DCNKS.CCL
.ERROR ?
;
;Create DCNKS.CCL
.RUN TECO
*ERDECNET.FIL 25<A> J0L SROUTER 0L -.D
*IDECNET.RLS/I= <:S#; R K I.RLS,> ZJ -D I
= EWDCNKS.CCL EX
;
;Create DECNET.RLS
.RUN PIP 50P
*DCNKS.CCL@
.IF (NOERROR) .GOTO CMBKSD
.PLEASE ** T1S702 ** Errors creating DECNET.RLS
.GOTO ERROR
;
;
CMBKSD::
.NOERROR
.RUN PIP
*DSK:/D=CMBKS.CCL
.ERROR ?
;
;Create CMBKS.CCL
.RUN TECO
*ERKS10.FIL 25<A> J0L SEJBDAT 0L -.D
*J0L ITOPS10.REL/I= <S#; -D K I.RLS,> ZJ -D I
= J0L SSYSINI.RLS I,EDDT.REL EWCMBKS.CCL EX
;
.RUN PIP 50P
*CMBKS.CCL@
.IF (NOERROR) .GOTO LOAD
.PLEASE ** T1S702 ** Errors creating TOPS10.REL
.GOTO ERROR
LOAD::
.CHKPNT LOAD
.PLEASE ** T1S702 ** CHKPNT LOAD - Begining RS72Z LOAD
;*******************************************************************************
;				RS72Z LOAD
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF (NOERROR) .GOTO LOADI
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
LOADI::
;
.RUN LINK
*@LODKS.CCL
.IF (NOERROR) .GOTO GLOB
.PLEASE ** T1S702 ** Errors creating RS72Z.EXE
.GOTO ERROR
GLOB::
.CHKPNT GLOB
.PLEASE ** T1S702 ** CHKPNT GLOB - Begining TOPS10 GLOB
;*******************************************************************************
;				TOPS10 GLOB
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.RUN GLOB
*COMMON.RLS,COMDEV.RLS,COMNET.RLS,COMMOD.RLS,MONBTS.RLS,DECNET.RLS,TOPS10.REL
*DSK:TOPS10.GLB=
.IF (ERROR) .PLEASE ** T1S702 ** Error creating monitor GLOB
LIST::
.CHKPNT LIST
.PLEASE ** T1S702 ** CHKPNT LIST - Generate CREF listings if required
;*******************************************************************************
;			Generate CREF listings if required
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
;Find out if LIST.KS exists - if so, run CREF
.ERROR %
.RUN DIRECT
*LIST.KS
.IF (ERROR) .GOTO LIST1
;
.ASSIGN DSK LPT
.CREF
.IF (ERROR) .PLEASE ** T1S702 ** Errors creating CREF listings
.DEASSIGN LPT
;
.ERROR ?
;
;Create QKS.CCL
.RUN TECO
*ERKS10.FIL 25<A> <S#; -D K I.LST
> EWQKS.CCL EX
;
;Sort QKS.CCL alphabetically
.RUN SORT
*QKS.CCL=QKS.CCL/KEY:1:6:ASCEND/RECORD:6/VARIABLE
;
.RUN TECO
=ERQKS.CCL 25<A> I/FORMS:MFI/PRIORI:1/OKNONE <.-Z;L2RI,-L> 4R2D EWQKS.CCL EX
;
.RUN QUEUE
*@QKS
;*MONGEN.LST/FORMS:MFI
.IF (ERROR) .PLEASE ** T1S702 ** Errors QUEUEing listings
.GOTO LIST2
;
LIST1::
.PLEASE ** T1S702 ** CREF listing not requested
;
LIST2::
EXIT::
.CHKPNT EXIT
.PLEASE ** T1S702 ** CHKPNT EXIT - End of stream
;*******************************************************************************
;				End of stream
;*******************************************************************************
;
.R QUOLST
.IF (ERROR)
;
.ERROR %
.PATH ASL:
.IF(NOERROR).GOTO EXITI
.R PEPB
*INITIALIZE TOPS-10-KS-V702
*EXIT
.IF (ERROR) .GOTO ERROR
.PATH ASL:/SEARCH
.IF (ERROR) .GOTO ERROR
EXITI::
;
.ERROR %
.R PEPB
*SIGNAL-SUCCESS TOPS-10-KS-V702
*EXIT
.GOTO END
;
%ERR:: .GOTO ERROR
%CERR:: .GOTO ERROR
%TERR:: .PLEASE ** T1S702 ** Time limit exceeded
.GOTO ERR2
;
ERROR::
.PLEASE ** T1S702 ** Stream has errors
ERR2::
;
.R PEPB
*SIGNAL-FAILURE TOPS-10-KS-V702
*EXIT
;
END::
;
%FIN:: .PLEASE ** T1S702 ** Stream finished
;
;[END OF T1S702.CTL]