Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

	SUBTTL	Introduction

; Copyright (c) 1980 Stevens Institute of Technology, Hoboken, New Jersey
; 07030.

; This software may be used and copied provided that this copyright notice
;is included, and provided that copies of all modifications are sent to:
;
;	TECO Project
;	Computer Center
;	Stevens Institute of Technology
;	Castle Point Station
;	Hoboken, New Jersey    07030
;
;
; The information in this software is subject to change without notice
; and should not be construed as a commitment by Stevens Institute of
; Technology.

  ; Search needed universals

	SEARCH	TECUNV		; TECO universal file

  ; Generate the prologue


	TECVER==200		; Major version number
	TECMIN==1		; Minor version number
	TECEDT==1126		; Edit level
	TECWHO==0		; Last editor


	PROLOGUE(DTP,<TECO Datapoint terminal support>)	; Generate the TITLE and other stuff

	$CODE			; Put into code PSECT

	SUBTTL	Table of Contents

;+
;.pag.lit

;		Table of Contents for TECDTP - Datapoint terminal support
;
;
;			   Section			      Page
;   1. Introduction . . . . . . . . . . . . . . . . . . . . .    1
;   2. Table of Contents. . . . . . . . . . . . . . . . . . .    2
;   3. Revision History . . . . . . . . . . . . . . . . . . .    3
;   4. Tables
;        4.1.   Datapoint . . . . . . . . . . . . . . . . . .    5
;   5. Support routines
;        5.1.   Datapoint
;             5.1.1.     Control U. . . . . . . . . . . . . .    6
;             5.1.2.     Delete a line feed . . . . . . . . .    7
;             5.1.3.     Delete a vertical tab. . . . . . . .    8
;             5.1.4.     Delete a form feed . . . . . . . . .    9
;   6. Low segment. . . . . . . . . . . . . . . . . . . . . .   10
;   7. End of TECDTP. . . . . . . . . . . . . . . . . . . . .   11

;.end lit.pag
;-

	SUBTTL	Revision History
COMMENT	|

1000	Start of this version

Start of Version 200A(1126)
|

; Macro to define a word of five characters
	DEFINE	TB(A<.CHNUL>,B<.CHNUL>,C<.CHNUL>,D<.CHNUL>,E<.CHNUL>)
<	BYTE	(7)A,B,C,D,E>

	SUBTTL	Tables -- Datapoint

	CRTINI	VDPT
	CRTENT	BCK,<TB(.CHCNH,.CHCNY)>
	CRTENT	SPC,<TB(" ")>
	CRTENT	DBS,<TB(.CHCCF)>
	CRTENT	DLF,<PUSHJ P,DTPDLF>	; Delete a line feed
	CRTENT	DVT,<PUSHJ P,DTPDVT>	; Delete a vertical tab
	CRTENT	DFF,<PUSHJ P,DTPDFF>	; Delete a form feed
	CRTENT	CRB,<TB(.CHCNH,.CHCNY)>
	CRTENT	CBS,<TB(.CHCNY)>
	CRTENT	CTU,<PUSHJ P,DTPCTU>	; Control U sequence
	CRTEND

	SUBTTL	Support routines -- Datapoint -- Control U

;+
;.HL1 DTPCTU
;This routine will process the control U in the command parser.  It
;may be called without CRT being set up.
;.literal
;
; Usage:
;	MOVE	CRT,CRT.block.address
;	PUSHJ	P,@$CRCTU(CRT)
;	(Return)
;
;.end literal
;-

DTPCTU:	MOVX	T1,<BYTE (7).CHCRT,.CHCCF> ; Get the string
	PUSHJ	P,SC$STR	; Output the string
	MOVX	CH,.CHCRT	; Get the character to output
	PJRST	T$OCHR		; Output the character

	SUBTTL	Support routines -- Datapoint -- Delete a line feed

;+
;.HL1 DTPDLF
;This routine will send the character string to delete a line feed.
;.literal
;
; Usage:
;	MOVE	CRT,CRT.block.address
;	PUSHJ	P,@$CRDLF(CRT)
;	(Return)
;.end literal
;-

DTPDLF:	MOVX	CH,.CHCNZ	; Get the character to delete a line feed
	PJRST	SC$IMG		; Output it

	SUBTTL	Support routines -- Datapoint -- Delete a vertical tab

;+
;.HL1 DTPDVT
;This routine will send the character string to delete a vertical tab.
;.literal
;
; Usage:
;	MOVE	CRT,CRT.block.address
;	PUSHJ	P,@$CRDVT(CRT)
;	(Return)
;
;.end literal
;-


DTPDVT:	MOVX	T1,4		; Get the number of times to loop
DTPCMN:	MOVX	CH,.CHCNZ	; Get the character to output
	PUSHJ	P,SC$IMG	; Output it
	SOJG	T1,.-1		; Loop until done
	POPJ	P,		; Return to the caller

	SUBTTL	Support routines -- Datapoint -- Delete a form feed

;+
;.HL1 DTPDFF
;This routine will send the character string to delete a form feed.
;.literal
;
; Usage:
;	MOVE	CRT,CRT.block.address
;	PUSHJ	P,$CRDFF(CRT)
;	(Return)
;
;.end literal
;-

DTPDFF:	MOVX	T1,10		; Get the number of times to loop
	PJRST	DTPCMN		; Enter the common code

	SUBTTL	Low segment

	$IMPURE			; Put in correct place

DTPBEG:!

	LOWVER(DTP,<.-DTPBEG>); Define the version number

	SUBTTL	End of TECDTP

	END			; End of TECDTP