Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

	.SBTTL	INIT1 - initialization...phase 1(+CHK11)

; THIS IS THE FIRST SECTION OF THE INITIALIZATION CODE.
;  THE INITIALIZATION HAS BEEN BROKEN UP INTO TWO PHASES
;  SO THAT THE EARLY PHASE CAN BE OVERLAYED BY BUFFERS.
; AFTER INITIALIZATION THIS MODULE BECOMES FREE STORAGE.
;
.REPT 0


                          COPYRIGHT (c) 1982,1981, 1980, 1979
            DIGITAL EQUIPMENT CORPORATION, maynard, mass.

THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND  COPIED
ONLY  IN  ACCORDANCE  WITH  THE  TERMS  OF  SUCH  LICENSE AND WITH THE
INCLUSION OF THE ABOVE COPYRIGHT NOTICE.  THIS SOFTWARE OR  ANY  OTHER
COPIES  THEREOF MAY NOT BE PROVIDED OR OTHERWISE MADE AVAILABLE TO ANY
OTHER PERSON.  NO TITLE TO AND OWNERSHIP OF  THE  SOFTWARE  IS  HEREBY
TRANSFERRED.

THE INFORMATION IN THIS SOFTWARE IS SUBJECT TO CHANGE  WITHOUT  NOTICE
AND  SHOULD  NOT  BE  CONSTRUED  AS  A COMMITMENT BY DIGITAL EQUIPMENT
CORPORATION.

DIGITAL ASSUMES NO RESPONSIBILITY FOR THE USE OR  RELIABILITY  OF  ITS
SOFTWARE ON EQUIPMENT WHICH IS NOT SUPPLIED BY DIGITAL.

.ENDR
;

;	REVISION HISTORY


; 3(001) BS		ADD EDIT NUMBERS
; 4(002) 28-JUN-79 JW	Don't enable parity checking if no parity unit


VINIT1=002


VEDIT=VEDIT+VINIT1

	.$$LOC=.

	.=JOBVER+4

	.WORD	VEDIT

	.=.$$LOC

; START HERE AFTER LOADING.

BEGIN:	RESET			;RESET THE UNIBUS
	MOV	#PDL,SP		;SET UP PUSH-DOWN LIST
	MOV	#LOWZ1,R0	;CLEAR LOWER CORE
11$:	CLR	(R0)+
	CMP	#LOWZ2,R0	;CLEARED ENOUGH?
	BNE	11$		;NO, CLEAR THE REST.
	JSR	PC,CHK.11	;DO ONCE-ONLY CHECK OF HARDWARE
	.WORD	MYNAME		;POINT TO NAME OF PROGRAM

; HERE WHEN HARDWARE TESTS ARE DONE

CKDONE:	TST	NSLINS		;IS THERE AT LEAST ONE SYNCHRONOUS LINE?
	BNE	11$		;YES.
	JSR	R0,CKTCRL	;NO, GIVE MESSAGE
	.ASCIZ	\ ?No synchronous lines?? \
	.EVEN
	STOPCD	NDQ		;NO DQ11S FOUND

; HERE IF THERE IS AT LEAST ONE DQ11.

11$:	JSR	R0,CKTCRL	;PRINT STARTUP MESSAGE
	.ASCII	\Starting \
	PGMNAM			;NAME OF PROGRAM
	.BYTE	0		;BE SURE THE STRING TERMINATES
	.EVEN			;BE SURE WE'RE ON A WORD BOUNDRY

; DO FINAL INITIALIZATION OF THE DN60 CORE IMAGE.
;  THE CORE USED BY THESE INSTRUCTIONS WILL BE RECLAIMED FOR
;  BUFFER SPACE BY SECTION INIT2.

	MOV	#NXMNRM,NXMGO	;BUS ERROR ACTION IS NORMAL
	MOV	#KW.INE,CLKWRD	;ENABLE THE KW11-L CLOCK

.IIF NDF,FT.MF,MOV	#MP.ENB,MP.REG	;ENABLE MEMORY PARITY ERRORS 4(002)

	MOV	#-1,DLGONE	;NOTE THE DL10 IS NOT RUNNING YET

.IF NE,FTRACE
	MOV	#TRCTBS,TRCPTR	;INITIALIZE TRACE TABLE POINTER
	MOV	(PC)+,@(PC)+	;set load time trace condtions
DEFTRC:	TRCLOD			;default trace flags
	TRCBTS			;where they go
	MOV	(PC)+,@(PC)+	;set load time trace halt conditions
DEFHLT:	TRCHLD			;default halt flags
	TRCHLT			;where they go
.ENDC ;.IF NE,FTRACE

	MOV	#CHDATL,D60CSZ	;REPORT CHUNK DATA LENGTH
	MOV	#XLOPTN,D60OPN ;REPORT TRANSLATION OPTIONS AVAILABLE
	JMP	DN60		;GO RUN THE PROGRAM.