Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

$ VERIFY = F$VERIFY(0)
$!
$! TVMACROS.COM
$!	COM-file, to put TVMACROS.MAR into TV.MLB,
$!	the TV-macro-library.
$!	TV.MLB will be created, if non-existent.
$!
$! Author: Jan Postmus, Digital SWS, Utrecht, The Netherlands.
$!
$! Calling TVMACROS.COM
$!	Normally called from TV.COM, the main procedure to build TV.
$!	No parameters needed, when TVMACROS is called.
$!
$! Error-handling
$!	In case an error is detected, this error is reported.
$!	Depending whether this step is called from TV.COM, or
$!	run individually, the error-code is passed. When called
$!	by the main procedure, exit-code = 101 and error-code
$!	holds the appr. error. When run individually, exit-code
$!	will contain the error.
$!
$! Termination
$!	This procedure can be terminated by typing CTRL-Y.
$!	In case this step is called from another procedure,
$!	this is reported by exit-code = 103.
$!
$ ON CONTROL_Y THEN GOTO TVMACROS_FATAL
$ SET NOON
$!
$! Is TV.MLB present?
$!
$ LIB_MLB = F$SEARCH("TV.MLB",1)
$!
$ IF "''LIB_MLB'" .NES. "" THEN GOTO EXIST
$!
$! Not present, create TV.MLB
$!
$ LIBRARY /CREATE /MACRO TV
$!
$ IF $STATUS THEN GOTO EXIST
$!
$! Error detected during library creation, save error-code.
$!
$ ERROR_CODE == $STATUS
$ GOTO TVMACROS_ERROR
$!
$ EXIST:
$!
$! Insert/replace TVMACROS in TV.MLB
$!
$ LIBRARY /MACRO /REPLACE TV TVMACROS.MAR
$!
$ IF $STATUS THEN GOTO TVMACROS_30
$!
$! Error detected during library replacement, save error-code.
$!
$ ERROR_CODE == $STATUS
$ GOTO TVMACROS_ERROR
$!
$ TVMACROS_30:
$!
$ WRITE SYS$OUTPUT " "
$ WRITE SYS$OUTPUT " ** TVMACROS inserted in TV macro library."
$!
$ TVMACROS_END:
$!
$! Normal (correct) end of procedure/step.
$!
$ EXIT_CODE = 1
$ GOTO TVMACROS_LAST
$!
$ TVMACROS_ERROR:
$!
$! Error detected during procedure/step
$!
$ EXIT_CODE = 101
$ IF "''LST_PAR'" .NES. "" THEN GOTO TVMACROS_LAST
$!
$! Procedure/step is run individually, exit-code = error-code
$!
$ EXIT_CODE = ERROR_CODE
$ DELETE /SYMBOL /GLOBAL ERROR_CODE
$ GOTO TVMACROS_LAST
$!
$ TVMACROS_FATAL:
$!
$! Procedure/step terminated by ^Y.
$!
$ EXIT_CODE = 103
$ GOTO TVMACROS_LAST
$!
$ TVMACROS_LAST:
$!
$! Restore verify-mode
$!
$ IF VERIFY .EQ. 1 THEN SET VERIFY
$!
$ EXIT EXIT_CODE