Trailing-Edge
-
PDP-10 Archives
-
decus_20tap4_198111
-
decus/20-0113/cmod93.bas
There are 2 other files named cmod93.bas in the archive. Click here to see a list.
00020REM***********************************************************
00030REM CMOD93 CMOD93 CMOD93 CMOD93 CMOD93 CMDO93
00040REM***********************************************************
00050REM***********************************************************
00060REM JUNIOR COLLEGE ACT AND GPA
00070REM***********************************************************
00080 FILES RFILE1,RFILE2,RFILE3
00120RESTORE#1
00121 INPUT# 1,I1,I2,I3
00130SCRATCH#1
00131 PRINT # 1,93,I2,I3
00140PRINT "IF YOU WANT A DESCRIPTION OF THIS FILE TYPE '1', ELSE '0'.";
00150GOSUB 9000
00160IF O1=0 THEN 380
00170PRINT L$
00180PRINT " DATA FILE #4"
00190PRINT " "
00200PRINT "THIS DATA FILE CONTAINS ACT (AMERICAN COLLEGE TESTING) SCORES AND"
00210PRINT "FIRST SEMESTER GPA'S FOR STUDENTS AT 10 SELECTED JUNIOR COLLEGES."
00220PRINT "THESE JUNIOR COLLEGES ARE CONSIDERED TO BE RELATIVELY HOMOGENEOUS"
00230PRINT "WITH RESPECT TO CURRICULA."
00240PRINT
00250PRINT "THERE ARE DATA FOR THE 1968 AND 1969 ACADEMIC YEARS. YOU MAY"
00260PRINT "SELECT ANY COLLEGE OR YEAR."
00270PRINT
00280PRINT "VARIABLE 1---ENGLISH"
00290PRINT "VARIABLE 2---MATHEMATICS"
00300PRINT "VARIABLE 3---SOCIAL STUDIES"
00310PRINT "VARIABLE 4---NATURAL SCIENCES"
00320PRINT "VARIABLE 5---FIRST SEMESTER GPA"
00330PRINT " "
00340PRINT "IF YOU WANT TO USE THIS FILE TYPE '1', ELSE '0'.";
00350GOSUB 9000
00360IF O1=1 THEN 380
00370CHAIN "RSTRT"
00380PRINT L$
00390PRINT "HERE ARE THE SAMPLE SIZES BY COLLEGE AND YEAR."
00400DATA 6,175,179,7,105,115,8,118,112,9,113,102,10,128,118,11,165,160
00410DATA 12,132,108,13,174,158,15,167,000,19,117,110
00420 DIM D(10,3)
00430MAT READ D
00440PRINT
00450PRINT " 1968 1969"
00460PRINT
00470FOR I=1 TO 10
00480:COLLEGE### #### ####
00490PRINT USING 480,D(I,1),D(I,2),D(I,3)
00500NEXT I
00510PRINT
00520PRINT "INPUT THE COLLEGE NUMBER AND YEAR YOU WANT.";
00530GOSUB 9050
00531 IF O1<>15 THEN 540
00532 IF O2<>1969 THEN 540
00533 PRINT" NO DATA AVAILABLE FOR COLLEGE 15, 1969."
00534PRINT"PLEASE REENTER COLLEGE NUMBER AND YEAR."
00535 GOTO 530
00540FOR I=1 TO 10
00550IF O1=D(I,1) THEN 590
00560NEXT I
00570PRINT "REENTER. MUST BE NUMBER OF COLLEGE AND 1968 OR 1969."
00580GOTO 530
00590IF O2=1968 THEN 620
00600IF O2=1969 THEN 640
00610GOTO 570
00620SCRATCH#2
00621 PRINT # 2,68,O1
00630GOTO 650
00640SCRATCH#2
00641 PRINT # 2,69,O1
00650CHAIN "CMOD20"
09000REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED.
09005INPUT O1
09015IF O1=-9999 THEN 9025
09020RETURN
09025CHAIN "RSTRT"
09050REM--SUBROUTINE THAT DETERMINES IF RESTART HAS BEEN REQUESTED. 2 INPUTS
09055INPUT O1,O2
09065IF O1=-9999 THEN 9080
09070IF O2=-9999 THEN 9080
09075RETURN
09080CHAIN "RSTRT"
09090REM*************END ROUTINE
09999 END