Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

! UPD ID= 68, FARK:<4-1-WORKING-SOURCES.MONITOR>S20TAP.CTL.2,  22-Apr-82 13:32:59 by ZIMA
!EDIT 1 - Set DLUSER structure to PS:
! UPD ID= 28, FARK:<4-WORKING-SOURCES.MONITOR>S20TAP.CTL.2,   4-Jun-80 16:19:13 by ZIMA
!TCO 4.1.1136 - Use the right microcode file.

! Obtain a tape drive
@MOUNT TAPE TAPE:/WRITE/LABEL:UNLABELED

!Systems not using Tape Drive Allocation must replace the
!@MOUNT TAPE command with @ASSIGN MTA0: and @DEFINE TAPE:
!(AS) MTA0: commands.

@ENABLE (CAPABILITIES)
@REWIND (DEVICE) TAPE:
! WRITE MICROCODE
@COPY (FROM) SYSTEM:KS10.RAM (TO) TAPE:

! WRITE BOOTSTRAP
@COPY (FROM) SYSTEM:MTBOOT.RDI (TO) TAPE:

! Save the monitor
@GET (PROGRAM) PS:<SYSTEM>MONITR.EXE
@SAVE (ON FILE) TAPE:

! Save the TOPS-20 Command Language Interpreter
@GET (PROGRAM) SYSTEM:EXEC.EXE
@SAVE (ON FILE) TAPE:

! Save the DLUSER program
@GET (PROGRAM) SYS:DLUSER.EXE
@SAVE (ON FILE) TAPE:

! Run the same DLUSER program, saving the directory structure on tape
@START
*STRUCTURE PS:
*DUMP (TO FILE) TAPE:
*EXIT

! Save DUMPER
@GET (PROGRAM) SYS:DUMPER.EXE
@SAVE (ON FILE) TAPE:

! Run the same DUMPER, saving SYSTEM: and SYS:
@START
*TAPE (DEVICE) TAPE:
*LIST (LOG INFORMATION ON FILE) S20TAP.LPT
*SSNAME SYSTEM-FILES
*SAVE (DISK FILES) PS:<NEW-SYSTEM>,PS:<SYSTEM>
*SSNAME SUBSYS-FILES
*SAVE (DISK FILES) PS:<NEW-SUBSYS>,PS:<SUBSYS>
*EXIT

! Print the DUMPER log file
@PRINT S20TAP.LPT/NOTE:"BACKUP TAPE"

@DISMOUNT TAPE:
@

!Systems not using Tape Drive Allocation must replace the
!@DISMOUNT TAPE: command with @UNLOAD (DEVICE) TAPE: and
!@DEASSIGN TAPE: commands.