Google
 

Trailing-Edge - PDP-10 Archives - decus_20tap1_198111 - decus/20-0020/bskbal.gam
There are 2 other files named bskbal.gam in the archive. Click here to see a list.
100'  NAME--BASKETBL
110'
120'  DESCRIPTION--DIGITAL> COLLEGE BASKETBALL
130'
140'  SOURCE--WRITTEN 5/67 AND REVISED 4/4/68 BY CHARLES R. BACHELLER '70.
150'
160'  INSTRUCTIONS--TYPE "RUN" AND FOLLOW INSTRUCTIONS.
170'
180'
190'  *  *  *  *  *    MAIN PROGRAM   *  *  *  *  *  *  *  *  *  *  *
200'
210 RANDOMIZE
220 PRINT "THIS IS PDP 10 TIMESHARING BASKETBALL. YOU WILL BE DIGITALS"
230 PRINT "  CAPTAIN AND PLAYMAKER.  CALL SHOTS AS FOLLOWS:  1. LONG"
240 PRINT "  (30 FT.) JUMP SHOT; 2  SHORT (15 FT.) JUMP SHOT; 3. LAY"
250 PRINT "  UP; 4. SET SHOT."
260 PRINT "BOTH TEAMS WILL USE THE SAME DEFENSE. CALL DEFENSE AS"
270PRINT"  FOLLOWS: 6  PRESS;  6.5  MAN-TO-MAN;  7  ZONE;  7.5  NONE."
280 PRINT "  TO CHANGE DEFENSE, JUST TYPE   0   AS YOUR NEXT SHOT."
290 PRINT "YOUR STARTING DEFENSE WILL BE";
300 INPUT D
310 IF D<6 THEN 1460
320 PRINT
330 PRINT "CHOOSE YOUR OPPONENT";
340 INPUT O$
350 PRINT "CENTER JUMP"
360 IF RND > 3/5 THEN 390
370 PRINT O$;" CONTROLS THE TAP."
380 GO TO 1500
390 PRINT "DIGITAL CONTROLS THE TAP."
400 PRINT
410 PRINT "YOUR SHOT";
420 LET P=0
430 INPUT Z
440 IF Z<>INT(Z) THEN 470
450IF ABS(Z-2)>2 THEN 470
460 GOTO 490
470 PRINT "INCORRECT ANSWER.  RETYPE IT";
480 GOTO 430
490 GO TO 500
500 IF RND <.5 THEN 680
510 IF T<100 THEN 680
520 PRINT
530 IF S(1)<>S(0) THEN 610
540 PRINT "   ***** END OF SECOND HALF *****"
550 PRINT "SCORE AT END OF REGULATION TIME:"
560 PRINT "        DIGITAL" S(1); O$" "S(0)
570 PRINT
580 PRINT "BEGIN TWO MINUTE OVERTIME PERIOD"
590 LET T=93
600 GO TO 350
610 PRINT "   ***** END OF GAME *****"
620 PRINT "FINAL SCORE: DIGITAL" S(1); O$" "S(0)
630 STOP
640 PRINT
650 PRINT "  ***  TWO MINUTES LEFT IN THE GAME  ***"
660 PRINT
670 RETURN
680 IF Z=1 THEN 710
690 IF Z=2 THEN 710
700 GO TO 1120
710 LET T=T+1
720 IF T=50 THEN 2190
730 IF T=92 THEN 750
740 GO TO 760
750 GOSUB 640
760 PRINT "JUMP SHOT"
770 IF RND >.341*D/8 THEN 810
780 PRINT "SHOT IS GOOD."
790 GOSUB 2160
800 GO TO 1500
810 IF RND >.682*D/8 THEN 990
820 PRINT "SHOT IS OFF TARGET."
830 IF D/6*RND>.45 THEN 860
840 PRINT "DIGITAL CONTROLS THE REBOUND."
850 GO TO 880
860 PRINT "REBOUND TO ";O$;"."
870 GO TO 1500
880 IF RND>.40 THEN 900
890 GO TO 1120
900 IF D=6 THEN 2080
910 PRINT "BALL PASSED BACK TO YOU. ";
920 GO TO 410
930 IF RND>.9THEN970
940 PRINT "PLAYER FOULED. TWO SHOTS."
950 GOSUB 1910
960 GO TO 1500
970 PRINT "BALL STOLEN. ";O$;"'S BALL."
980 GO TO 1500
990 IF RND>.782*D/8 THEN 1060
1000 PRINT "SHOT IS BLOCKED.  BALL CONTROLLED BY";
1010 IF RND>.5 THEN 1040
1020 PRINT " DIGITAL."
1030 GO TO 410
1040 PRINT " ";O$;"."
1050 GO TO 1500
1060 IF RND>.843*D/8 THEN 1100
1070 PRINT "SHOOTER IS FOULED.  TWO SHOTS."
1080 GOSUB 1910
1090 GO TO 1500
1100 PRINT "CHARGING FOUL.  DIGITAL LOSES THE BALL."
1110 GO TO 1500
1120 LET T=T+1
1130 IF T=50 THEN 2190
1140 IF T=92 THEN 1160
1150 GO TO 1170
1160 GOSUB 640
1170 IF Z=0 THEN 1460
1180 IF Z>3 THEN 1440
1190 PRINT "LAY UP."
1200 IF 7/D*RND>.4 THEN 1240
1210 PRINT "SHOT IS GOOD.  TWO POINTS."
1220 GOSUB 2160
1230GO TO 1500
1240 IF 7/D*RND>.7 THEN 1350
1250 PRINT "SHOT IS OFF THE RIM."
1260 IF RND>2/3 THEN 1300
1270 PRINT O$;" CONTROLS THE REBOUND."
1280 GO TO 1500
1290 
1300 PRINT "DIGITAL CONTROLS THE REBOUND."
1310 IF RND>.4 THEN 1330
1320 GO TO 1120
1330 PRINT "BALL PASSED BACK TO YOU.";
1340 GO TO 410
1350 IF 7/D*RND>.875 THEN 1390
1360 PRINT "SHOOTER FOULED.  TWO SHOTS."
1370 GOSUB 1910
1380 GO TO 1500
1390 IF 7/D*RND>.925 THEN 1420
1400 PRINT "SHOT BLOCKED. "O$;"'S BALL."
1410 GO TO 1500
1420 PRINT "CHARGING FOUL.  DIGITAL LOSES THE BALL."
1430 GO TO 1500
1440 PRINT "SET SHOT"
1450 GO TO 1200
1460 PRINT "YOUR NEW DEFENSIVE ALLIGNMENT IS";
1470 INPUT D
1480 IF D<6 THEN 1460
1490 GO TO 400
1500 LET P=1
1510 LET T=T+1
1520 IF T=54 THEN 2190
1530 IF T=92 THEN 1550
1540 GO TO 1560
1550 GOSUB 640
1560 PRINT
1570 LET Z1=10/4*RND+1
1580 IF Z1>2 THEN 1810
1590PRINT "JUMP SHOT"
1600 IF 8/D*RND>.35 THEN 1640
1610 PRINT "SHOT IS GOOD."
1620 GOSUB 2130
1630 GO TO 400
1640 IF 8/D*RND>.75 THEN 1750
1650 PRINT "SHOT IS OFF THE RIM."
1660 IF D/6*RND>.5 THEN 1690
1670 PRINT "DIGITAL CONTROLS THE REBOUND."
1680 GO TO 400
1690 PRINT O$;" CONTROLS THE REBOUND."
1700 IF D=6 THEN 2030
1710 IF RND>.5 THEN 1740
1720 PRINT "PASS BACK TO " O$;" GUARD."
1730 GO TO 1500
1740 GO TO 1810
1750 IF 8/D*RND>.9 THEN 1790
1760 PRINT "PLAYER FOULED.  TWO SHOTS."
1770 GOSUB 1910
1780 GO TO 400
1790 PRINT "OFFENSIVE FOUL. DIGITAL'S BALL"
1800 GO TO 400
1810 IF Z1>3 THEN 1890
1820 PRINT "LAY UP"
1830 IF 7/D*RND>.413 THEN 1870
1840 PRINT "SHOT IS GOOD."
1850 GOSUB 2130
1860 GO TO 400
1870 PRINT "SHOT IS MISSED."
1880 GO TO 1660
1890 PRINT "SET SHOT"
1900 GO TO 1830
1910 REM *FOUL SHOOTING*
1920 IF RND>.49 THEN 1970
1930 PRINT "SHOOTER MAKES BOTH SHOTS."
1940 LET S(1-P)=S(1-P)+2
1950 GOSUB 2140
1960 RETURN
1970 IF RND>.75 THEN 2010
1980 PRINT "SHOOTER MAKES ONE SHOT AND MISSES ONE."
1990 LET S(1-P)=S(1-P)+1
2000 GO TO 1950
2010 PRINT "BOTH SHOTS MISSED."
2020 GO TO 1950
2030 IF RND>.75 THEN 2050
2040 GO TO 1710
2050 PRINT "BALL STOLEN.  EASY LAY-UP FOR DIGITAL."
2060 GOSUB 2160
2070 GO TO 1500
2080 IF RND>.6 THEN 2100
2090 GO TO 910
2100 PRINT "PASS STOLEN BY ";O$;" EASY LAY-UP."
2110 GOSUB 2130
2120 GO TO 400
2130 LET S(0)=S(0)+2
2140 PRINT "SCORE: " S(1); "TO " S(0)
2150 RETURN
2160 LET S(1)=S(1)+2
2170 GOSUB 2140
2180 RETURN
2190 PRINT "   ***** END OF FIRST HALF *****"
2200 PRINT"SCORE: DIGITAL" S(1); O$" "S(0)
2210 PRINT
2220 PRINT
2230 GO TO 350
2240 END