Trailing-Edge
-
PDP-10 Archives
-
decus_20tap4_198111
-
decus/20-0113/cmod68.bas
There are 2 other files named cmod68.bas in the archive. Click here to see a list.
00020REM***************************************************************
00030REM CMOD68 CMOD68 CMOD68 CMOD68 CMOD68
00040REM***************************************************************
00050FILES RFILE1,RFILE2,RFILE3
00060 DIM N(12),S(12),M(12)
00100RESTORE#1
00101 INPUT# 1,I1,I2,I3
00110SCRATCH#1
00111 PRINT # 1,68,I2,I3
00120PRINT L$
00130PRINT " INPUT OF DATA FOR LINEAR MODEL"
00140PRINT " "
00142PRINT "THIS MODEL ASSUMES HOMOSCEDASCITY OF VARIANCE AND INDEPENENCE"
00144PRINT "BETWEEN CELLS."
00146PRINT " "
00150PRINT "THIS MODULE ALLOWS YOU TO ENTER THE SUFFICIENT STATISTICS"
00160PRINT "FOR EACH CELL IN YOUR ANALYSIS. YOU WILL BE ASKED TO ENTER"
00170PRINT "THE SAMPLE SIZE, MEAN AND STANDARD DEVIATION(DIVISOR OF N)"
00180PRINT "FOR EACH CELL."
00190PRINT " "
00200PRINT "IF YOU DO NOT HAVE THESE STATISTICS, THEY MAY BE OBTAINED IN"
00210PRINT "COMPONENT 1--DATA REDUCTION - SUMMARY STATISTICS -- PROVIDED"
00220PRINT "YOU HAVE DATA IN YOUR RESTART FILE. TO GET DATA IN YOUR "
00230PRINT "RESTART FILE USE COMPONENT 2 OR COMPONENT 1--OPTION 1 OR 8."
00235PRINT " "
00240PRINT "TO CONTINUE TYPE '1'."
00245PRINT "TO OBTAIN SUFFICIENT STATISTICS TYPE '0'.";
00250GOSUB 9000
00260IF O1=1 THEN 280
00270CHAIN "RSTRT"
00280PRINT L$
00290PRINT "INPUT THE NUMBER OF CELLS IN YOUR DATA(MAXIMUM OF 12)."
00300GOSUB 9000
00310O1=INT(O1)
00320IF O1 >= 2 THEN 360
00330PRINT "NUMBER OF CELLS MUST BE AT LEAST 2 AND NOT MORE THAN 12."
00340PRINT "PLEASE RESPECIFY.";
00350GOTO 300
00360IF O1>12 THEN 330
00370M=O1
00380MAT N=ZER(M)
00390MAT M=ZER(M)
00400MAT S=ZER(M)
00410PRINT L$
00420PRINT "INPUT SAMPLE SIZE, MEAN, STANDARD DEVIATION(DIVISOR OF N)"
00430FOR I=1 TO M
00440GOTO 460
00450PRINT "SAMPLE SIZE,MEAN,STANDARD DEVIATION FOR ";
00460PRINT "CELL ";I
00470GOSUB 9100
00480IF O3>0 THEN 510
00490PRINT "STANDARD DEVIATION MUST BE POSITIVE. RESPECIFY."
00500GOTO 450
00510IF O1 >= 2 THEN 540
00520PRINT "MUST HAVE AT LEAST TWO OBSERVATIONS IN EACH CELL. RESPECIFY."
00530GOTO 450
00540S(I)=O3
00550N(I)=O1
00560M(I)=O2
00570NEXT I
00580PRINT L$
00590PRINT "YOU HAVE ENTERED THE FOLLOWING DATA:"
00600PRINT "CELL ","N","MEAN","STANDARD DEVIATION"
00610FOR I=1 TO M
00620PRINT I,N(I),M(I),S(I)
00630NEXT I
00635PRINT " "
00640PRINT "IF DATA IS SATISFACTORY, TYPE '0'."
00641PRINT "OTHERWISE TYPE THE NUMBER OF CELL TO BE CHANGED."
00642GOSUB 9000
00643O9=INT(O1)
00644IF O9 <= 0 THEN 670
00645IF O9>M THEN 670
00650PRINT "INPUT CELL ";O9
00652PRINT "SAMPLE SIZE, MEAN AND STANDARD DEVIATION";
00654GOSUB 9100
00655IF O1 >= 2 THEN 660
00656PRINT "SAMPLE SIZE MUST BE AT LEAST 2. RESPECIFY."
00657GOTO 650
00660IF O3>0 THEN 665
00662PRINT "STANDARD DEVIATION MUST BE POSITIVE. RESPECIFY."
00664GOTO 650
00665N(O9)=INT(O1)
00666S(O9)=O3
00667M(O9)=O2
00668GOTO 580
00670SCRATCH#2
00671 PRINT # 2,M
00680FOR I=1TOM
00681PRINT#2,N(I)
00682NEXT I
00683FORI=1TOM
00684PRINT#2,M(I)
00685NEXTI
00686FORI=1TOM
00687PRINT#2,S(I)
00688NEXTI
00690CHAIN "CMOD69"
09000REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
09005INPUT O1
09015IF O1=-9999 THEN 9025
09020RETURN
09025CHAIN "RSTRT"
09035REM*************END ROUTINE
09100REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED. 3 INPUTS
09105INPUT O1,O2,O3
09115IF O1=-9999 THEN 9135
09120IF O2=-9999 THEN 9135
09125IF O3=-9999 THEN 9135
09130RETURN
09135CHAIN "RSTRT"
09145REM*************END ROUTINE
09999END