Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

        title MACD20
        search monsym,macsym
;
;FORTRAN CALLABLE ROUTINES FOR RESUME PROGRAM ON DECSYSTEM20
;
;------------------------------------------------------------------
;
;CALL LEAVE(NO ARGUMENTS)
;
;Exits without the time statistics produced by FORTRAN STOP statement
;
LEAVE::
        HALTF                   ;stop this fork
        jrst 0,leave              ;repeat if user continues program
;
;------------------------------------------------------------------
;
;CALL TTYSET(NO ARGUMENTS)
;
;Judy Martel  Nov 81
;
;Sets terminal characteristics of controlling terminal to following:
;
;Refuse Links
;Refuse Advice
;Refuse System-Messages
;Pause Command
;No Pause End-Of-Page
;Length 0
;Width 0
;Lowercase
;No Raise
;No Flag
;No Indicate
;Formfeed
;No Tabs
;No Immediate.
;

ttyset::

; Do mode word
        movx    1,.priou                ;TT%PGM == enables pause command
        movx    2,TT%PGM+TT%MFF+TT%LCA  ;TT%MFF == formfeed
        stpar                           ;TT%LCA == lowercase

; Do "system messages" bit.
        movx    1,.priou
        movx    2,.mosnt                ;Refuse system messages
        movx    3,.mosmn
        mtopr

; Do CCOC words.
        movx    1,.priou
        rfcoc                           ;Get current CCOC words
        movx    1,2                     ;"send actual code"
        dpb     1,[point 2,2,25]        ;For ^L

; Do links/advice
        movx    1,.cttrm                ;refuse links and advice
        txo     1,tl%sab!tl%sta         ;don't ask!
        tlink
        jump                            ;failure return
        ret                             ;normal return

;
;------------------------------------------------------------------
;
;JOBINF( USRNAM, JOBNO, USERNO )
;
;Fortran callable routine which stores current user name, job number
;and user number in the arguments.  USRNAM should be large enough to
;hold 39 characters.
;
;Fortran argument passing convention:  addresses of arguments are passed
;in a block pointed to by AC16:
;
;   16 ---> +------+
;           |USRNAM|     @0(16)
;           |JOBNO |
;           |USERNO|
;           +------+
;
jobinf::
        gjinf                       ;Get job information
        hrrzm   1,@2(16)            ;User number
        movem   3,@1(16)            ;Job number
        move    2,1
        hrro    1,0(16)             ;=> to user buffer
        dirst                       ;Directory number to string
         jfcl                       ;Ignore error return
        popj    p,                  ;Return
;
;------------------------------------------------------------------
;
;CALL EXPUNG(NO ARGUMENTS)
;
;Expunges deleted files from a directory on the DECsystem-20.
;This is called after each temporary scratch file is
;closed and deleted.
;
;kim peck 1/79
;
expung::
        seto    1,              ;set up info to get current dir num
        move    2,[-1,,dirnum#] ;ask for 1 word of info
        movei   3,.jidno        ;offset  for dir number in gettab
        getji                   ;get actual info
        jump                    ;noop
        move    2,dirnum        ;load directory number
        hrlzi   1,(dd%dtf+dd%dnf)       ;flag options for deldf
        deldf                   ;do expunge of temp and deleted files
        popj    17,             ;return

;
        end