Google
 

Trailing-Edge - PDP-10 Archives - decus_20tap1_198111 - decus/20-0020/lessee.tuk
There are 2 other files named lessee.tuk in the archive. Click here to see a list.
1 ' NAME--LESSEE
3 '
5 ' DESCRIPTION--LEASE ANALYSIS FROM POINT OF VIEW OF LESSEE
7 '
9 ' SOURCE--REVISED 7/8/68 BY J. GUERBER
11 '
13 ' INSTRUCTIONS
14 '     THIS PROGRAM COMPARES A LEASE WITH PURCHASE OF EQUIPMENT,
15 '     USING THE BOWER-WILLIAMSON METHOD OF ANALYSIS.  THE
16 '     EQUIPMENT IS DEPRECIATED ON SUM-OF-THE-YEARS DIGITS,
17 '     AND THE APPROPRIATE INVESTMENT TAX CREDIT IS TAKEN, FOR
18 '     THE PURCHASE ALTERNATIVE.
19 '
20 '     VALUES ARE REQUIRED FOR THE FOLLOWING VARIABLES:
21 '
22 ' 1. P = THE PURCHASE PRICE OF THE EQUIPMENT
23 ' 2. T = THE LESSEE'S INCOME TAX RATE
24 ' 3. R1= THE INTEREST RATE ON A LOAN, COMPOUNDED SEMI-ANNUALLY
25 ' 4. R2= THE OPPORTUNITY RATE THAT CAN BE EARNED, AFTER TAXES,
26 '        ON NEW INVESTMENTS, COMPOUNDED SEMI-ANNUALLY
27 ' 5. M = THE MONTHLY RENT, PAYABLE IN ADVANCE
28 ' 6. L = THE DEPRECIABLE LIFE OF THE EQUIPMENT, IN YEARS
29 ' 7. S1= THE SALVAGE VALUE FOR TAX PURPOSES
30 ' 8. S2= EXPECTED ACTUAL SALVAGE VALUE; MUST BE LESS THAN P
31 ' 9. E1= EXPENSES OF MAKING THE LEASE AGREEMENT
32 '10. E2= ANNUAL SAVING IN EXPENSES DUE TO THE LEASE
33 '11. Y = THE LENGTH OF THE LEASE IN YEARS
34 '12. J = THE LENGTH OF THE BASIC RENTAL PERIOD
35 '13. Z = 0 IF NO INVESTMENT TAX CREDIT TAKEN, OTHERWISE 1
36 '14. X = THE NUMBER OF THE VARIABLE FOR WHICH A SENSITIVITY ANALYSIS
37 '        IS TO BE DONE, 0 IF NO ANALYSIS, 1 IF ON PURCHASE PRICE,
38 '        2 IF INCOME TAX RATE, 3 IF INTEREST RATE, ETC.
39 '15. X1= THE LOWEST VALUE FOR THE VARIABLE SPECIFIED IN 14.
40 '16. X2= THE HIGHEST VALUE FOR THE VARIABLE SPECIFIED IN 14.
41 '
43 ' THIS PROGRAM WAS WRITTEN FOR STUDENT USE AT AMOS TUCK SCHOOL
45 ' OF HANOVER, N.H., WHICH DOES NOT ASSUME RESPONSIBILITY FOR
47 ' ITS ACCURACY.
49 '
51 ' * * * * * * * * * * * * * MAIN PROGRAM * * * * * * * * * * * 
53 '
100 READ P,T,R1,R2,M,L,S1,S2,E1,E2,Y,J,Z
110 READ X,X1,X2
120 DATA 60000,.48,.0475,.1
121 DATA 900,10,5000,10000
122 DATA 1000,3500,8,6,0
130 IF X=0 THEN 170
140 PRINT "DO YOU WANT THE SENSITIVITY ANALYSIS ONLY";
150 INPUT N$
160 IF N$="YES" THEN 280
170 GOSUB 430
180 PRINT "DO YOU WANT TO SEE THE FLOWS";
190 INPUT N$
200 IF N$="YES" THEN 230
210 LET F9=-1
220 GOTO 240
230 GOSUB 680
240 GOSUB 760
250 PRINT " "
260 GOSUB 1820
270 IF X=0 THEN 1900
280 PRINT "SENSITIVITY ANALYSIS ON ";
290 GOSUB 1350
300 PRINT " "
310 GOSUB 1350
320 PRINT TAB(30)"NET ADVANTAGE OF LEASE"
330 FOR F8= 0 TO 10
340    LET F9=-1
350    RESTORE 
360    READ P,T,R1,R2,M,L,S1,S2,E1,E2,Y,J,Z,X,X1,X2
370    GOSUB 1440
380    GOSUB 560
390    GOSUB 760
400    PRINT TAB(30);A1+V2
410 NEXT F8
420 STOP
430 PRINT "COMPARISON OF LEASE WITH PURCHASE"
440 PRINT "PURCHASE PRICE $";P,"TAX RATE";T   
450 PRINT "INTEREST RATE";R1,"OPPORTUNITY RATE";R2
460 PRINT "MONTHLY RENT";M,"DEPRECIABLE LIFE";L;"YEARS"
470 PRINT "SALVAGE FOR TAX $";S1,"EXPECTED SALVAGE $";S2
480 PRINT "EXPENSE OF ARRANGING LEASE $";E1
490 PRINT "ANNUAL EXPENSE SAVING DUE TO LEASE $";E2
500 PRINT "LEASE LENGTH";Y;"YEARS"
510 PRINT "BASIC RENTAL PERIOD";J;"YEARS"
520 IF X=0 THEN 560
530 PRINT "SENSITIVITY ANALYSIS ON ";
540 GOSUB 1350
550 PRINT " WITH A RANGE OF";X1;"TO";X2
560 IF Z = 0 THEN 630
570 LET C1 = .07*P
580 IF L>7 THEN 640
590 LET C1 = (2/3)*C1
600 IF L>5 THEN 640
610 LET C1=(1/2)*C1
620 IF L>3 THEN 640
630 LET C1 = 0
640 IF F9=-1 THEN 670
650 PRINT "INVESTMENT TAX CREDIT TO BE TAKEN $";C1
660 PRINT
670 RETURN
680 PRINT
690 PRINT TAB(50)"BASIC"
700 PRINT TAB(40)"OP'G FLO"TAB(50)"CASH FLO"TAB(60)"BASIC"
710 PRINT TAB(40)"DIFF'CE"TAB(50)"SAVING"TAB(60)"CASH FLOW"
720 PRINT TAB(30)"LOAN"TAB(40)"WITH"TAB(50)"WITH"TAB(60)"DISC. AT"
730 PRINT "YEAR";TAB(10)"RENT";TAB(20)"DEPREC'N";TAB(30)"INTEREST";
731 PRINT TAB(40)"LEASE";TAB(50)"LEASE";TAB(60);R2
740 PRINT
750 RETURN
760 LET R4 = (1+R1/2)^(1/6)-1
770 LET P1=(M/R4)*(1+R4-(1/(1+R4)^(12*J-1)))
780 LET A1 = P-P1
790 IF J = 0 THEN 810
800 LET B2 = M*P/P1
810 LET P2 = P
820 LET D1 = 0
830 LET V2 = 0
840 LET M1 = 12*M
850 LET I1=I2=I3=I4=I5=I6=0
860 FOR K = 1 TO Y
870    LET D = (P2-S1)*2*(L-K+1)/(L*(L+1))
880    IF D <= P2-S1-D1 THEN 900
890    LET D = P2-S1-D1
900    IF  D>=0THEN 920
910    LET D=0
920    LET D1=D1+D
930    LET B3 = 0
940    IF K > J THEN 1010
950    FOR I = 1 TO 12
960       LET B1 = R4*(P-B2)
970       LET B3 = B3+B1
980       LET B4 = B2-B1
990       LET P = P-B4
1000    NEXT I
1010    LET F = E2
1020    LET S3 = -E2
1030    IF K>1 THEN 1070
1040    LET F = E2-E1
1050    LET S3 = -F
1060    GO TO 1110
1070    IF K < Y THEN 1100
1080    LET F = E2-S2
1090    LET S3 = S2 - (P2-D1) - E2
1100    LET C1=0
1110    LET C = (M1+S3-D-B3)*T+F-C1
1120    IF K <=J THEN 1140
1130    LET C = C-M1
1140    LET V1 = C/(1+R2/2)^(2*K-1)
1150    LET V2 = V2 + V1
1160    LET U1 = INT (M1+.5)
1170    LET U2 = INT(D+.5)
1180    LET U3 = INT(B3+.5)
1190    LET U4 = INT(F+.5)
1200    LET U5 = INT(C+.5)
1210    LET U6 = INT(V1+.5)
1220    IF F9=-1 THEN 1300
1230    PRINT K;TAB(10);U1;TAB(20);U2;TAB(30);U3;TAB(40);U4;TAB(50);U5;TAB(60);U6
1240    LET I1=I1+U1
1250    LET I2=I2+U2
1260    LET I3=I3+U3
1270    LET I4=I4+U4
1280    LET I5=I5+U5
1290    LET I6=I6+U6
1300 NEXT K
1310 IF F9=-1 THEN 1340
1320 PRINT "TOTAL"TAB(10);I1;TAB(20);I2;TAB(30);I3;TAB(40);I4;TAB(50);I5;TAB(60);I6
1340 RETURN
1350 FOR H=1 TO X
1360    READ N$
1370 NEXT H
1380 PRINT N$;
1390 RESTORE
1400 RETURN
1410 DATA PURCHASE PRICE,TAX RATE,INTEREST RATE,OPPORTUNITY RATE,MONTHLY RENT
1420 DATA DEPRECIABLE LIFE,TAX SALVAGE,ACTUAL SALVAGE,LEASE EXPENSE
1430 DATA ANNUAL SAVING,LIFE OF LEASE,BASIC RENTAL PERIOD
1440 LET W=X1+(F8/10)*(X2-X1)
1450 ON X GOTO 1460,1490,1520,1550,1580,1610,1640,1670,1700,1730,1760,1790
1460 LET P=W
1470 PRINT P;
1480 RETURN
1490 LET T=W
1500 PRINT T;
1510 RETURN
1520 LET R1=W
1530 PRINT R1;
1540 RETURN
1550 LET R2=W
1560 PRINT R2;
1570 RETURN
1580 LET M=W
1590 PRINT M;
1600 RETURN
1610 LET L=W
1620 PRINT L;
1630 RETURN
1640 LET S1=W
1650 PRINT S1;
1660 RETURN
1670 LET S2=W
1680 PRINT S2;
1690 RETURN
1700 LET E1=W
1710 PRINT E1;
1720 RETURN
1730 LET E2=W
1740 PRINT E2;
1750 RETURN
1760 LET Y=W
1770 PRINT Y;
1780 RETURN
1790 LET J=W
1800 PRINT J;
1810 RETURN
1820 PRINT
1830 PRINT "FINANCIAL ADVANTAGE OF LEASE",A1
1840 PRINT
1850 PRINT "OPERATING ADVANTAGE OF LEASE",V2
1860 PRINT
1870 PRINT "NET ADVANTAGE OF LEASE",A1+V2
1880 RETURN
1890 DATA 0,0,0
1900 END