Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

!-*-TECO-*- Personal Emacs Initialization for Leonard N Zubkoff. !


!*
	Author:		Leonard N Zubkoff
	Revision:	03/03/81 00:56:28
!


!* Define some Variables... !

!* Only wait 1/2 second before echoing prompt or prefix. !
15 M.V Read Line Delay

!* Put Auto Save on by default every 300 keystrokes. !
1 M.V Auto Save Default
300 M.V Auto Save Interval

!* Set Fill Column to 72. !
72 UFill Column


!* Define some Hooks... !

!* Always auto-fill Text. !
@:I*|1 M.L Auto Fill Mode| M.V Text Mode Hook

!* Also always auto-fill Scribe. !
@:I*|1 M.L Auto Fill Mode| M.V Scribe Mode Hook

!* Comment Column in Lisp Mode should be 40. !
@:I*|40 M.L Comment Column| M.V Lisp Mode Hook

!* Save All Files on Exit. !
@:I*|M(M.M Save All Files)| M.V Exit Hook


!* Define some Command Characters... !

!* Make C-M-L be ReDisplay Screen to C100 program. !
!* with argument, ReDisplay current line only. !
@:I*|
   27 FS Image Out
   FF-1"E 124 FS Image Out' "# 123 FS Image Out'
   0  | U...L

!* Make M-R be Replace String. !
M.M ^R Replace String U..R

!* Make M-Q be Query Replace. !
M.M ^R Query Replace U..Q

!* Make M-: be Save Files and Execute previous Exec Command. !
@:I*|
   M(M.M ^R Save File)
   M(M.M Save All Files)
   EX | U..:

!* Make M-' be Move to End of Line and Tab to Column 72 if necessary. !
@:I*|
   :L .[0
   !Col72! (FS H Position - 72)"L 9I OCol72'
   Q0,.  | U..'


!* Make C-X C-S update Revision: before writing file if modified. !
@:I*|
   FS Modified"N
      .[0 0J 1:<:SRevision:	; K FS Date FS FD Convert I
 > Q0 J '
   M(M.M ^R Save File)
   0  | U:.X()

!* If the System doen't know what Baud Rate the terminal is using, !
!* set it to 1200 baud to avoid excessive padding. !

@:I*| 2 FS Echo Lines FS OSpeed"E 1200 FS OSpeed' | FS TTY Macro
FS TTY Init


!* Terminal Display Customizations... !

M(M.M Load Library)Slowly	    !* Load Slowly. !
:IDefault Separator__________    !* Change Default Separator. !
3 USlow Search Lines Used	    !* Lines for Incremental Search. !
-1 FS Echo Errors		    !* Put error messages in echo area. !


!* Mode Line Customizations... !

F[B Bind			    !* Save current Buffer. !
G..J				    !* Get Mode Line. !
FS UName[0			    !* Get User's Name. !
J I 0 Emacs			    !* Go to beginning and add Name. !
J HX..J				    !* Update Mode Line .!
:I* 0 EmacsUEditor Name	    !* Change Editor Name. !
]0				    !* Restore Q Register 0. !
F]B Bind			    !* Restore Buffer. !
1 FS Inv Mod			    !* Mode Line to be Reverse Video. !


!* Setup a default Auto Save File Name. !

FS MSName[0
:IAuto Save Filenames0Emacs.Save.
]0


!* Now it's ok to process the EVARS file and risk an error.  The EVARS file !
!* should not be processed twice, e.g. in case it loads libraries, and a !
!* dumped EMACS should be able to jump to the default init.  Hence the !
!* variable check. !

0 FO..Q Init Vars Processed"E	    !* If not yet done it, process. !
   M(M.M & Process Init Vars)	    !* EMACS.VARS. !
   1 M.V Init Vars Processed '	    !* Do not do it again. !

FS XJName			    !* Put Job Name in Q Register J. !


!* See if this Emacs is a LEDIT inferior to a Lisp fork.  If so, !
!* just load the LEDIT Library.  Otherwise, attempt to parse the JCL !
!* for a File Name and Initial Teco Commands. !

FS LispT"N			    !* If were we started by a Superior. !
   F~JLEDIT"E			    !* And our Job Name is LEDIT. !
      M(M.M Load Library)PS:<Maclisp>LEDIT    !* Then Load LEDIT Library. !
       ''			    !* And Return to ^R Mode. !
   				    !* Otherwise... !


!* Load MMAIL if appropriate... !

F~JMM"E			    !* If our Job Name is MM. !
   M(M.M Load Library)MMAIL	    !* Then Load Library MMAIL. !
   0M.VExit Hook'		    !* And inhibit Save All Files on Exit. !


!* Process the JCL... !

0[0 0[1				    !* Save Q Registers 0 and 1. !
				    !* File Name goes in Q Register 0. !
				    !* Commands go in Q Register 1. !
FJ				    !* Retrieve JCL. !
J @F K			    !* Flush leading Spaces and CRLF. !
ZJ ."N				    !* Extract File Name and Commands. !
   0,0A-
"E -D'		    !* Remove LF at End. !
"E 0,0A-   !* Remove CR at End. !
   J <:S$; -D 27I>		    !* Replace Dollar Signs with Escapes. !
   J :S!/"N .,Z@FX1 -2D'	    !* If there are Commands to execute, put !
				    !* them in Q Register 1. !
   J <:S!; .-1,(:S! .)K>  !* Delete confirmations. !
   J 7F~(FILE) "E 7D	'	    !* Delete stupid noise word.!
   :S  B,.FX0 '		    !* Put Name of File into Q Register 0. !

HK 0 FS Modified		    !* Clear Buffer. !

Q0"N M(M.M Visit File)0 '	    !* Visit File. !

Q1"N M1 '			    !* Execute any JCL Commands. !

				    !* Return to ^R Mode. !


!* End of Personal Emacs Customization. !