Google
 

Trailing-Edge - PDP-10 Archives - bb-bt99q-bb - dbmv5a.ctl
There are 10 other files named dbmv5a.ctl in the archive. Click here to see a list.
;
;   DBMV5A.CTL -- Patch and rebuild DBMS-10-V5A
;   Version 1(4)
;	December 22, 1982  /  WTK
;	September 22, 1983 / HAH
;	March 20, 1984 / HAH
;	16-JUN-88 HAH ADD BRANCH FOR NO UPDATE
;	18-jul-89 HAH Make ASL: search directory
;
; 
;
;COPYRIGHT (c) 1982, 1983, 1984, 1985 BY
;	    Digital Equipment Corporation, Maynard, MA.
;
;   This software is furnished under a license and may be  used
;   and  copied  only  in  accordance  with  the  terms of such
;   license and with  the  inclusion  of  the  above  copyright
;   notice.   This software or any other copies thereof may not
;   be provided  or  otherwise	made  available  to  any  other
;   person.   No  title  to  and  ownership  of the software is
;   hereby transferred.
;
;   The information in	this  software	is  subject  to  change
;   without  notice and should not be construed as a commitment
;   by Digital Equipment Corporation.
;
;   Digital  assumes  no  responsibility   for	 the   use   or
;   reliability  of  its  software  on	equipment  which is not
;   supplied by Digital.
;
;
;
;   This .CTL file applies the  patches  to  the  libraries  of
;   DBMS-10-V5A and rebuilds the utility components.  DBCS   is
;   linked into  each  host  language  OTS  by  that  languages
;   patch/build .CTL file.
;
;   For this .CTL file to run, the connected directory must  be
;   the patching directory (PAT:).
;
;   This control file is expected to run without errors.
;
;
;
;
;
;
.ERROR
;
INIT::
;
.R PEPB
*INITIALIZE DBMS-10-V5A
*EXIT
.IF (ERROR) .GOTO TRUBLE
;
PATCH::
;
.ERROR %
.DIR PAT:DBMV5A.MKL
.IF (ERROR) .GOTO NOUPD
.ERROR
.RUN ASL:MAKLIB
*@PAT:DBMV5A.MKL
.IF (ERROR) .GOTO TRUBLE
NOUPD::
.ERROR
;
.PATH DEC:=ASL:
.PATH ASL:/SEARCH
;
BUILD::
;	START OF COPY FROM DBMS10.CTL
.SET WATCH VERSION
;
;
BLDSCH::
;CREATE SCHEMA PROCESSOR
;
.RUN ASL:LINK
*@DBMV5A.VER
*@ASL:SCHEM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:SCHEMA
.IF (ERROR) .GOTO TRUBLE
;
BLDFDM::
;CREATE FORTRAN PRE-PROCESSOR
;
.RUN ASL:LINK
*@DBMV5A.VER
*@ASL:FORDM1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:FORDML
.IF (ERROR) .GOTO TRUBLE
;
BLDMND::
;CREATE BACKUP/RECOVERY UTILITY
;
.RUN ASL:LINK
*@DBMV5A.VER
*@ASL:DBMEN1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBMEND
.IF (ERROR) .GOTO TRUBLE
;
BLDINF::
;CREATE INFO-GENERATING UTILITY
;
.RUN ASL:LINK
*@DBMV5A.VER
*@ASL:DBINF1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DBINFO
.IF (ERROR) .GOTO TRUBLE
;
BLDDAE::
;CREATE BACKGROUND MTA FACILITY
;
.RUN ASL:LINK
*@DBMV5A.VER
@ASL:DAEMD1
.IF (ERROR) .GOTO TRUBLE
.SSAVE DSK:DAEMDB
.IF (ERROR) .GOTO TRUBLE
;
;	END OF DBMS10.CTL COPY
;
;	DBCS IS BUILT IN THE HOST LAGUAGE OTS BY EACH
;	LANGUAGE'S AUTOPATCH PROCESS
;
;
;
ALLOK::
;	EVERYTHING WORKED...TELL HOW WE DID
.R PEPB
*SIGNAL-SUCCESS DBMS-10-V5A
*EXIT
;
.GOTO ENDOF
;
;
;	CATCH UNEXPECTED ERRORS
%ERR::
.GOTO TRUBLE
%TERR::
.GOTO TRUBLE
%CERR::
.GOTO TRUBLE
;
TRUBLE::
;	ALL ERRORS TRAP TO HERE
.R PEPB
*SIGNAL-FAILURE DBMS-10-V5A
*EXIT
;
;
ENDOF::
;	[ END OF DBMV5A.CTL ]