Google
 

Trailing-Edge - PDP-10 Archives - decuslib10-01 - 43,50110/reserv.bnk
There are 2 other files named reserv.bnk in the archive. Click here to see a list.
1' NAME--RESERVE
5' 
10' DESCRIPTION--CALCULATES RESERVE POSITION OF A BANK.
15'
20' SOURCE--REVISED 8/8/69 BY J. ROKUS
25'
30' THIS PROGRAM WAS WRITTEN FOR STUDENT USE AT AMOS TUCK SCHOOL
31' OF HANOVER, N.H., WHICH DOES NOT ASSUME RESPONSIBILITY FOR ITS
32' ACCURACY.
35'
40' * * * * * * * * * * * * MAIN PROGRAM * * * * * * * * * * * * 
45'
52 PRINT
54 PRINT
56 PRINT
58 PRINT TAB(16);"CALCULATION OF RESERVE POSITION"
60 PRINT
62 PRINT
64 PRINT"PLEASE ENTER THE FOLLOWING BALANCES IN THOUSANDS OF DOLLARS"
66 PRINT "AT THE CLOSE OF BUSINESS YESTERDAY"
68 PRINT
70 PRINT"DEMAND DEPOSITS OF BANKS";
72 INPUT C
74 PRINT "U.S. GOVERNMENT DEMAND DEPOSITS";
76 INPUT D
78 PRINT"OTHER DEMAND DEPOSITS";
80 INPUT E
90 PRINT "CASH ITEMS IN PROCESS";
100 INPUT F
110 PRINT"DEMAND DEPOSITS DUE FROM BANKS";
120 INPUT G
130 PRINT "TIME DEPOSITS";
140 INPUT H
150 PRINT"CURRENCY AND COIN";
160 INPUT H1
170 LET S = (C+D+E-F-G)*.12+.03*H-H1
180 LET S = INT(S+.5)
190 PRINT
200 PRINT
210 PRINT "THE REQUIRED RESERVE IS EQUAL TO"S
220 PRINT
230 PRINT
240 PRINT"WOULD YOU LIKE TO CALCULATE THE STATEMENT OF RESERVE POSITION"
250 PRINT"(YES OR NO)";
260 INPUT A1$
270 IF A1$="NO" THEN 9999
280 PRINT
290 PRINT"PLEASE ENTER THE FOLLOWING AMOUNTS:"
295 PRINT
300 PRINT"FEDERAL RESERVE BANK BALANCE YESTERDAY";
310 INPUT J
320 PRINT"NUMBER OF DAYS REMAINING IN THE PERIOD";
330 INPUT J1
340 PRINT"CUMULATIVE EXCESS OR DEFICIENCY(-) AS OF YESTERDAY";
350 INPUT J2
360 PRINT"FEDERAL FUNDS RATE (IN DECIMALS)";
365INPUT K8
370 PRINT"COLLECTED FLOAT TO BE CREDITED TODAY";
380 INPUT K1
390PRINT"CASH LETTER";
400 INPUT K
410 PRINT"SECURITIES COLLECTED OR PURCHASED (-) BY THE FED";
420 INPUT L
430 PRINT "CASH SHIPPED OR ORDERED (-)";
440 INPUT M
450 PRINT"TRANSFERS IN OR OUT (-)";
460 INPUT N
470 PRINT "TREASURY TAX & LOAN CHARGE";
480 INPUT O
485 LET O=-(O)
490 PRINT"OTHER CREDITS OR DEBITS(-)";
500 INPUT P
510 PRINT
512PRINT"FUTURE TRANSACTIONS -CREDITS OR DEBITS(-)";
513 INPUT P9
520 PRINT
530 PRINT
550 PRINT TAB(15);"STATEMENT OF RESERVE POSITION"
560PRINTTAB(11);J1;"DAYS REMAINING IN RESERVE PERIOD"
565 PRINT TAB(18);"(THOUSANDS OF DOLLARS)"
570 PRINT
580 PRINT
590 PRINT "RESERVE BALANCE AT THE CLOSE YESTERDAY",TAB(55),FNF(J,12,3)
600 PRINT " ADD COLLECTED FLOAT TO BE CREDITED TODAY";
602 PRINT TAB(55),FNF(K1,12,3)
605 PRINT TAB(59);"--------"
610 PRINT TAB(30),"SUBTOTAL",TAB(55),FNF(J+K1,12,3)
620 PRINT "LESS CASH LETTER",TAB(55),FNF(K,12,3)
625 PRINT TAB(59);"--------"
630 PRINT TAB(30),"SUBTOTAL",TAB(55),FNF(J+K1-K,12,3)
640 PRINT
650 PRINT "SECURITIES COLLECTED OR PURCHASED(-)",TAB(40),FNF(L,12,3)
660 PRINT "CASH SHIPPED OR ORDERED(-)",TAB(40),FNF(M,12,3)
670 PRINT "TRANSFERS IN OR OUT(-)",TAB(40),FNF(N,12,3)
680 PRINT "TREASURY TAX & LOAN CHARGE",TAB(40),FNF(O,12,3)
690 PRINT "OTHER CREDITS OR DEBITS(-)",TAB(40),FNF(P,12,3);
700 LET B1=L+M+N+O+P
710 PRINT TAB(55),FNF(B1,12,3)
720 PRINT TAB(59);"--------"
730 LET B2=J+K1-K+B1
740 PRINT "ESTIMATED RESERVE BALANCE AT CLOSE TODAY";TAB(55);
745 PRINT FNF(B2,12,3)
750 PRINT " LESS REQUIRED RESERVE",TAB(55),FNF(S,12,3)
760 PRINT TAB(59);"--------"
770 PRINT "INDICATED RESERVE EXCESS OR DEFICIENCY";TAB(55);
775 PRINT FNF(B2-S,12,3)
780 PRINT "PRIOR CUMULATIVE EXCESS OR DEFICIENCY";TAB(55);FNF(J2,12,3)
790 LET B3=B2-S+J2
800 PRINT TAB(59);"--------"
810 PRINT "CUMULATIVE EXCESS OR DEFICIENCY TO DATE";TAB(55);FNF(B3,12,3)
830 PRINT
840 PRINT
842 PRINT "CUM. EXCESS OR DEF. AFTER FUTURE TRANSACTIONS";TAB(55);
843 PRINT FNF(B3+P9,12,3)
845PRINT
846 PRINT "AVERAGE FOR DAYS REMAINING";TAB(55);FNF((B3+P9)/J1,12,3)
850 PRINT
852PRINT
860PRINT"LEVEL OF","REQUIRED","EXCESS OR","CUMULATIVE","FED  FUNDS"
870 PRINT"DEMAND DEP","RESERVE","DEFICIENCY","POSITION","VALUE"
880 PRINT"----------","-------","----------","--------","-------"
881 LET X7=C+D+E
882 LET X8=INT((X7-X7*.1)/100+.5)*100
883 LET X9=INT((X7+X7*.1)/100+.5)*100
884 LET X5=INT((X8*.01)/100+.5)*100
885 IF X5<10 THEN 887
886 GO TO 888
887 LET X5=100
888 FOR I=X8 TO X9 STEP X5
890 LET B4=(I-F-G)*.12+.03*H-H1
900 LET B5=B2-B4
910 LET B6=B5+B3
920 LET B7=B6*(K8/360)*1000
925LET B7=INT(B7+.5)
935 PRINT I,B4,B5,B6,B7
940NEXTI
1000 DEF FNF(X1,W9,D9)
1010 DIM V(25)
1020 LET V9=INT(ABS(X1)*10^D9+.5)
1030 IF V9<10^(W9-1) THEN 1060
1040 LET FNF=X1
1050 GOTO 1280
1060 FOR V8=W9 TO W9-D9+1 STEP -1
1070 LET V(V8)=V9-10*INT(V9/10)+48
1080 IF V(V8)<58 THEN 1100
1090 LET V(V8)=0
1100 LET V9=INT(V9/10)
1110 NEXT V8
1120 LET V(W9-D9)=46
1130 FOR V8=W9-D9-1 TO 1 STEP -1
1140 LET V(V8)=V9-10*INT(V9/10)+48
1150 IF V(V8)<58 THEN 1170
1160 LET V(V8)=0
1170 LET V9=INT(V9/10)
1180 IF V9=0 THEN 1200
1190 NEXT V8
1200 IF X1>=0 THEN 1230
1210 LET V(V8-1)=45
1220 LET V8=V8-1
1230 FOR V8=V8-1 TO 1 STEP -1
1240 LET V(V8)=32
1250 NEXT V8
1260 LET V(0)=W9
1270 LET FNF=V
1280 FNEND
9999 END