Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

.;This MIC file is used to put CSM plotting software into FORLIB version 6
.GOTO 'A
ALL::.;ALL		;Use PLTUNV.REL, PLOT.REL, and SYMBOL.REL
.DIRECT SYS:FORLIB	;Replace all 3 REL files
.COPY FORLIB.REL=SYS:FORLIB.REL
.DO FORLIB PLTUNV,NOINDEX
.DO FORLIB PLOT,NOINDEX
.DO FORLIB SYMBOL,INDEX
.MIC RETURN

EXTRAC::.;EXTRAC::	Extract CSM modules from SYS:FORLIB
.R MAKLIB
*PLTUNV=SYS:FORLIB/EXTRACT:(IPLOT,PLOTS,CRSHRS,ERASE,FACTOR,GETWIN,NEWPEN,-
*  OPRTXT,PAUSEP,PLOT.,PLOTOF,PLOTOK,PLOTON,ROTATE,SETWIN,SUBWIN,WHERE,XHAIRS)
*PLOT=  SYS:FORLIB/EXTRACT:PLOT
*DSKPLT=SYS:FORLIB/EXTRACT:.PLOT.
*SYMBOL=SYS:FORLIB/EXTRACT:(ISETAB,MSETAB,SETSYM,NUMBER,SYMBOL)
*CPLOT1=SYS:FORLIB/EXTRACT:(SCALE,AXES,LOGAXS,GRID,LINE,DASHLN,GRIDER)
*CMISC1=SYS:FORLIB/EXTRACT:(RANGE,RUNTIM,MAXMIN,ALLOC,QSORT,FIBSRH)
.DIRECT PLTUNV,PLOT,DSKPLT,SYMBOL,CPLOT1,CMISC1
.MIC RETURN


REMDEC::.;REMDEC::	Remove DEC plot routines from distributed FORLIB.REL
.;DEC:FORLIB version 6 has plotting routines in this order:
.; FORPSE=PAUS.,STOP.  (last module before plotting routines)
.; AXIS  =AXIS   (Does not have entry point AXES)
.; LINE  =LINE   (Draws lines)
.; SCALE =SCALE  (Sets scaling factor)
.; FORPL2 (zero length module)
.; PLOTF =PLOTF  (Fenorian character set)
.; PLOTC =PLOTC  (Cyrillic character set)
.; PLOT  =MKTBL,NUMBER,PLOT,PLOTS,SETABL,SYMBOL,WHERE
.; PLOT.A=PLOT.A (Ascii (lineprinter) character set)
.; PLOTCD=PLOTC  (dummy PLOTC definition for SYMBOL)
.; PLOTFD=PLOTF  (dummy PLOTF definition for SYMBOL)
.; FORCPX              (first module after plotting routines)

.DIRECT/SLOW DEC:FORLIB.V6,DSK:PLTUNV,PLOT,DSKPLT,SYMBOL,CPLOT1,CMISC1
.COPY TEMP.REL=PLTUNV.REL,PLOT.REL,DSKPLT.REL,SYMBOL.REL
.R MAKLIB
*DSK:FORLIB=DEC:FORLIB.V6/DELETE:(AXIS,LINE,SCALE,PLOT) ;Must remove PLOT first
*;Insert CSM modules before FORPL2
*FORLIB=FORLIB/MASTER:FORPL2,CPLOT1/INSERT	;Routines which call PLOT
*FORLIB=FORLIB/MASTER:FORPL2,TEMP/INSERT	;PLOT and other routines
*FORLIB=FORLIB/MASTER:FORPL2,CMISC1/INSERT	;Miscellaneous CSM routines
*FORLIB=FORLIB/DELETE:(FORPL2,PLOTF,PLOTC,PLOT.A,PLOTCD,PLOTFD)
*FORLI6.MAP/POINTS=FORLIB
*FORLID.MAP/POINTS=DEC:FORLIB.V6
.R FILCOM
*=FORLID.MAP,FORLI6.MAP
.DELETE TEMP.REL
.MIC RETURN

PLTUNV::.;PLTUNV::	;Replace dummy modules from PLTUNV.REL
.DIRECT/SLOW PLTUNV.REL
.R MAKLIB
*FORLIB=FORLIB/MASTER:(IPLOT,PLOTS,CRSHRS,ERASE,FACTOR,GETWIN,NEWPEN,-
*OPRTXT,PAUSEP,PLOT.,PLOTOF,PLOTOK,PLOTON,ROTATE,SETWIN,SUBWIN,WHERE,XHAIRS),-
*      PLTUNV/REPLACE:(IPLOT,PLOTS,CRSHRS,ERASE,FACTOR,GETWIN,NEWPEN,-
*OPRTXT,PAUSEP,PLOT.,PLOTOF,PLOTOK,PLOTON,ROTATE,SETWIN,SUBWIN,WHERE,XHAIRS)
*/EXIT
.IF ($B="NOINDEX") .MIC RETURN
.GOTO INDEX

PLOT::.;PLOT::		;Replace modules from PLOT.REL
.DIRECT/SLOW PLOT.REL
.R MAKLIB
*FORLIB=FORLIB/MASTER:PLOT,PLOT/REPLACE:PLOT
*/EXIT
.IF ($B="NOINDEX") .MIC RETURN
.GOTO INDEX

SYMBOL::.;SYMBOL::	;Replace modules from SYMBOL.REL
.DIRECT/SLOW SYMBOL.REL
.R MAKLIB
*FORLIB=FORLIB/MASTER:(ISETAB,MSETAB,SETSYM,NUMBER,SYMBOL),-
*      SYMBOL/REPLACE:(ISETAB,MSETAB,SETSYM,NUMBER,SYMBOL)
*/EXIT
.IF ($B="NOINDEX") .MIC RETURN
.GOTO INDEX

INDEX::.;INDEX::	;Use MAKLIB to index FORLIB.REL
.R MAKLIB
*FORLIB.REL=FORLIB/INDEX
*FORLIB.MAP=FORLIB/POINTS
*/EXIT
.VERSIO FORLIB=SYS:FOROT6/NAME:NEW
.DIRECT FORLIB		;End of FORLIB.MIC