Enter your search terms Submit search form
	Web pdp-10.trailing-edge.com

!; TECmacros -- Emacs type macros in TECO %200!
!; First turn off the echo!
	:-1^T$
!; Now re-arrange the screen buffer!
	.,.X(LAST-LINE)$
	1,21E`$(.)$ 22,22E`$(ERROR-TEXT)$ 23,24E`$(LAST-LINE)
!; Now store some information on the last line!
	E.(LAST-LINE)$
	I
TECmacros$^O11I$:E<(.)"F :E>(.)$'$I
$
	JE.(.)$MY$
!; Now start the processing of the commands!
    !MAIN-LOOP!
	EVUPDATE$
	^TU(CHARACTER)$
	Q(CHARACTER)-^^^A"E ODONE$'$
	Q(CHARACTER)-^O33"E OALT-MODE-COMMAND$'$
	Q(CHARACTER)-^^^B"E :+1R OMAIN-LOOP$'$
	Q(CHARACTER)-^^^F"E :+1C OMAIN-LOOP$'$
	Q(CHARACTER)-^^^N"E [A.UA0LQA-.UA:+1L.+QAJ]A OMAIN-LOOP$'$
	Q(CHARACTER)-^^^P"E [A.UA0LQA-.UA:-1L.+QAJ]A OMAIN-LOOP$'$
	Q(CHARACTER)-^^^U"E 0LKOMAIN-LOOP$'$
	Q(CHARACTER)-^O177"E :-1D OMAIN-LOOP$'$
	Q(CHARACTER)-^^^H"E :-1D OMAIN-LOOP$'$
	Q(CHARACTER)-^^^R"E .,.+1X(CHR)DCG(CHR) OMAIN-LOOP$'$
	Q(CHARACTER)-^^^X"E OMETA-COMMAND$'$
	Q(CHARACTER)-^^^V"E :S^L$ OMAIN-LOOP$'$
	Q(CHARACTER)-^^^L"E ^L OMAIN-LOOP$'
	Q(CHARACTER)-^^^D"E :+1D OMAIN-LOOP$'
	Q(CHARACTER)-^^^K"E .U(TMP) :S^EL$:-S^N^EL$
		Q(TMP)-."E +1K OMAIN-LOOP$'
		.U(TMP) 0L .,Q(TMP)K OMAIN-LOOP$'
	Q(CHARACTER)-^^^E"E :S^EL$:-S^N^EL$ OMAIN-LOOP$'
	Q(CHARACTER)I$
	OMAIN-LOOP$

!; here if the command is a meta command!
    !META-COMMAND!
	^TU(CHARACTER)$
	OMAIN-LOOP$
!; Here if the command is an altmode!
    !ALT-MODE-COMMAND!
	^TU(CHARACTER)$
	Q(CHARACTER)-^O133"E OMETA-ALT-MODE$'
	Q(CHARACTER)-^O74"E J$'$
	Q(CHARACTER)-^O76"E ZJ$'$
	Q(CHARACTER)-^O126"E :-2S^L$'$
	OMAIN-LOOP$
    !META-ALT-MODE!
	^TU(CHARACTER)$
	Q(CHARACTER)-^O101"E [A.UA0LQA-.UA:-1L.+QAJ]A'$
	Q(CHARACTER)-^O102"E [A.UA0LQA-.UA:+1L.+QAJ]A'$
	Q(CHARACTER)-^O103"E +1C'$
	Q(CHARACTER)-^O104"E -1C'$
	Q(CHARACTER)-^O114"E I
$:-L$'$
	Q(CHARACTER)-^O115"E +1K'$
	Q(CHARACTER)-^O120"E +1D'$
	OMAIN-LOOP$

!; Here if finished processing!

    !DONE!
	1,20E`$(.)$ 21,24E`$(COMMAND-BUFFER)$
EVUPDATE$