Google
 

Trailing-Edge - PDP-10 Archives - decuslib20-01 - decus/20-0020/nick63.tuk
There are 2 other files named nick63.tuk in the archive. Click here to see a list.
1'
2' DESCRIPTION--REQUIRED CONTINUATION OF GROWTH TO JUSTIFY PRICE
3'
4' SOURCE--UNKNOWN
5'
6' THIS PROGRAM WAS WRITTEN FOR STUDENT USE AT AMOS TUCK SCHOOL
7' WHICH DOES NOT ASSUME RESPONSIBILITY FOR ITS ACCURACY.
8'
9' * * * * * * * * * * MAIN PROGRAM * * * * * * * * * * * * 
10  READ P
20  IF P = -1 THEN 50
30  READ X(0),X(1),R,D
40  GO TO 180
50  PRINT "ENTER THE FOLLOWING INFORMATION SEPERATED BY COMMAS"
60  PRINT "    CURRENT MARKET PRICE"
80  PRINT "    CURRENT EARNINGS"
100 PRINT "    NORMALIZED EARNINGS NEXT PERIOD"
120 PRINT "    MARKET CAPITALIZATION RATE"
140 PRINT "    PAYOUT RATIO"
160 INPUT P,X(0),X(1),R,D
165 PRINT 
170 PRINT "IN THE FUTURE YOU MAY ENTER THIS INFORMATION AS 'DATA' ";
171 PRINT "IN LINE 0"
172 PRINT 
180 DIM X(100),Y(100)
182 IF R>.05 THEN 190
184 PRINT "CAPITALIZER MUST BE GREATER THAN LONG RUN GROWTH RATE"
185 PRINT "ENTER LARGER CAPITALIZER";
186 INPUT R
187 GOTO 182
190 PRINT "     WHAT IS THE EXPECTED RATE OF GROWTH IN EARNINGS";
200 INPUT G1
210 LET G2 = .05
211 PRINT
212 PRINT "WOULD YOU LIKE A LONG-TERM GROWTH RATE OTHER THAN .05";
213 INPUT Q$
214 IF Q$="NO" THEN 220
215 PRINT "WHAT RATE";
216 INPUT G2
220 PRINT 

230 GOSUB 490
240 LET T1 = 2
250 LET T2 = 3
260 GOSUB 350
270 GOSUB 390
280 IF V(1) > P THEN 660
285 IF G1<0 THEN 674
290 LET T2 = T2+1
300 GOSUB 350
310 GOSUB 390
315 IF T2>50 THEN 672
320 IF V(1) < P THEN 290
330 GOSUB 620
340 GO TO 690
350 FOR I = T1 TO T2
360   LET X(I) = X(I-1)*(1+G1)
370 NEXT I
380 RETURN
390 FOR I = 1 TO T2
400   LET Y(I) = X(I)*D
410 NEXT I
420 LET Y(T2) = Y(T2)+(Y(T2)*(1+G2)/(R-G2))
430 LET J = 1
440 LET V(J) = 0
450 FOR I = J TO T2
460   LET V(J) = V(J)+Y(I)/(1+R)^(I-J+1)
470 NEXT I
480 RETURN
490 PRINT "GIVEN:"
500 PRINT "------"
510 PRINT
520 PRINT " ","CURRENT PRICE",P
530 PRINT "CURNT EARNINGS",X(0),"NORMAL EARNINGS",X(1)
540 PRINT "DISCOUNT RATE",R,"PAYOUT RATE",D
550 PRINT "CURRENT GROWTH",G1,"NORMAL GROWTH",G2
560 PRINT
570 PRINT
580 PRINT "IT FOLLOWS:"
590 PRINT "-----------"
600 PRINT
610 RETURN
620 PRINT
630 PRINT "GROWTH MUST CONTINUE AT THE CURRENT RATE FOR AT LEAST"
640 PRINT T2 "YEARS TO JUSTIFY THE CURRENT PRICE"
650 RETURN
660 PRINT "EVEN IF GROWTH RETURNS TO NORMAL AFTER 1 MORE YEAR"
670 PRINT "THE CURRENT PRICE OF THIS STOCK IS JUSTIFIED."
671 STOP
672 PRINT "GROWTH AT CURRENT RATE IS IN EXCESS OF 50 YEARS."
673 STOP
674 PRINT "THIS NEGATIVE RATE OF GROWTH YIELDS NO SOLUTION."
680 DATA -1
690 END