Trailing-Edge
-
PDP-10 Archives
-
decus_20tap4_198111
-
decus/20-0113/cmod7.bas
There are 2 other files named cmod7.bas in the archive. Click here to see a list.
00020REM *****************************************************************
00030REM CMOD7 CMOD7 CMOD7 CMOD7 CMOD7 CMOD7
00040REM *****************************************************************
00050REM
00060REM ENTRY OF TWO T DISTRIBUTIONS FOR COMP. OF MEANS
00070REM
00080REM****************************************************************
00090 FILES RFILE1,RFILE2,RFILE3,RF4,RF5,RF6,RF7,RF8,RF9
00130RESTORE#1
00131 INPUT# 1,I1,I2,I3
00140SCRATCH#1
00141 PRINT # 1,7,I2,I3
00150PRINT L$
00160PRINT " COMPARISON OF NORMAL MEANS"
00170PRINT
00180PRINT "THIS PROGRAM ALLOWS YOU TO EXAMINE THE CHARACTERISTICS OF THE"
00190PRINT "POSTERIOR BEHRENS-FISHER DISTRIBUTION ON THE DIFFERENCE OF TWO"
00200PRINT "NORMAL MEANS. YOU NEED TO KNOW THE PARAMETERS OF THE MARGINAL"
00210PRINT "POSTERIOR T-DISTRIBUTIONS ON THE TWO MEANS. IF YOU DO NOT KNOW"
00220PRINT "THESE THEY CAN BE OBTAINED BY DOING TWO SEPARATE TWO-PARAMETER"
00230PRINT "NORMAL ANALYSES."
00240PRINT
00250PRINT "IF YOU KNOW THE PARAMETERS AND WANT TO PROCEED TYPE '1'."
00260PRINT "IF YOU WANT TO EXIT MODULE TYPE '0'."
00270GOSUB 9000
00280IF O1 <> 0 THEN 300
00290CHAIN "RSTRT"
00300IF O1=1 THEN 350
00310PRINT
00320PRINT "REENTER. INPUT MUST BE 0 OR 1."
00330PRINT
00340GOTO 270
00350PRINT L$
00360PRINT "INPUT THE PARAMETERS OF THE FIRST T-DISTRIBUTION."
00370PRINT
00380PRINT "DEGREES OF FREEDOM";
00390GOSUB 9000
00400N0=O1
00410IF N0 >= 5 THEN 430
00420GOTO 540
00430PRINT
00440PRINT "MEAN";
00450GOSUB 9000
00460M0=O1
00470PRINT
00480PRINT "SCALE PARAMETER";
00490GOSUB 9000
00500IF O1>0 THEN 580
00510PRINT
00520PRINT "REENTER. SCALE PARAMETER MUST BE POSITIVE AND NON-ZERO."
00530GOTO 470
00540PRINT
00550PRINT "REENTER. DEGREES OF FREEDOM MUST BE AT LEAST 5."
00560PRINT
00570GOTO 380
00580PRINT
00590Q0=O1
00600PRINT "INPUT THE PARAMETERS OF THE SECOND T-DISTRIBUTION."
00610PRINT
00620PRINT "DEGREES OF FREEDOM";
00630GOSUB 9000
00640IF O1 >= 5 THEN 680
00650PRINT
00660PRINT "REENTER. DEGREES OF FREEDOM MUST BE AT LEAST 5."
00670GOTO 610
00680PRINT
00690N1=O1
00700PRINT "MEAN";
00710GOSUB 9000
00720M1=O1
00730PRINT
00740PRINT "SCALE PARAMETER";
00750GOSUB 9000
00760IF O1>0 THEN 800
00770PRINT
00780PRINT "REENTER. SCALE PARAMETER MUST BE POSITIVE AND NON-ZERO."
00790GOTO 730
00800Q1=O1
00810M=M0-M1
00820E0=SQR(Q0/N0+Q1/N1)
00830T0=ATN(SQR((Q0/N0)/(Q1/N1)))
00840T0=T0*180/3.14159
00850PRINT L$
00860PRINT "THE DISTRIBUTION OF THE DIFFERENCE OF THE TWO T-DISTRIBUTIONS IS A"
00870PRINT "BEHRENS-FISHER DISTRIBUTION WITH THE FOLLOWING 5 PARAMETERS:"
00880PRINT
00890:NU1 (DEGREES OF FREEDOM OF 1ST DIST.) ####.###
00900 PRINT USING 890,N0
00910:NU2 (DEGREES OF FREEDOM OF 2ND DIST.) ####.###
00920 PRINT USING 910,N1
00930:PSI (IN DEGREES) ####.###
00940 PRINT USING 930,T0
00950:ZETA (MEAN OF 1ST MINUS MEAN OF 2ND) ####.###
00960 PRINT USING 950,M
00970:EPSILON (SCALE PARAMETER) ####.###
00980 PRINT USING 970,E0
00990PRINT
01000PRINT "WHEN YOU ARE READY TO CONTINUE TYPE '1'.";
01010GOSUB 9000
01020SCRATCH#2
01021 PRINT # 2,N0,N1,T0,E0,M
01030CHAIN "CMODF"
09000REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
09005INPUT O1
09015IF O1=-9999 THEN 9025
09020RETURN
09025CHAIN "RSTRT"
09035REM*************END ROUTINE
09999END