Trailing-Edge
-
PDP-10 Archives
-
decus_20tap2_198111
-
decus/20-0038/pdis.pal
There are 2 other files named pdis.pal in the archive. Click here to see a list.
/******PROGRAM PDIS.PAL, 1969******
/PETER LEMKIN
/NATIONAL INSTITUTES OF HEALTH
/BETHESDA, MD. 20014
/
/
/
/INTRODUCTION:
/------------
/PDIS IS A SUBROUTINE FOR THE LINC8 COMPUTER USED TO
/ACCESS THE LINC CPU'S POINT DISPLAY HARDWARE FROM
/THE PDP8 CPU. THIS GREATLY FACILITATES INCORPORATING THE
/LINC DISPLAY IN PDP8 PROGRAMS.
/
/
/
/
/HARDWARE REQUIRED:
/------------------
/LINC8 COMPUTER WITH AT LEAST 4K OF MEMORY.
/PDIS WILL COMPILE WITH PAL.
/
/
/
/
/
/DESCRIPTION:
/----------------
/SUBROUTINE PDIS IS A POINT DISPLAY ROUTINE WHICH CAN BE
/USED FOR DISPLAYING ARBITRARY SETS OF (X,Y) COORDINATES ON
/THE LINC DISPLAY SCOPE. IT MAY BE CALLED FROM ANY FIELD. IT SHOULD
/BE NOTED THAT THE DISPLAY ROUTINE MUST BE RESIDENT IN THE PART OF
/MEMORY WHICH CORRESPONDS TO THE CURRENT LINC CPU MEMORY BANK.
/THE (X,Y)=(0,0) POSITION IS THE ENTER OF THE SCREEN. (+X,+Y)
/IS TO THE RIGHT AND UP RESPECTIVELY.
/CALLING SEQUENCE:
/ JMS PDIS
/ Y /Y COORD -Y=-377, +Y=377
/ X /X COORD -X=-377, +X=377
/ NORMAL RETURN
/&
FIELD 0
*4000 /CORRESPONDS TO BANK 2 IN THE LINC CPU.
ISSP=6165
ICON=6141
/
/
/
/
PDIS, 0
CLA CLL
TAD I PDIS /GET Y
DCA Y
ISZ PDIS
TAD PK377 /COMPUTE THE REAL X NEEDED FOR THE DISPLAY
TAD I PDIS /GET X
DCA X
RDF /SET UP RETURN
TAD PKCIF
DCA PDISEX
CDF 00
TAD I PK4010 /SAVE MEMORY
DCA PKSAVE
ISZ PDIS /SET UP RETURN
/NOW GO GET SET TO LINC UP.
/CLEAR FLAGS
TAD PK11
ICON /CLEAR LINC HANGUPS
CLA
TAD GOLINC
ISSP
CLA
TAD PK10 /SELECT
ICON
TAD PK2
MP, ICON /GO DISP
CLA
TAD PK11 /DESELECT THE LINK
ICON
CLA
TAD PKSAVE /RESTORE MEMORY
DCA I PK4010
PDISEX, CIF 00
JMP I PDIS /RETURN
/*****CONSTANTS******
GOLINC, LINC
PKCIF, CIF 00
PKSAVE, 0
PK4010, 4010
PK377, 377
PK11, 11
PK10, 10
PK7, 7
PK2, 2
X, 0
Y, 0
/
/
/
/
/
/SUBROUTINE LINC
/IS A LINC CODE SUBROUTINE USED TO DISPLAY 1
/POINT AT X AND Y. IT IS CALLED AND STARTED BY PDIS.
/
/&
LINC, 0050 /SET 10 ----- LINC CODE
X-4000
1000 /LDA IN LINC CODE
Y-4000
150 /DIS 10....DISPLAY CHANNEL 0
0000 /HLT IN LINC CODE
/RETURN TO PDP8 CPU
/CHANGE BACK MODE.
/.....................................................
$