Google
 

Trailing-Edge - PDP-10 Archives - dec-10-omona-u-mc9 - mk002.ct
There are 2 other files named mk002.ct in the archive. Click here to see a list.
;%1(13) VERSION OF MK002  28 APR 1977   /MS/RAP
;THIS MK0001.CT FILE IS MASSAGED BY TECO TO HAVE ALL # # # 'S TURN
; INTO THE CURRENT VERSION NUMBER OF THE MONITOR AT WHICH TIME IT
; BECOMES MK002.CTL, THE CONTROL FILE WHICH LOADS A MONITOR FOR
; DECSYSTEM-10 #2 (OUR IN-HOUSE KA10 DEVELOPMENT SYSTEM).
;
MG002::  ;
.CHKPNT MG002
.SET WATCH ALL
.IF (ERROR)  ;O.K.
;
;AVOID USING VIRTUAL MEMORY
.SET PHYSICAL 256
.IF (ERROR)  ;OK, WE MUST BE ON A KA10
;
;THIS IS THE SYSTEM #2 HARDWARE CONFIGURATION
;
.RUN DSK:MONGEN
*
*HDW
*HDW002
*1050
*    R0###   Sys #2
*002	;CPU SERIAL NUMBER
*1	;DK10 CLOCKS
*N	;EXCLUDE MONITOR OVERHEAD?
*Y	;HIGH PRECISION TIME ACCOUNTING?
*1	;# OF DATA CHANNELS
*DF10	;TYPE CHANNEL
*0	;RC10 ON CHANNEL 0
*0	;RH10 FOR RS04
*0	;RH10 FOR RP04
*1	;RP10
*3	;DPA'S
*0	;# OF TM10BS
*0	;# OF TC10CS
*0	;# OF TM02'S
*1	;# OF TM10AS
*2	;MTA'S
*1	;MTA'S ON 7 TRACK
*	;END MAGTAPE DEFINITION
*	;END MAGTAPE DENSITY
*32	;JOBS
*	;MAX PAGES CORE/USER
*128	;TOTAL CORE
*60	;TICKS/SEC
*2	;REAL TIME DEVICES
*	;GUARANTEED CORE FOR NON-LOCKED JOBS
*3	;HPQ'S
*Y	;CCL
*Y	;METER
*Y	;SYSCHK
*Y	;MSGSER
*Y	;PSISER
*Y	;IPCSER
*Y	;ENQ/DEQ
*1	;CDR
*N	;CDP
*N	;DISPLAY
*1	;TD10 (DECTAPE CONTROLLER)
*4	;DTA'S
*1	;LPT
*Y	;LPT0 LOWER CASE
*0	;PLT'S
*Y	;PTP
*Y	;PTR
*15	;PTY'S
*N	;DC44
*0	;# OF DA28'S
*0	;# OF DC78'S
*	;DECIMAL VALUE DEFINITIONS
*A1050S,0
*PRVFIL,055
*LIMLVL,3
*DEFDEB,300000000000
*RTCH1,1
*MBFN,5		;NUMBER OF MONITOR BUFFERS
*M.DFNB,6	;DEFAULT NUMBER OF USER BUFFERS
*MTDLTP,1	;STANDARD MAGTAPE LABELS ARE ASCII
*	;END OCTAL VALUE DEFINITIONS
*	;SIXBIT VALUE DEFINITIONS
*	;DEV,PI
*	;DEV,PI,#
*	;DEV,PI,AC
;
;THIS IS THE SYSTEM #2 TELETYPE CONFIGURATION
;
.RUN DSK:MONGEN
*
*TTY
*TTY002
*1	;DC10'S
*1	;DC68'S
*0	;DC76'S
*2	;DC10B
*1	;DC10E
*20-27,10	;DC10E/DC10B CORRESPONDENCE
*
*32	;DC68 LINES
*CTY	;OPR
*10-17	;DATA SETS
*
;TABS
*2-7
*16
*20-47
*CTY
*
;ONLY THE CTY, TTY0 ("PLEASE") AND VT06 MAY LOG-IN AS [1,2]
*2-7	;REMOTE
*13-15
*20-47
*
*	;LOCAL COPY
*	;HALF DUPLEX
*	;SLAVES
*	;FORM FEED
;INITIA
*CTY
*0-7
*
*1,1	;FILLER FOR VT06
*
*	;2741 INTERFACE LINE #
;
;THIS IS THE SYSTEM #2 NETWORK CONFIGURATION
;
.RUN DSK:MONGEN
*
*NET
*NET002
*N	;NETWORKS NOT SUPPORTED
;
;END OF SYSTEM #2 MONGEN DIALOGUES.
;
;AT THIS POINT MK002.CTL EITHER CONTINUES PROCESSING ON ITS OWN OR RETURNS
; CONTROL TO WHATEVER OTHER FILE CALLED IT AS A SUBROUTINE....
.RUN DSKB:TECO[10,7]
*ERMK002.KLG
.IF (ERROR)  .GOTO MA002  ;CONTINUE PROCESSING IF MK002.KLG FILE NOT PRESENT.
;IF MK002.KLG FILE IS PRESENT IT CONTAINS A POINTER BACK TO THE FILE WHICH CALLED
; THIS FILE AS A SUBROUTINE, SO USE IT TO RETURN CONTROL AS FOLLOWS:
.SUBMIT MK002.KLG/UNIQ:0/AFTER:+0:01
.IF (ERROR)  .PLEASE CANNOT EXIT FROM MK002.CTL VIA MK002.KLG
;KILL THIS JOB IF IT WAS BEING USED AS A SUBROUTINE
.KJOB/F
;
;CONTINUE PROCESSING IF MK002.CTL WAS CALLED AS A MAIN JOB INSTEAD OF A SUBROUTINE.
;
;NEXT ASSEMBLE COMMON, COMDEV, COMNET, AND COMMOD FOR 1050 CONFIGURATION
;
MA002::  ;
.CHKPNT MA002
.SET WATCH ALL
.IF (ERROR)  ;OK
.PLEASE CHKPNT MA002
;
;AVOID USING VIRTUAL MEMORY
.SET PHYSICAL 256
.IF (ERROR)  ;OK, WE MUST BE ON A KA10
;
;NOTE:  SINCE THIS MONITOR IS FOR OUR "BASE" KA10 SYSTEM, ITS COMMON,
; COMDEV, COMNET, AND COMMOD WERE NORMALLY ASSEMBLED BY MONMKA.
; HOWEVER, PROVIDE FOR THE POSSIBILITY THAT MK002 IS BEING RUN WITHOUT HAVING
; RUN MONMKA.  ASSEMBLE COMMON ET AL ONLY IF .RLA FILES DO NOT EXIST......
.ASSIGN DSK SYS		;FORCE USE OF FIELD IMAGE COMPIL, MACRO
.RUN DSKB:TECO[10,7]
*ERCOMMON.RLA
.IF (NOERROR)  .GOTO A1
.ERROR %
.R MACRO
*F002/U,F002/C_FKA
*S002/U,S002/C_S
*COMMON.RLA,CMN002/C_HDW002,TTY002,NET002,COMMON
.IF (ERROR)  .PLEASE SYS#2 COMMON ASSEMBLY ERROR--MK002 PROCEEDING
A1::  ;
.RUN DSKB:TECO[10,7]
*ERCOMDEV.RLA
.IF (NOERROR)  .GOTO A2
.R MACRO
*F002/U,F002/C_FKA
*S002/U,S002/C_S
*COMDEV.RLA,CMV002/C_HDW002,TTY002,NET002,COMDEV
.IF (ERROR)  .PLEASE SYS#2 COMDEV ASSEMBLY ERROR--MK002 PROCEEDING
A2::  ;
.RUN DSKB:TECO[10,7]
*ERCOMNET.RLA
.IF (NOERROR)  .GOTO A3
.R MACRO
*F002/U,F002/C_FKA
*S002/U,S002/C_S
*NP002/U,NP002/C_NETPRM
*COMNET.RLA,CMT002/C_HDW002,TTY002,NET002,COMNET
.IF (ERROR)  .PLEASE SYS#2 COMNET ASSEMBLY ERROR--MK002 PROCEEDING
A3::  ;
.RUN DSKB:TECO[10,7]
*ERCOMMOD.RLA
.IF (NOERROR)  .GOTO A4
.R MACRO
*F002/U,F002/C_FKA
*S002/U,S002/C_S
*COMMOD.RLA,CMD002/C_HDW002,COMMOD
.IF (ERROR)  .PLEASE SYS#2 COMMOD ASSEMBLY ERROR--MK002 PROCEEDING
A4::	;
.ERROR
.DEASSIGN SYS
;
;NEXT WE ASK THE QUESTION "DO YOU WANT CREF LISTINGS ?"
;
MK002::  ;
.CHKPNT MK002
.SET WATCH ALL
.IF (ERROR)  ;O.K.
.RUN DSKB:TECO[10,7]
.OPERATOR %
*!BEG!
*% MK002 CREFS ?  (YES/NO)
*
*!GET! ^^TUM QM-9"EOGET' QM-32"EOGET' QMUN
*!MORE! QN-10"EOEOL' QN-27"EOEOL' QN-125"EOEOL' ^^TUN OMORE
*!EOL! QM-^^^^Y"E 
*GENERATE CREF LISTINGS
* ODONE'
*QM-^^^^N"E 
* ? CANCEL CREF LISTINGS
* ODONE' 
*% OPERATOR - YOU MUST TYPE YES OR NO
* OGET
=!DONE!
.NOOPERATOR
.IF (ERROR) .GOTO MJ002
;
MR002::  ;
.CHKPNT MR002
.SET WATCH ALL
.IF (ERROR)  ;OKAY
.ASSIGN DSK LPT
.ASSIGN MON QUE
;SPECIAL GALAXY HANDLING
.R ISIT ;GALAXY
.IF (NOERROR)  .LOCATE 50
.RUN DSKB:CREF[10,7]
*CMN002
.IF (NOERROR)  .QUEUE CMN002.LST/PRIORITY:1/FORM:NORMAF
.RUN DSKB:CREF[10,7]
*CMV002
.IF (NOERROR)  .QUEUE CMV002.LST/PRIORITY:1/FORM:NORMAF
.RUN DSKB:CREF[10,7]
*CMT002
.IF (NOERROR)  .QUEUE CMT002.LST/PRIORITY:1/FORM:NORMAF
.RUN DSKB:CREF[10,7]
*CMD002
.IF (NOERROR)  .QUEUE CMD002.LST/PRIORITY:1/FORM:NORMAF
.DEASSIGN LPT
.DEASSIGN QUE
.LOCATE
MJ002::  ;
.DELETE CM?002.CRF
.IF (ERROR)  ;OKAY
;
;NOW LOAD THE MONITOR FOR SYS#2
;
ML002::  ;
.CHKPNT ML002
.SET WATCH ALL
.IF (ERROR)  ; OKAY
.PLEASE CHKPNT ML002--BEGINNING SYS#2 LOAD
;
;AVOID USING VIRTUAL MEMORY
.SET PHYSICAL 256
.IF (ERROR)  ;OK, WE MUST BE ON A KA10
;
.RUN DSKB:PIP[10,7]
*R0###.MAP<157>_TTY:
=^Z
.IF (ERROR)  ; NICE TRY
;USE FIELD IMAGE VERSION OF LINK-10
.ASSIGN DSK SYS
.R LINK
.IF (ERROR)  .PLEASE  LINK-10 REQUIRED TO LOAD R0### - BETTER ABORT
*/NOINITIAL /HASH:6000 R0###/SAVE ,R0###/MAP /CONTENT:NONE = /LOCALS /MAXCOR:45K -
*COMMON.RLA,COMDEV.RLA,COMNET.RLA,COMMOD.RLA,TOPA10/SEARCH /PATCHSIZE:200 /GO
.IF (ERROR)  .PLEASE ERROR LOADING MONITOR R0### USING LINK10--PROCEEDING
.DEASSIGN SYS
;
;.PLEASE  IF YOU WANT R0###.MAP, YOU MUST PRINT IT BY HAND
.QUEUE R0###.MAP/PRIORITY:47/DISPOSE:PRESERVE
.IF (ERROR) .PLEASE COULDN'T PRINT R0###.MAP - PLEASE QUEUE BY HAND
;
;NOW PRODUCE AN .EXE FILE INSTEAD OF .SAV OR .HGH/.LOW
MN002::
.CHKPNT MN002
.SET WATCH ALL
.IF (ERROR)  ;OKAY
.SET PHYSICAL 256
.IF (ERROR)  ;OKAY, WE MUST BE ON A KA10
.GET R0###
.IF (ERROR)  .GOTO MQ002  ;NOT ENOUGH CORE TO .GET MONITOR
.NSAV R0###
.IF (NOERROR)  .GOTO MF002  ;R0###.EXE CREATED CORRECTLY
.PLEASE  NSAV R0### LOST -- ABORTING
.GOTO ME002
MQ002::
.RUN DEC:FILEX
*R0###.EXE=R0###.SAV
.IF (NOERROR)  .GOTO MF002
.PLEASE FILEX COULDN'T MAKE R0###.EXE -- ABORTING
.GOTO ME002
;
;CREATE FILDDT FOR THE SYS#2 MONITOR JUST LOADED
;
MF002::  ;
.CHKPNT MF002
.SET WATCH ALL
.IF (ERROR)  ;OKAY
.PLEASE  CHKPNT MF002--FILDDT
;
.RUN DSK:FILDDT
*R0###.EXE/S
.NSAV DSK:FR0###
.DELETE F002.*,S002.*,NP002.*,R0###.XPN,R0###.SAV
.IF (ERROR)  ;NICE TRY
;
;FINALLY, COPY RESULTS BACK TO THE BLACK PACKS
;
MC002::  ;
.CHKPNT MC002
.SET WATCH ALL
.IF (ERROR)  ;O.K.
.PLEASE CHKPNT MC002--READY TO COPY TO BLKA: ?
;THIS WAITS FOR OPERATOR TO CONTINUE......
.MOUNT BLKA:
.IF (ERROR) .PLEASE CAN'T MOUNT BLKA:--BETTER ABORT
.RUN DSKB:PIP[10,7]
*BLKA:[7,5112]<100>/X/B_R0###.EXE,R0###.MAP
.IF (ERROR) .PLEASE TROUBLE COPYING ONTO BLKA:
.GOTO MX002
%ERR:: .GOTO ME002
%CERR:: .GOTO ME002
ME002:: .PLEASE ERROR IN MK002--EXAMINE .LOG FILE
.QUEUE MK002.LOG/DISPOSE:PRESERVE
.GOTO MX002
MX002:: .PLEASE MK002 FINISHED
%FIN::  ;
.KJOB/F
;[END OF MK002.CT(L)]