Trailing-Edge
-
PDP-10 Archives
-
cobol12c
-
getasy.mac
There are 7 other files named getasy.mac in the archive. Click here to see a list.
; UPD ID= 1369 on 10/23/78 at 3:17 PM
TITLE GETASY FOR COBOL V12C
SUBTTL READ IN AN ASYFIL WORD AL BLACKINGTON/CAM
SEARCH COPYRT
SALL
;COPYRIGHT (C) DIGITAL EQUIPMENT CORPORATION 1974, 1985
;ALL RIGHTS RESERVED.
;
;THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY BE USED AND COPIED
;ONLY IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
SEARCH P
%%P==:%%P
;EDITS
;V10*****************
;NAME DATE COMMENTS
;********************
TWOSEG
.COPYRIGHT ;Put COPYRIGHT statement in .REL file.
RELOC 400000
ENTRY GETASY ;GET A WORD
ENTRY SETASY ;SET UP ASYFIL FOR INPUT
EXTERNAL DEVDED,KILL,SIXOUT
GETASY: SOSG AS1BHI+2
JRST GETASB
GETASA: ILDB CH,AS1BHI+1
POPJ PP,
GETASB: AOS AS1BLK
IN ASY,
JRST GETASA
MOVEI CH,AS1DEV
JRST DEVDED
SETASY: MOVE TA,AS1BUF ;SET JOBFF TO A BUFFER AREA
MOVEM TA,.JBFF##
INBUF ASY,2 ;GRAB 2 BUFFERS
SETZM AS1BLK ;CLEAR BLOCK COUNTER
MOVE TE,ASYFIL ;SET UP "LOOKUP" PARAMETERS
MOVE TD,AS1HDR+1
SETZB TC,TB
LOOKUP ASY,TE ;FIND THE FILE
JRST KNOAS1 ;NOT THERE--CATASTROPHE
POPJ PP,
;CANNOT FIND ASYFIL
KNOAS1: MOVE TA,ASYFIL
PUSH PP,TD ;SAVE ERROR NUMBER
PUSHJ PP,SIXOUT
TTCALL 3,[ASCIZ ".TMP ("]
POP PP,I2 ;GET ERROR
HRRZS TA,I2 ;GET NUMBER ONLY
PUSHJ PP,OCTOUT##
JUMPE I2,KNOAS0 ;0 IS SPECIAL
MOVE TA,ERAPTR##
KNOAS2: HLRZ TB,(TA)
CAIE TB,(I2)
AOBJN TA,KNOAS2
HRRZ TA,(TA)
OUTSTR (TA)
OUTSTR [ASCIZ /
/]
JRST KILL
KNOAS0: OUTSTR [ASCIZ /0) file not found
/]
JRST KILL
EXTERNAL AS1BHI,AS1BLK,AS1DEV,AS1BUF,AS1HDR,ASYFIL
END