Trailing-Edge
-
PDP-10 Archives
-
decuslib20-01
-
decus/20-0020/fvalue.sta
There are 2 other files named fvalue.sta in the archive. Click here to see a list.
100' NAME--FVALUE
110'
120' DESCRIPTION--COMPUTES THE EXACT PROBABILITY OF AN F-RATIO WITH
130' DEGREES OF FREEDOM (M,N).
140'
150' SOURCE--PROGRAMMED BY VICTOR E MCGEE,DARTMOUTH COLLEGE,
160' HANOVER, N.H. 03755 AFTER THE FORTRAN PROGRAM GIVEN
170' IN DONALD J. VELDMAN'S BOOK,"FORTRAN PROGRAMMING FOR THE
180' BEHAVIORAL SCIENCES",(HOLT,RINEHART, AND WINSTON),1967,P.131
190'
200' INSTRUCTIONS--TYPE "RUN" AND FOLLOW DIRECTIONS AS THEY APPEAR.
210'
220' * * * * * * MAIN PROGRAM * * * * * * * * * * *
230'
240 PRINT "ENTER F-VALUE,NUMERATOR D.F., AND DENOMINATOR D.F."
250 INPUT G,M,N
260 LET P=1
270 IF G*M*N=0 THEN 500
280 IF G<1 THEN 330
290 LET A=M
300 LET B=N
310 LET F=G
320 GO TO 360
330 LET A=N
340 LET B=M
350 LET F=1/G
360 LET A1=2/(9*A)
370 LET B1=2/(9*B)
380 LET Z=ABS((1-B1)*F^(.333333)-1+A1)
390 LET Z=Z/SQR(B1*F^(.666667)+A1)
400 IF B<4 THEN 440
410 LET P=(1+Z*(.196854+Z*(.115194+Z*(.000344+Z*.019527))))^4
420 LET P=.5/P
430 GO TO 460
440 LET Z=Z*(1+.08*Z^4/B^3)
450 GO TO 410
460 IF G<1 THEN 480
470 GO TO 520
480 LET P=1-P
490 GO TO 520
500 PRINT "YOU HAVE ERRED - INPUT THE 3 VALUES AGAIN"
510 GO TO 250
520 PRINT
530 PRINT
540 PRINT"EXACT PROBABILITY OF F="G;"WITH ( "M;", "N;") D.F."
550 PRINT
560 PRINT " IS "INT(100000*P)/100000
570 END