Google
 

Trailing-Edge - PDP-10 Archives - bb-d868a-bm - 3-sources/link.ctl
There are 46 other files named link.ctl in the archive. Click here to see a list.
!
!
! NAME:	LINK.CTL
! DATE: 27-FEB-78
!
!
!THIS CONTROL FILE IS PROVIDED FOR INFORMATION PURPOSES ONLY.  THE
!PURPOSE OF THE FILE IS TO DOCUMENT THE PROCEDURES USED TO BUILD
!THE DISTRIBUTED SOFTWARE.  IT IS UNLIKELY THAT THIS CONTROL FILE
!WILL BE ABLE TO BE SUBMITTED WITHOUT MODIFICATION ON CONSUMER
!SYSTEMS.  PARTICULAR ATTENTION SHOULD BE GIVEN TO ERSATZ DEVICES
!AND STRUCTURE NAMES, PPN'S, AND OTHER SUCH PARAMETERS.  SUBMIT
!TIMES MAY VARY DEPENDING ON SYSTEM CONFIGURATION AND LOAD.  THE
!AVAILABILITY OF SUFFICIENT DISK SPACE AND CORE IS MANDATORY.
!
!
! FUNCTION:	THIS CONTROL FILE BUILDS LINK V4 FROM ITS
!		SOURCE FILES.  IN ADDITION TO THE SOURCES, THE
!		FOLLOWING FILES ARE REQUIRED ON <SELF>, THE 
!		DIRECTORY UNDER WHICH LINK IS BEING BUILT:
!
!				LNKPRD.CMD
!				LNKDEB.CMD
!				LNKPLT.CMD
!				LNKLNK.CCL
!				OVRLAY.CMD
!
!		SUBMIT WITH THE COMMAND  @SUBMIT LINK/TIME:1::
!		OR, FOR DEBUG VERSION,	@SUBMIT LINK/TIME:1::/TAG:DEBUG
!
!	THIS CONTROL FILE IS SUBMITTED THREE TIMES:  THE FIRST TIME TO
!	BUILD LINK V4 USING MACRO V53 AND LINK V3A, AND THE OTHER
!	TIMES TO BUILD LINK V4 USING MACRO V54 AND LINK V4.  IN
;	BETWEEN THE SUBMISSIONS, THE PREVIOUS LINK V4 IS COPIED
;	TO A DIFFERENT NAME, SO THAT THE THREE LINK V4S CAN BE FILCOMED LATER.
;	THE COMPARISON IS DONE BY SUBMITTING M53-L4-FILCOM.CTL.
!
!THIS IS THE PRODUCTION VERSION
@COPY LNKPRD.CMD LNKCMD.CMD
@DEF DEC: PS:<FIELD-IMAGE>,PS:<REL>
@DEF SYS: DSK:,DEC:,SYS:
@GOTO GO	!AND GO BUILD IT
!
DEBUG::		!THIS IS THE DEBUG VERSION
@COPY LNKDEB.CMD LNKCMD.CMD
GO::
!SHOW WHERE THINGS ARE COMING FROM
!
@INFORMATION LOGICAL ALL
!
!
! TAKE A CHECKSUMMED DIRECTORY OF ALL THE INPUT FILES
!
@VDIR SYS:MACRO.EXE,SYS:LINK.EXE,SYS:FILCOM.EXE,SYS:SCAN.REL,SYS:HELPER.REL,SYS:JOBDAT.REL,SYS:C.UNV,SYS:SCNMAC.UNV,SYS:MONSYM.UNV,LNK*.MAC,PLT*.MAC,OVRLAY.MAC,
@CHECKSUM SEQ
@
!
!
! ASSEMBLE ALL THE SOURCES
! (FIRST TIME WITH MACRO V52, AND THE SECOND TIME WITH MACRO V53)
!
@COMPILE /COMPILE @OVRLAY.CMD
@COMPILE /COMPILE @LNKCMD.CMD
@COMPILE /COMPILE @LNKPLT.CMD
!
! LINK THEM AND SAVE A NEW LINK
! (FIRST TIME USING LINK V3A, AND THE SECOND TIME
!	USING LINK V4 BUILT FROM THE FIRST TIME.)
!
@R SYS:LINK
*@LNKLNK.CCL
!
@SAVE
!
@VDIR LINK.EXE,OVRLAY.REL,
@CHECKSUM SEQ
@
!
! DELETE THE OLD MAP FILE
@DELETE LINK.MAP
@EXPUNGE
!
! DELETE UNNECESSARY FILES
!
@DELETE LNK*.REL,PLT*.REL,*.UNV,LNKCMD.CMD
!
@PLEASE LINK CREATION SUCCESSFUL^[
!
@GOTO FIN
!
%CERR::
%ERR::
@PLEASE LINK CREATION UNSUCCESSFUL^[
!
FIN::
%FIN::
!
!