Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

TITLE DNWAIT Wait for the 2020 DECnet acceptance test server

COMMENT #

	This program is run by the source task job to insure that
the server task job is running DYNETS. Using this program
the two UETP tests can be submitted at the same time with no problems.
The source task will always wait for the server before trying
to establish a DYNETS to DYNETS logical link.

	This program assumes that the DYNETS server task will
automatically reestablish itself as a server after a logical link
is aborted.

#
	SEARCH MONSYM,MACSYM
	.REQUIRE SYS:MACREL
	T1=1
	T2=2
	T3=3
	T4=4

BEGIN:	MOVX T1,<GJ%SHT>		;SHORT FORM
	HRROI T2,[ASCIZ/DCN:-TASK-TEST72/] ;TARKET TASK IS TEST72
	GTJFN				;THIS SHOULD ALWAYS WORK
	 JSHLT				;ERROR?
	HRRZ T1,T1			;ISOLATE THE JFN
	MOVEM T1,JFN			;SAVE THE JFN FOR LATER
AGAIN:	MOVE T1,JFN			;RETRIEVE THE JFN
	MOVX T2,<FLD(7,OF%BSZ)+OF%RD+OF%WR>	;WE WONT DO IO BUT NEED FLAGS
	OPENF				;SEND A CONNECT INITIATE TO TEST72
	 JSHLT				; ERROR?
	MOVEI T1,^D5000			;5 SECONDS
	DISMS				;WAIT THE THE CONNECT CONFIRM
	MOVE T1,JFN			;GET THE JFN
	MOVEI T2,.MORLS			;GET LL STATUS
	MTOPR
	TXNE T3,MO%CON			;CONNECTED YET?
	JRST GOTIT			;YES
	MOVX T1,<CO%NRJ+CZ%ABT>		;ABORT AND SAVE JFN
	HRR T1,JFN			;THE JFN
	CLOSF				;CLOSE THE FILE
	 JSHLT				;ERROR?
	MOVEI T1,^D10000		;WAIT 10 SECONDS
	DISMS
	JRST AGAIN			;TRY AGAIN
GOTIT:	MOVE T1,JFN			;GET THE JFN
	CLOSF				;CLOSE THE FILE
	 JSHLT
	HALTF

JFN:	0				;SAVED JFN
	END BEGIN