Trailing-Edge
-
PDP-10 Archives
-
decuslib20-01
-
decus/20-0020/sales.bnk
There are 2 other files named sales.bnk in the archive. Click here to see a list.
100 PRINT "HOW MANY DEPARTMENTS DO YOU HAVE";
110 INPUT D
120 PRINT "PERIOD LENGTH(MOS)";
130 INPUT P9
140 LET D9 = 100 * 30 * P9
150 PRINT "COMPANY NAME";
160 INPUT C$
170 PRINT ""
180 PRINT "FOR EACH DEPARTMENT ENTER:"
190 PRINT " SALES,BEGINNING INVENTORY, ENDING INVENTORY, PURCHASES"
200 PRINT
210 FOR N = 1 TO D
220 PRINT N;
230 INPUT S(N),B(N),E(N),P(N)
240 LET C(N) = P(N) + B(N) -E(N)
250 LET G(N) = S(N) - C(N)
260 NEXT N
270 PRINT" "
280 PRINT"---------------------------------------------------------------------------"
290 PRINT
300 PRINT C$
310 PRINT
320 PRINT TAB(46)"GROSS";TAB(58);"% GROSS"
330 PRINT TAB(10)"SALES";TAB(22)"C/G/S";TAB(34)"%C/G/S";
340 PRINT TAB(46)"PROFIT";TAB(58)"PROFIT"
350 PRINT
360 FOR N = 1 TO D
370 PRINT "DEPT"N;
380 PRINT TAB(10) ;S(N);TAB(22);C(N);
390 PRINT TAB(34);INT(10000*C(N)/S(N) + .5)/100;
400 PRINT TAB(46);G(N);TAB(58);INT(10000*G(N)/S(N) +.5)/100
410 LET X = X + S(N)
420 LET Y = Y + C(N)
430 LET Z = Z + G(N)
440 LET W = W + E(N)
450 NEXT N
460 PRINT
470 PRINT "TOTALS";TAB(10);X;TAB(22);Y;TAB(34);INT(10000*Y/X +.5)/100;
480 PRINT TAB(46);Z;TAB(58);INT(10000*Z/X + .5)/100
490 PRINT
500 PRINT
510 PRINT
520 PRINT TAB(10)"PERCENT"TAB(22);"PERCENT"TAB(34)"PERCENT";
530 PRINT TAB(46) "PERCENT"; TAB(58)"DAYS"
540 PRINT TAB (10);"OF SALES";TAB(22)"OF C/G/S";TAB(34);"GROSS PFT";
550 PRINT TAB(46);"INVENTORY";TAB(58);"INVENTORY"
560 PRINT
570 PRINT
580 FOR N = 1 TO D
590 PRINT "DEPT" N;
600 PRINT TAB(10);INT(10000*S(N)/X + .5)/100;
610 PRINT TAB(22);INT(10000*C(N)/Y + .5)/100;
620 PRINT TAB(34); INT(10000*G(N)/Z + .5)/100;
630 PRINT TAB(46);INT(10000*E(N)/W + .5)/100;
640 PRINT TAB(58);INT ( D9*( (B(N)+E(N)) / (2*C(N)) ) + .5)/100;
650 PRINT "DAYS"
660 NEXT N
670 PRINT
680 PRINT "OVERALL INVENTORY TURNOVER";
690 PRINT INT(D9*(W/Y) +.5)/100;"DAYS"
700 PRINT
710 PRINT"---------------------------------------------------------------------------"
720 END